prserv: add LOCALCOUNT to AUTOINCs migration feature

- use migrate_localcount.bbclass to generate AUTOINC entries
which are exported to LOCALCOUNT_DUMPFILE
- import the generated AUTOINC entries
- one can migrate LOCALCOUNT to AUTOINC by executing:
    bitbake-prserv-tool migrate_localcount

[YOCTO #3071]

Signed-off-by: Constantin Musca <constantinx.musca@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

2 files changed, 48 insertions, 0 deletions

diff --git a/meta/classes/migrate_localcount.bbclass b/meta/classes/migrate_localcount.bbclass
new file mode 100644
index 0000000000..59f14e8a34
--- /dev/null
+++ b/meta/classes/migrate_localcount.bbclass
@@ -0,0 +1,47 @@
+PRSERV_DUMPDIR ??= "${LOG_DIR}/db"
+LOCALCOUNT_DUMPFILE ??= "${PRSERV_DUMPDIR}/prserv-localcount-exports.inc"
+
+python migrate_localcount_handler () {
+    import bb.event
+    if not e.data:
+        return
+
+    if isinstance(e, bb.event.RecipeParsed):
+        pv = e.data.getVar('PV', True)
+        if not 'AUTOINC' in pv:
+            return
+
+        localcounts = bb.persist_data.persist('BB_URI_LOCALCOUNT', e.data)
+        pn = e.data.getVar('PN', True)
+        revs = localcounts.get_by_pattern('%%-%s_rev' % pn)
+        counts = localcounts.get_by_pattern('%%-%s_count' % pn)
+        if not revs or not counts:
+            return
+
+        srcrev = bb.fetch2.get_srcrev(e.data)
+        bpv = pv[:pv.find(srcrev)]
+
+        if len(revs) != len(counts):
+            bb.warn("The number of revs and localcounts don't match in %s" % pn)
+            return
+
+        version = 'AUTOINC-%s-%s' % (pn, bpv)
+        pkgarch = e.data.getVar('PACKAGE_ARCH', True)
+        value = max(int(count) for count in counts)
+
+        if len(revs) == 1:
+            if srcrev != ('AUTOINC+%s' % revs[0]):
+                value += 1
+        else:
+            value += 1
+
+        bb.utils.mkdirhier(e.data.getVar('PRSERV_DUMPDIR', True))
+        df = e.data.getVar('LOCALCOUNT_DUMPFILE', True)
+        flock = bb.utils.lockfile("%s.lock" % df)
+        with open(df, 'a') as fd:
+            fd.write('PRAUTO$%s$%s$%s = "%s"\n' %
+                    (version, pkgarch, srcrev, str(value)))
+        bb.utils.unlockfile(flock)
+}
+
+addhandler migrate_localcount_handler
diff --git a/meta/conf/migrate_localcount.conf b/meta/conf/migrate_localcount.conf
new file mode 100644
index 0000000000..e486e03e5f
--- /dev/null
+++ b/meta/conf/migrate_localcount.conf
@@ -0,0 +1 @@
+INHERIT += "migrate_localcount"