blob: 6194d4f8da498f0ab0d4bedbd5477985693b5d08 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# linux-yocto-custom.bb:
#
# An example kernel recipe that uses the linux-yocto and oe-core
# kernel classes to apply a subset of yocto kernel management to git
# managed kernel repositories.
#
# To use linux-yocto-custom in your layer, copy this recipe (optionally
# rename it as well) and modify it appropriately for your machine. i.e.:
#
# COMPATIBLE_MACHINE_yourmachine = "yourmachine"
#
# You must also provide a Linux kernel configuration. The most direct
# method is to copy your .config to files/defconfig in your layer,
# in the same directory as the copy (and rename) of this recipe and
# add file://defconfig to your SRC_URI.
#
# To use the yocto kernel tooling to generate a BSP configuration
# using modular configuration fragments, see the yocto-bsp and
# yocto-kernel tools documentation.
#
# Warning:
#
# Building this example without providing a defconfig or BSP
# configuration will result in build or boot errors. This is not a
# bug.
#
#
# Notes:
#
# patches: patches can be merged into to the source git tree itself,
# added via the SRC_URI, or controlled via a BSP
# configuration.
#
# defconfig: When a defconfig is provided, the linux-yocto configuration
# uses the filename as a trigger to use a 'allnoconfig' baseline
# before merging the defconfig into the build.
#
# If the defconfig file was created with make_savedefconfig,
# not all options are specified, and should be restored with their
# defaults, not set to 'n'. To properly expand a defconfig like
# this, specify: KCONFIG_MODE="--alldefconfig" in the kernel
# recipe.
#
# example configuration addition:
# SRC_URI += "file://smp.cfg"
# example patch addition (for kernel v4.x only):
# SRC_URI += "file://0001-linux-version-tweak.patch"
# example feature addition (for kernel v4.x only):
# SRC_URI += "file://feature.scc"
#
inherit kernel
require recipes-kernel/linux/linux-yocto.inc
# Override SRC_URI in a copy of this recipe to point at a different source
# tree if you do not want to build from Linus' tree.
SRC_URI = "git://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git;protocol=git;nocheckout=1;name=machine"
LINUX_VERSION ?= "4.2"
LINUX_VERSION_EXTENSION_append = "-custom"
# Modify SRCREV to a different commit hash in a copy of this recipe to
# build a different release of the Linux kernel.
# tag: v4.2 64291f7db5bd8150a74ad2036f1037e6a0428df2
SRCREV_machine="64291f7db5bd8150a74ad2036f1037e6a0428df2"
PV = "${LINUX_VERSION}+git${SRCPV}"
# Override COMPATIBLE_MACHINE to include your machine in a copy of this recipe
# file. Leaving it empty here ensures an early explicit build failure.
COMPATIBLE_MACHINE = "(^$)"
|
