Merge bk://oe-devel.bkbits.net/openembedded

into bkbits.net:/repos/n/nslu2-linux/openembedded

2005/02/21 17:35:27-06:00 ti.com!kergoth
Kill the ipkg paths patch, since its busted.

2005/02/21 17:33:13-06:00 ti.com!kergoth
Fix sbindir in native.bbclass and cross.bbclass.  Thanks to Jordan Crouse for reporting.

2005/02/21 17:13:19-06:00 ti.com!kergoth
Add the paths patch to ipkg which fixes it to no longer hardcode the '/usr/lib/ipkg' path, which I forgot to check in from the previous commit.

2005/02/21 17:09:46-06:00 ti.com!kergoth
Merge oe-devel@oe-devel.bkbits.net:openembedded
into odin.sc.ti.com:/home/kergoth/code/user/oe/openembedded

2005/02/21 17:09:03-06:00 ti.com!kergoth
Run a sed script against our packages to fix some hardcoded target path
references.  As always when I do things like this, if packages you maintain
were touched by this, please do a sanity check to ensure the sed script didn't
run wild.

2005/02/21 15:49:47-06:00 ti.com!kergoth
Use a HOTPLUG variable to manage which hotplug you prefer, to ensure that hotplug is still included in task-bootstrap even if you dont set DISTRO.

BKrev: 421b2b63X5eoMcSrC7pVcptXK-iFKg

1 files changed, 99 insertions, 0 deletions

diff --git a/packages/apt/apt-package.inc b/packages/apt/apt-package.inc
index e69de29bb2..a3ccc82e01 100644
--- a/packages/apt/apt-package.inc
+++ b/packages/apt/apt-package.inc
@@ -0,0 +1,99 @@
+apt-manpages="doc/apt-cache.8 \
+	      doc/apt-cdrom.8 \
+	      doc/apt-config.8 \
+	      doc/apt-get.8 \
+	      doc/apt.8 \
+	      doc/apt.conf.5 \
+	      doc/apt_preferences.5 \
+	      doc/fr/apt-cache.fr.8 \
+	      doc/fr/apt-cdrom.fr.8 \
+	      doc/fr/apt-config.fr.8 \
+	      doc/fr/apt-get.fr.8 \
+	      doc/fr/apt.conf.fr.5 \
+	      doc/fr/apt_preferences.fr.5 \
+	      doc/fr/sources.list.fr.5 \
+	      doc/es/apt.es.8 \
+	      doc/es/apt-cache.es.8 \
+	      doc/es/apt-cdrom.es.8 \
+	      doc/es/apt-config.es.8 \
+	      doc/es/apt-get.es.8 \
+	      doc/es/apt.conf.es.5 \
+	      doc/es/apt_preferences.es.5 \
+	      doc/es/sources.list.es.5 \
+	      doc/pt_BR/apt_preferences.pt_BR.5 \
+	      doc/ja/apt-cache.ja.8 \
+	      doc/ja/apt-cdrom.ja.8 \
+	      doc/ja/apt-get.ja.8 \
+	      doc/ja/apt.conf.ja.5 \
+	      doc/sources.list.5"
+apt-utils-manpages="doc/apt-extracttemplates.1 \
+		    doc/apt-sortpkgs.1 \
+		    doc/fr/apt-extracttemplates.fr.1 \
+		    doc/fr/apt-sortpkgs.fr.1"
+#		    doc/fr/apt-ftparchive.fr.1
+#		    doc/apt-ftparchive.1
+
+def get_files_apt_doc(d, bb, manpages):
+	import re
+	manpages = re.sub(r'\bdoc/(\S+)/(\S+)\.\1\.(.)\b', r'${mandir}/\1/man\3/\2.\3', manpages)
+	manpages = re.sub(r'\bdoc/(\S+)\.(.)\b', r'${mandir}/man\3/\1.\3', manpages)
+	return manpages
+
+def get_commands_apt_doc(d, bb, manpages):
+	import os
+	s = list()
+	__dir_cache__ = list()
+	for m in manpages.split():
+		dest = get_files_apt_doc(d, bb, m)
+		dir = os.path.dirname(dest)
+		if not dir in __dir_cache__:
+			s.append("install -d ${D}/%s" % dir)
+			__dir_cache__.append(dir)
+		s.append("install -m 0644 %s ${D}/%s" % (m, dest))
+	return "\n".join(s)
+
+PACKAGES += "${PN}-utils ${PN}-utils-doc"
+FILES_${PN} = "${bindir}/apt-cdrom ${bindir}/apt-get \
+	       ${bindir}/apt-config ${bindir}/apt-cache \
+	       ${libdir}/apt ${libdir}/libapt*.so.* \
+	       ${localstatedir} ${sysconfdir} \
+	       ${libdir}/dpkg"
+FILES_${PN}-utils = "${bindir}/apt-sortpkgs ${bindir}/apt-extracttemplates"
+FILES_${PN}-doc = "${@get_files_apt_doc(d, bb, bb.data.getVar('apt-manpages', d, 1))} \
+		   ${docdir}/apt"
+FILES_${PN}-utils-doc = "${@get_files_apt_doc(d, bb, bb.data.getVar('apt-utils-manpages', d, 1))}"
+FILES_${PN}-dev = "${libdir}/libapt*.so"
+
+do_install () {
+	${@get_commands_apt_doc(d, bb, bb.data.getVar('apt-manpages', d, 1))}
+	${@get_commands_apt_doc(d, bb, bb.data.getVar('apt-utils-manpages', d, 1))}
+	install -d ${D}/${bindir}
+	install -m 0755 bin/apt-cdrom ${D}/${bindir}/
+	install -m 0755 bin/apt-get ${D}/${bindir}/
+	install -m 0755 bin/apt-config ${D}/${bindir}/
+	install -m 0755 bin/apt-cache ${D}/${bindir}/
+
+	install -m 0755 bin/apt-sortpkgs ${D}/${bindir}/
+	install -m 0755 bin/apt-extracttemplates ${D}/${bindir}/
+
+	oe_libinstall -so -C bin libapt-pkg--6 ${D}/${libdir}/
+	ln -sf libapt-pkg--6.so ${D}/${libdir}/libapt-pkg.so
+	oe_libinstall -so -C bin libapt-inst--6 ${D}/${libdir}/
+	ln -sf libapt-inst--6.so ${D}/${libdir}/libapt-inst.so
+
+	install -d ${D}/${libdir}/apt/methods
+	install -m 0755 bin/methods/* ${D}/${libdir}/apt/methods/
+
+	install -d ${D}/${libdir}/dpkg/methods/apt
+	install -m 0644 dselect/desc.apt ${D}/${libdir}/dpkg/methods/apt/ 
+	install -m 0644 dselect/names ${D}/${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/install ${D}/${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/setup ${D}/${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/update ${D}/${libdir}/dpkg/methods/apt/ 
+
+	install -d ${D}/${sysconfdir}/apt
+	install -d ${D}/${localstatedir}/lib/apt/lists/partial
+	install -d ${D}/${localstatedir}/cache/apt/archives/partial
+	install -d ${D}/${docdir}/apt/examples
+	install -m 0644 doc/examples/* ${D}/${docdir}/apt/examples/
+}