1 files changed, 53 insertions, 0 deletions
diff --git a/meta/recipes-support/libpcre/libpcre_8.32.bb b/meta/recipes-support/libpcre/libpcre_8.32.bb
new file mode 100644
index 0000000000..b6847e8217
--- /dev/null
+++ b/meta/recipes-support/libpcre/libpcre_8.32.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "The PCRE library is a set of functions that implement regular \
+expression pattern matching using the same syntax and semantics as Perl 5. PCRE \
+has its own native API, as well as a set of wrapper functions that correspond \
+to the POSIX regular expression API."
+SUMMARY = "Perl Compatible Regular Expressions"
+HOMEPAGE = "http://www.pcre.org"
+SECTION = "devel"
+PR = "r0"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=115e2bee152e2e23e838a29136094877"
+SRC_URI = "${SOURCEFORGE_MIRROR}/project/pcre/pcre/${PV}/pcre-${PV}.tar.bz2 \
+           file://pcre-cross.patch \
+           file://fix-pcre-name-collision.patch"
+
+SRC_URI[md5sum] = "62f02a76bb57a40bc66681760ed511d5"
+SRC_URI[sha256sum] = "a913fb9bd058ef380a2d91847c3c23fcf98e92dc3b47cd08a53c021c5cde0f55"
+
+S = "${WORKDIR}/pcre-${PV}"
+
+PROVIDES = "pcre"
+DEPENDS = "bzip2 zlib readline"
+
+inherit autotools binconfig
+
+PARALLEL_MAKE = ""
+
+CFLAGS_append = " -D_REENTRANT"
+CXXFLAGS_powerpc += "-lstdc++"
+EXTRA_OECONF = " --with-link-size=2 --enable-newline-is-lf --with-match-limit=10000000 --enable-rebuild-chartables --enable-utf8"
+
+do_compile () {
+	# stop libtool from trying to link with host libraries - fix from #33
+	# this resolve build problem on amd64 - #1015
+	if [ -e ${S}/${HOST_SYS}-libtool ] ; then
+		sed -i 's:-L\$:-L${STAGING_LIBDIR} -L\$:' ${S}/${HOST_SYS}-libtool
+	else
+		ln -sf ${S}/libtool ${S}/${HOST_SYS}-libtool
+		sed -i 's:-L\$:-L${STAGING_LIBDIR} -L\$:' ${S}/${HOST_SYS}-libtool
+	fi
+
+	# The generation of dftables can lead to timestamp problems with ccache
+	# because the generated config.h seems newer.  It is sufficient to ensure that the
+	# attempt to build dftables inside make will actually work (foo_FOR_BUILD is
+	# only used for this).
+	oe_runmake CC_FOR_BUILD="${BUILD_CC}" CFLAGS_FOR_BUILD="-DLINK_SIZE=2 -I${S}/include" LINK_FOR_BUILD="${BUILD_CC} -L${S}/lib"
+}
+
+python populate_packages_prepend () {
+    pcre_libdir = d.expand('${libdir}')
+    do_split_packages(d, pcre_libdir, '^lib(.*)\.so\.+', 'lib%s', 'libpcre %s library', extra_depends='', allow_links=True, prepend=True)
+}
+
+BBCLASSEXTEND = "native"