Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta/recipes-extended/xinetd/xinetd_2.3.14.bb b/meta/recipes-extended/xinetd/xinetd_2.3.14.bb
new file mode 100644
index 0000000000..122be2c18d
--- /dev/null
+++ b/meta/recipes-extended/xinetd/xinetd_2.3.14.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "Highly configurable, modular and secure inetd"
+HOMEPAGE = "http://www.xinetd.org"
+
+# xinetd is a BSD-like license
+LICENSE = "xinetd"
+LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=8ad8615198542444f84d28a6cf226dd8"
+
+DEPENDS = ""
+PR ="r0"
+
+SRC_URI = "http://www.xinetd.org/xinetd-${PV}.tar.gz \
+      file://xinetd.init \
+      file://xinetd.conf \
+      file://Various-fixes-from-the-previous-maintainer.patch \
+      file://Disable-services-from-inetd.conf-if-a-service-with-t.patch \
+      file://xinetd-should-be-able-to-listen-on-IPv6-even-in-ine.patch \
+      "
+
+inherit autotools update-rc.d
+
+INITSCRIPT_NAME = "xinetd"
+INITSCRIPT_PARAMS = "defaults"
+
+EXTRA_OECONF="--disable-nls"
+
+do_configure() {
+	# Looks like configure.in is broken, so we are skipping
+	# rebuilding configure and are just using the shipped one
+	oe_runconf
+}
+
+do_install() {
+	# Same here, the Makefile does some really stupid things,
+	# but since we only want two files why not override
+	# do_install from autotools and doing it ourselfs?
+	install -d "${D}/usr/sbin"
+	install -d "${D}/etc/init.d"
+	install -d "${D}/etc/xinetd.d"
+	install -m 644 "${WORKDIR}/xinetd.conf" "${D}/etc"
+	install -m 755 "${WORKDIR}/xinetd.init" "${D}/etc/init.d/xinetd"
+	install -m 755 "${S}/xinetd/xinetd" "${D}/usr/sbin"
+	install -m 755 "${S}/xinetd/itox" "${D}/usr/sbin"
+}
+
+CONFFILES_${PN} = "${sysconfdir}/xinetd.conf"