Initial population

git-svn-id: https://svn.o-hand.com/repos/poky@1 311d38ba-8fff-0310-9ca6-ca027cbcb966

1 files changed, 72 insertions, 0 deletions

diff --git a/openembedded/classes/image_ipk.bbclass b/openembedded/classes/image_ipk.bbclass
new file mode 100644
index 0000000000..5fdd340673
--- /dev/null
+++ b/openembedded/classes/image_ipk.bbclass
@@ -0,0 +1,72 @@
+inherit rootfs_ipk
+
+# Images are generally built explicitly, do not need to be part of world.
+EXCLUDE_FROM_WORLD = "1"
+
+USE_DEVFS ?= "0"
+
+DEPENDS += "makedevs-native"
+
+def get_image_deps(d):
+	import bb
+	str = ""
+	for type in (bb.data.getVar('IMAGE_FSTYPES', d, 1) or "").split():
+		deps = bb.data.getVar('IMAGE_DEPENDS_%s' % type, d) or ""
+		if deps:
+			str += " %s" % deps
+	return str
+
+DEPENDS += "${@get_image_deps(d)}"
+
+IMAGE_DEVICE_TABLE ?= "${@bb.which(bb.data.getVar('BBPATH', d, 1), 'files/device_table-minimal.txt')}"
+IMAGE_POSTPROCESS_COMMAND ?= ""
+
+# Must call real_do_rootfs() from inside here, rather than as a separate
+# task, so that we have a single fakeroot context for the whole process.
+fakeroot do_rootfs () {
+	set -x
+	rm -rf ${IMAGE_ROOTFS}
+
+	if [ "${USE_DEVFS}" != "1" ]; then
+		mkdir -p ${IMAGE_ROOTFS}/dev
+		makedevs -r ${IMAGE_ROOTFS} -D ${IMAGE_DEVICE_TABLE}
+	fi
+
+	real_do_rootfs
+
+	insert_feed_uris	
+
+	rm -f ${IMAGE_ROOTFS}${libdir}/ipkg/lists/oe
+	
+	${IMAGE_PREPROCESS_COMMAND}
+		
+	export TOPDIR=${TOPDIR}
+
+	for type in ${IMAGE_FSTYPES}; do
+		if test -z "$FAKEROOTKEY"; then
+			fakeroot -i ${TMPDIR}/fakedb.image bbimage -t $type -e ${FILE}
+		else
+			bbimage -n "${IMAGE_NAME}" -t "$type" -e "${FILE}"
+		fi
+	done
+
+	${IMAGE_POSTPROCESS_COMMAND}
+}
+
+insert_feed_uris () {
+	
+	echo "Building feeds for [${DISTRO}].."
+		
+	for line in ${FEED_URIS}
+	do
+		# strip leading and trailing spaces/tabs, then split into name and uri
+		line_clean="`echo "$line"|sed 's/^[ \t]*//;s/[ \t]*$//'`"
+		feed_name="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\1/p'`"
+		feed_uri="`echo "$line_clean" | sed -n 's/\(.*\)##\(.*\)/\2/p'`"					
+		
+		echo "Added $feed_name feed with URL $feed_uri"
+		
+		# insert new feed-sources
+		echo "src/gz $feed_name $feed_uri" >> ${IMAGE_ROOTFS}/etc/ipkg/${feed_name}-feed.conf
+	done			
+}