1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
|
DESCRIPTION = "Perl is a popular scripting language."
HOMEPAGE = "http://www.perl.org/"
SECTION = "devel"
LICENSE = "Artistic|GPL"
PRIORITY = "optional"
# We need gnugrep (for -I)
DEPENDS = "virtual/db perl-native grep-native"
PR = "r3"
# Major part of version
PVM = "5.8"
DEFAULT_PREFERENCE = "-1"
SRC_URI = "ftp://ftp.funet.fi/pub/CPAN/src/perl-${PV}.tar.gz \
file://Makefile.patch;patch=1 \
file://Makefile.SH.patch \
file://perl-dynloader.patch;patch=1 \
file://perl-moreconfig.patch;patch=1 \
file://generate-sh.patch;patch=1 \
file://53_debian_mod_paths.patch;patch=1 \
file://54_debian_perldoc-r.patch;patch=1 \
file://62_debian_cpan_definstalldirs.patch;patch=1 \
file://64_debian_enc2xs_inc.patch;patch=1 \
file://config.sh \
file://config.sh-32 \
file://config.sh-32-le \
file://config.sh-32-be \
file://config.sh-64 \
file://config.sh-64-le \
file://config.sh-64-be"
# Where to find the native perl
HOSTPERL = "${STAGING_BINDIR_NATIVE}/perl${PV}"
# Where to find .so files - use the -native versions not those from the target build
export PERLHOSTLIB = "${STAGING_DIR}/${BUILD_SYS}/lib/perl5/${PV}/${BUILD_ARCH}-${BUILD_OS}-thread-multi/"
do_configure() {
# Put a hostperl in staging - should probably be part of do_deploy for native
ln -sf ${HOSTPERL} ${STAGING_BINDIR_NATIVE}/hostperl
# Make hostperl in build directory be the native perl
cp -f ${HOSTPERL} hostperl
# This is silly - should just patch Makefile.SH directly
cd Cross
cp -f ${WORKDIR}/Makefile.SH.patch .
# Generate configuration
rm -f config.sh-${TARGET_ARCH}-${TARGET_OS}
touch config.sh-${TARGET_ARCH}-${TARGET_OS}
for i in ${WORKDIR}/config.sh \
${WORKDIR}/config.sh-${@siteinfo_get_bits(d)} \
${WORKDIR}/config.sh-${@siteinfo_get_bits(d)}-${@siteinfo_get_endianess(d)}; do
cat $i >> config.sh-${TARGET_ARCH}-${TARGET_OS}
done
# uclibc not checked with this version yet
# uclicb fixups
#for i in config.sh-*-linux; do
# a="`echo $i|sed -e 's,^config.sh-,,; s,-linux$,,'`"
# newfile="`echo $i|sed -e 's,-linux$,-linux-uclibc,g'`"
# cat $i | sed -e "s,${a}-linux,${a}-linux-uclibc,g; \
# s,d_sockatmark='define',d_sockatmark='undef',g;" > $newfile
#done
# Update some paths in the configuration
sed -i -e 's,@DESTDIR@,${D},g' config.sh-${TARGET_ARCH}-${TARGET_OS}
sed -i -e 's,@ARCH@,${TARGET_ARCH}-${TARGET_OS},g' config.sh-${TARGET_ARCH}-${TARGET_OS}
sed -i -e "s%/usr/include/%${STAGING_INCDIR}/%g" config.sh-${TARGET_ARCH}-${TARGET_OS}
if test "${MACHINE}" != "native"; then
# These are strewn all over the source tree
for foo in `grep -I -m1 \/usr\/include\/.*\\.h ${WORKDIR}/* -r | cut -f 1 -d ":"` ; do
echo Fixing: $foo
sed -e "s%/usr/include/%${STAGING_INCDIR}/%g" -i $foo
done
fi
rm -f config
echo "ARCH = ${TARGET_ARCH}" > config
echo "OS = ${TARGET_OS}" >> config
oe_runmake patch
}
do_compile() {
if test "${MACHINE}" != "native"; then
sed -i -e 's|/usr/include|${STAGING_INCDIR}|g' ext/Errno/Errno_pm.PL
fi
cd Cross
oe_runmake perl LD="${TARGET_SYS}-gcc"
}
do_install() {
oe_runmake install
# Add versioned perl interpereter
ln -sf perl${PV} ${D}/usr/bin/perl
# Fix up versioned directories
mv ${D}/${libdir}/perl/${PVM} ${D}/${libdir}/perl/${PV}
mv ${D}/${datadir}/perl/${PVM} ${D}/${datadir}/perl/${PV}
ln -sf ${PV} ${D}/${libdir}/perl/${PVM}
ln -sf ${PV} ${D}/${datadir}/perl/${PVM}
# Fix up shared library
mv -f ${D}/${libdir}/perl/${PV}/CORE/libperl.so ${D}/${libdir}/libperl.so.${PV}
ln -sf libperl.so.${PV} ${D}/${libdir}/libperl.so.5
# Fix up installed configuration
if test "${MACHINE}" != "native"; then
sed -i -e "s,${D},,g" \
-e "s,-isystem${STAGING_INCDIR} ,,g" \
-e "s,${STAGING_LIBDIR},${libdir},g" \
-e "s,${STAGING_INCDIR},${includedir},g" \
${D}/${libdir}/perl/${PV}/Config_heavy.pl
fi
}
do_stage() {
install -d ${STAGING_DIR}/${HOST_SYS}/perl/
install config.sh ${STAGING_DIR}/${HOST_SYS}/perl/
}
PACKAGES = "perl-dbg perl perl-misc perl-lib perl-dev perl-pod"
FILES_${PN} = "${bindir}/perl ${bindir}/perl${PV}"
FILES_${PN}-lib = "${libdir}/libperl.so* ${libdir}/perl/${PVM} ${datadir}/perl/${PVM}"
FILES_${PN}-dev = "${libdir}/perl/${PV}/CORE"
FILES_${PN}-pod = "${datadir}/perl/${PV}/pod"
FILES_perl-misc = "${bindir}/*"
FILES_${PN}-dbg += "${libdir}/perl/${PV}/auto/*/.debug \
${libdir}/perl/${PV}/auto/*/*/.debug \
${libdir}/perl/${PV}/auto/*/*/*/.debug \
${datadir}/perl/${PV}/auto/*/.debug \
${datadir}/perl/${PV}/auto/*/*/.debug \
${datadir}/perl/${PV}/auto/*/*/*/.debug \
${libdir}/perl/${PV}/CORE/.debug"
DEBIAN_NOAUTONAME_perl-lib = "1"
RPROVIDES_perl-lib = "perl-lib"
# Create a perl-modules package recommending all the other perl
# packages (actually the non modules packages and not created too)
ALLOW_EMPTY_perl-modules = "1"
PACKAGES_append = " perl-modules "
RRECOMMENDS_perl-modules = "${@bb.data.getVar('PACKAGES', d, 1).replace('perl-modules ', '').replace('perl-dbg ', '').replace('perl-misc ', '').replace('perl-dev ', '').replace('perl-pod ', '')}"
python populate_packages_prepend () {
libdir = bb.data.expand('${libdir}/perl/${PV}', d)
do_split_packages(d, libdir, 'auto/(.*)(?!\.debug)/', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
do_split_packages(d, libdir, '(.*)\.(pm|pl)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
datadir = bb.data.expand('${datadir}/perl/${PV}', d)
do_split_packages(d, datadir, 'auto/(.*)(?!\.debug)/', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
do_split_packages(d, datadir, '(.*)\.(pm|pl)', 'perl-module-%s', 'perl module %s', recursive=True, allow_dirs=False, match_path=True)
}
require perl-rdepends_${PV}.inc
# To create/update the perl-rdepends_${PV}.inc use this piece of ugly script (modified for your arch/paths etc):
# daka@DaKa2:/home/slug/slugos/tmp/work/perl-5.8.7-r14/install$ egrep -r "use|require" * | grep ";$" | egrep ".pm:use |.pm:require " | grep -v v5.6.0 | grep -v 5.00 | grep -v \$module | sed -e "s, \+, ,g" | cut -f1,2 -d" " | sed -e "s,;, ,g" | sed -e "s,(), ,g" | sed -e "s,::,-,g" | sort | uniq | tr [:upper:] [:lower:] | sed -e "s,/[^ ]\+ , += \"perl-module-,g" | sed -e "s, \?$, \",g" | sed -e "s,_,-,g" | sed -e "s,^,RDEPENDS_,g" | sed -e "s,armeb-linux,\$\{TARGET_ARCH\}-\$\{TARGET_OS\},g" | egrep -v "perl-module-5|perl-module-tk|perl-module-mac-internetconfig|perl-module-ndbm-file|perl-module-html-treebuilder|perl-module-lwp-simple|perl-module-vms-filespec|perl-module-fcgi|perl-module-vms-stdio|perl-module-mac-buildtools" > /home/slug/openembedded/packages/perl/perl-rdepends_5.8.7.inc
# Some additional dependencies that the above doesn't manage to figure out
DEPENDS_perl-module-math-bigint += "perl-module-math-bigint-calc "
DEPENDS_perl-module-math-bigint-calc += "perl-module-integer "
require perl-rprovides.inc
PARALLEL_MAKE = ""
|
