fltk: add 1.1.4 + fldevice patch, needed for giac 0.6.x

1 files changed, 43 insertions, 0 deletions

diff --git a/packages/fltk/fltk_1.1.4.bb b/packages/fltk/fltk_1.1.4.bb
new file mode 100644
index 0000000000..08ce8080cb
--- /dev/null
+++ b/packages/fltk/fltk_1.1.4.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "FLTK is a cross-platform C++ GUI toolkit"
+HOMEPAGE = "http://www.fltk.org"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "LGPL"
+DEPENDS = "jpeg libpng zlib"
+
+PR = "FLDevice-r0"
+
+SRC_URI = "ftp://ftp-fourier.ujf-grenoble.fr/xcas/devel/sources/fltk-${PV}-device.tar.gz"
+
+S = "${WORKDIR}/fltk-${PV}-Fl_Device"
+
+inherit autotools binconfig lib_package
+
+EXTRA_OECONF = "--enable-shared --disable-gl --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR}"
+
+do_configure() {
+        oe_runconf
+}
+
+do_install () {
+        oe_runmake prefix="${D}${prefix}" \
+                bindir="${D}${bindir}" \
+                libdir="${D}${libdir}" \
+                includedir="${D}${includedir}" \
+                install
+}
+
+do_stage() {
+        oe_runmake install prefix=${STAGING_DIR} \
+               bindir=${STAGING_BINDIR} \
+               includedir=${STAGING_INCDIR} \
+               libdir=${STAGING_LIBDIR} \
+               datadir=${STAGING_DATADIR}
+}
+
+python populate_packages_prepend () {
+        if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
+                bb.data.setVar('PKG_${PN}', 'libfltk${PV}', d)
+}
+
+LEAD_SONAME = "libfltk.so"