jsp2.0 5.5.26: New recipe (from Jalimo SVN).

servlet2.3 4.1.37: Dito.
servlet2.3-native 4.1.37: Dito.
servlet2.4 5.5.26: Dito.

4 files changed, 125 insertions, 0 deletions

diff --git a/recipes/servlet-api/jsp2.0_5.5.26.bb b/recipes/servlet-api/jsp2.0_5.5.26.bb
new file mode 100644
index 0000000000..6a5f3b6f71
--- /dev/null
+++ b/recipes/servlet-api/jsp2.0_5.5.26.bb
@@ -0,0 +1,42 @@
+DESCRIPTION = "Java Server Page (JSP) API 2.0 (from Tomcat 5.5)"
+LICENSE = "AL2.0"
+AUTHOR = "Apache Software Foundation"
+
+SRC_URI = "http://archive.apache.org/dist/tomcat/tomcat-5/v${PV}/src/apache-tomcat-${PV}-src.tar.gz"
+
+S = "${WORKDIR}/apache-tomcat-${PV}-src/servletapi/jsr152"
+
+inherit java-library
+
+DEPENDS = "fastjar-native servlet2.4"
+RDEPENDS = "libservlet2.4-java"
+
+# Value of implementation.revision in build.xml
+IMPL_REVISION = "public_draft"
+
+JARFILENAME = "jsp-api-2.0.${IMPL_REVISION}.jar"
+ALTJARFILENAMES = "jsp-api-2.0.jar jsp-api.jar"
+
+do_unpackpost() {
+  sed -i -e "s|@implementation.version@|${IMPL_REVISION}|" src/etc/manifest
+}
+
+addtask unpackpost after do_unpack before do_patch
+
+do_compile() {
+  mkdir -p build
+
+  oe_makeclasspath cp -s servlet-api-2.4`
+  javac -sourcepath src/share -d build -cp $cp `find src/share/javax -name \*.java`
+
+  # Copy extraneous files according to build.xml's compile task
+  (cd src/share && find . -name "*.properties" -exec cp {} ../../build/{} \;)
+
+  mkdir -p build/javax/servlet/jsp/resources
+  cp src/share/dtd/jsp*.dtd build/javax/servlet/jsp/resources
+  cp src/share/dtd/jsp*.xsd build/javax/servlet/jsp/resources
+  cp src/share/dtd/web-jsp*.dtd build/javax/servlet/jsp/resources
+  cp src/share/dtd/web-jsp*.xsd build/javax/servlet/jsp/resources
+
+  fastjar -C build -c -m src/etc/manifest -f ${JARFILENAME} .
+}
diff --git a/recipes/servlet-api/servlet2.3-native_4.1.37.bb b/recipes/servlet-api/servlet2.3-native_4.1.37.bb
new file mode 100644
index 0000000000..c06f5f499c
--- /dev/null
+++ b/recipes/servlet-api/servlet2.3-native_4.1.37.bb
@@ -0,0 +1,4 @@
+require servlet2.3_${PV}.bb
+
+inherit java-native
+
diff --git a/recipes/servlet-api/servlet2.3_4.1.37.bb b/recipes/servlet-api/servlet2.3_4.1.37.bb
new file mode 100644
index 0000000000..6176161d3d
--- /dev/null
+++ b/recipes/servlet-api/servlet2.3_4.1.37.bb
@@ -0,0 +1,41 @@
+DESCRIPTION = "Servlet API 2.3 (from Tomcat 4.1)"
+LICENSE = "AL2.0"
+AUTHOR = "Apache Software Foundation"
+
+SRC_URI = "http://archive.apache.org/dist/tomcat/tomcat-4/v${PV}/src/apache-tomcat-${PV}-src.tar.gz"
+
+inherit java-library
+
+S = "${WORKDIR}/apache-tomcat-${PV}-src/servletapi"
+
+DEPENDS = "fastjar-native"
+
+# Value of implementation.revision in build.xml
+IMPL_REVISION = "1"
+
+JARFILENAME = "servlet-2.3.${IMPL_REVISION}.jar"
+ALTJARFILENAMES = "servlet-2.3.jar servlet2.3.jar"
+
+do_unpackpost() {
+  sed -i -e "s|@implementation.version@|${IMPL_REVISION}|" src/etc/manifest
+}
+
+addtask unpackpost after do_unpack before do_patch
+
+do_compile() {
+  mkdir -p build
+
+  javac -sourcepath src/share -d build `find src/share/javax -name \*.java`
+
+  # Copy extraneous files according to build.xml's compile task
+  (cd src/share && find . -name "*.properties" -exec cp {} ../../build/{} \;)
+
+  mkdir -p build/javax/servlet/resources
+  cp src/share/dtd/web-app*.dtd build/javax/servlet/resources
+
+  mkdir -p build/javax/servlet/jsp/resources
+  cp src/share/dtd/web-jsptaglibrary*.dtd build/javax/servlet/jsp/resources
+  cp src/share/dtd/jspxml.* build/javax/servlet/jsp/resources
+
+  fastjar -C build -c -m src/etc/manifest -f ${JARFILENAME} .
+}
diff --git a/recipes/servlet-api/servlet2.4_5.5.26.bb b/recipes/servlet-api/servlet2.4_5.5.26.bb
new file mode 100644
index 0000000000..c4af1abba7
--- /dev/null
+++ b/recipes/servlet-api/servlet2.4_5.5.26.bb
@@ -0,0 +1,38 @@
+DESCRIPTION = "Servlet API 2.4 (from Tomcat 5.5)"
+LICENSE = "AL2.0"
+AUTHOR = "Apache Software Foundation"
+
+SRC_URI = "http://archive.apache.org/dist/tomcat/tomcat-5/v${PV}/src/apache-tomcat-${PV}-src.tar.gz"
+
+S = "${WORKDIR}/apache-tomcat-${PV}-src/servletapi/jsr154"
+
+inherit java-library
+
+DEPENDS = "fastjar-native"
+
+# Value of implementation.revision in build.xml
+IMPL_REVISION = "1"
+
+JARFILENAME = "servlet-api-2.4.${IMPL_REVISION}.jar"
+ALTJARFILENAMES = "servlet-api-2.4.jar servlet-api.jar servlet2.4.jar"
+
+do_unpackpost() {
+  sed -i -e "s|2.3.@implementation.version@|2.4.${IMPL_REVISION}|" src/etc/manifest
+}
+
+addtask unpackpost after do_unpack before do_patch
+
+do_compile() {
+  mkdir -p build
+
+  javac -sourcepath src/share -d build `find src/share/javax -name \*.java`
+
+  # Copy extraneous files according to build.xml's compile task
+  (cd src/share && find . -name "*.properties" -exec cp {} ../../build/{} \;)
+
+  mkdir -p build/javax/servlet/resources
+  cp src/share/dtd/jsp*.dtd build/javax/servlet/resources
+  cp src/share/dtd/web-jsp*.dtd build/javax/servlet/resources
+
+  fastjar -C build -c -m src/etc/manifest -f ${JARFILENAME} .
+}