alsa: added 1.0.14 from Poky

4 files changed, 134 insertions, 0 deletions

diff --git a/packages/alsa/alsa-lib/unbreak_plugindir.patch b/packages/alsa/alsa-lib/unbreak_plugindir.patch
new file mode 100644
index 0000000000..7d13166809
--- /dev/null
+++ b/packages/alsa/alsa-lib/unbreak_plugindir.patch
@@ -0,0 +1,12 @@
+diff -Nur alsa-lib-1.0.14.orig/configure.in alsa-lib-1.0.14/configure.in
+--- alsa-lib-1.0.14.orig/configure.in	2007-05-31 03:05:13.000000000 -0500
++++ alsa-lib-1.0.14/configure.in	2007-08-18 13:05:49.000000000 -0500
+@@ -93,7 +93,7 @@
+     esac
+     plugindir="$dir/$PACKAGE"
+ fi
+-AC_DEFINE_UNQUOTED(ALSA_PLUGIN_DIR, "plugindir", [directory containing ALSA add-on modules])
++AC_DEFINE_UNQUOTED(ALSA_PLUGIN_DIR, "${plugindir}", [directory containing ALSA add-on modules])
+ ALSA_PLUGIN_DIR="$plugindir"
+ AC_SUBST(ALSA_PLUGIN_DIR)
+ 
diff --git a/packages/alsa/alsa-lib_1.0.14.bb b/packages/alsa/alsa-lib_1.0.14.bb
new file mode 100644
index 0000000000..de805b9a4b
--- /dev/null
+++ b/packages/alsa/alsa-lib_1.0.14.bb
@@ -0,0 +1,44 @@
+DESCRIPTION = "Alsa sound library"
+HOMEPAGE = "http://www.alsa-project.org"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+
+PR = "r1"
+
+# configure.in sets -D__arm__ on the command line for any arm system
+# (not just those with the ARM instruction set), this should be removed,
+# (or replaced by a permitted #define).
+#FIXME: remove the following
+ARM_INSTRUCTION_SET = "arm"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/alsa-lib-${PV}.tar.bz2 \
+           file://fix-tstamp-declaration.patch;patch=1 \
+           file://unbreak_plugindir.patch;patch=1"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-cards=pdaudiocf --with-oss=yes"
+
+do_stage () {
+	oe_libinstall -so -C src libasound ${STAGING_LIBDIR}/
+	install -d ${STAGING_INCDIR}/alsa/sound
+	install -m 0644 include/*.h ${STAGING_INCDIR}/alsa/
+	install -m 0644 include/sound/ainstr*.h ${STAGING_INCDIR}/alsa/sound/
+	install -d ${STAGING_DATADIR}/aclocal
+	install -m 0644 utils/alsa.m4 ${STAGING_DATADIR}/aclocal/
+}
+
+PACKAGES =+ "alsa-server libasound alsa-conf-base alsa-conf alsa-doc alsa-dev"
+FILES_${PN}-dbg += "${libdir}/alsa-lib/*/.debu*"
+FILES_libasound = "${libdir}/libasound.so.*"
+FILES_alsa-server = "${bindir}/*"
+FILES_alsa-conf = "${datadir}/alsa/"
+FILES_alsa-dev += "${libdir}/pkgconfig/ /usr/include/ ${datadir}/aclocal/*"
+FILES_alsa-conf-base = "\
+${datadir}/alsa/alsa.conf \
+${datadir}/alsa/cards/aliases.conf \
+${datadir}/alsa/pcm/default.conf \
+${datadir}/alsa/pcm/dmix.conf \
+${datadir}/alsa/pcm/dsnoop.conf"
+
+RDEPENDS_libasound = "alsa-conf-base"
diff --git a/packages/alsa/alsa-oss_1.0.14.bb b/packages/alsa/alsa-oss_1.0.14.bb
new file mode 100644
index 0000000000..b11947e86a
--- /dev/null
+++ b/packages/alsa/alsa-oss_1.0.14.bb
@@ -0,0 +1,17 @@
+DESCRIPTION = "Alsa OSS Compatibility Package"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/oss-lib/alsa-oss-${PV}.tar.bz2"
+
+inherit autotools 
+
+do_configure_prepend () {
+	touch NEWS README AUTHORS ChangeLog
+}
+
+do_stage () {
+	oe_libinstall -C alsa -a -so libaoss ${STAGING_LIBDIR}
+	oe_libinstall -C alsa -a -so libalsatoss ${STAGING_LIBDIR}
+}
diff --git a/packages/alsa/alsa-utils_1.0.14.bb b/packages/alsa/alsa-utils_1.0.14.bb
new file mode 100644
index 0000000000..240b995e7b
--- /dev/null
+++ b/packages/alsa/alsa-utils_1.0.14.bb
@@ -0,0 +1,61 @@
+DESCRIPTION = "ALSA Utilities"
+HOMEPAGE = "http://www.alsa-project.org"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib ncurses"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2"
+
+# lazy hack. needs proper fixing in gettext.m4, see
+# http://bugs.openembedded.org/show_bug.cgi?id=2348
+# please close bug and remove this comment when properly fixed
+#
+EXTRA_OECONF_linux-uclibc = "--disable-nls"
+EXTRA_OECONF_linux-uclibcgnueabi = "--disable-nls"
+
+inherit autotools
+
+# This are all packages that we need to make. Also, the now empty alsa-utils
+# ipk depend on them.
+
+PACKAGES += "\
+             alsa-utils-alsamixer \
+             alsa-utils-midi \
+             alsa-utils-aplay \
+             alsa-utils-amixer \
+             alsa-utils-aconnect \
+             alsa-utils-iecset \
+             alsa-utils-speakertest \
+             alsa-utils-aseqnet \
+             alsa-utils-aseqdump \
+             alsa-utils-alsaconf \
+             alsa-utils-alsactl "
+
+# We omit alsaconf, because
+# a) this is a bash script
+# b) it creates config files not suitable for OE-based distros
+
+FILES_${PN} = ""
+FILES_alsa-utils-aplay       = "${bindir}/aplay ${bindir}/arecord"
+FILES_alsa-utils-amixer      = "${bindir}/amixer"
+FILES_alsa-utils-alsamixer   = "${bindir}/alsamixer"
+FILES_alsa-utils-speakertest = "${bindir}/speaker-test ${datadir}/sounds/alsa/ ${datadir}/alsa/"
+FILES_alsa-utils-midi        = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi"
+FILES_alsa-utils-aconnect    = "${bindir}/aconnect"
+FILES_alsa-utils-aseqnet     = "${bindir}/aseqnet"
+FILES_alsa-utils-iecset      = "${bindir}/iecset"
+FILES_alsa-utils-alsactl     = "${sbindir}/alsactl"
+FILES_alsa-utils-aseqdump    = "${bindir}/aseqdump"
+FILES_alsa-utils-alsaconf    = "${sbindir}/alsaconf"
+
+DESCRIPTION_alsa-utils-aplay        = "play (and record) sound files via ALSA"
+DESCRIPTION_alsa-utils-amixer       = "command-line based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-alsamixer    = "ncurses based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-speakertest  = "ALSA surround speaker test utility"
+DESCRIPTION_alsa-utils-midi         = "miscalleanous MIDI utilities for ALSA"
+DESCRIPTION_alsa-utils-aconnect     = "ALSA sequencer connection manager"
+DESCRIPTION_alsa-utils-aseqnet      = "network client/server on ALSA sequencer"
+DESCRIPTION_alsa-utils-alsactl      = "saves/restores ALSA-settings in /etc/asound.state"
+DESCRIPTION_alsa-utils-alsaconf     = "a bash script that creates ALSA configuration files"
+
+ALLOW_EMPTY_alsa-utils = "1"