perl, perl-native: upgrade from 5.8.8 to 5.12.2

Deleted these patches as they are part of the upstream code now.
    deleted:    files/perl-5.8.8-gcc-4.2.patch
    deleted:    perl-5.12.2/makedepend-dash.patch
    deleted:    perl-5.12.2/native-no-gdbminc.patch
    deleted:    perl-5.12.2/54_debian_perldoc-r.patch

And rebased these patches to the newer source code
    modified:   files/letgcc-find-errno.patch
    modified:   perl-5.12.2/Makefile.patch
    modified:   perl-5.12.2/asm-pageh-fix.patch
    modified:   perl-5.12.2/native-nopacklist.patch
    modified:   perl-5.12.2/native-perlinc.patch
    modified:   perl-5.12.2/Makefile.SH.patch
    modified:   perl-5.12.2/installperl.patch
    modified:   perl-5.12.2/perl-dynloader.patch
    modified:   perl-5.12.2/09_fix_installperl.patch

get patches from debian perl ver 5.12.2-2
   the fakeroot.diff patch from debian is conflicting with our
   Makefile.SH.patch, hence disabling the fakeroot patch

use newly created config files
   Created with current milestone branch on qemu machines
      modified:   config.sh
      modified:   config.sh-32
      modified:   config.sh-64

get some changes from oe's perl 5.10.1 recipe
   fix the Makefile.SH.patch use miniperl instead of perl
   import a OE 5.10.1 patch: uudmap_cross

fix install issues
   add /usr in the destdir, so that perl gets installed in
   /usr/bin/perl and not in /bin/perl

   link /usr/lib/perl to /usr/lib/perl5 so that operations with
   /usr/lib/perl path in them keep on working.

Fix/Improve perl packaging
   avoid perl-module-module-* kind of packages
   recreate perl-rdepends_5.12.2.inc file with new set of packages
   import from oe perl-rprovide_5.12.2.inc
   combine all unicore perl scripts in one package
   simplify perl-lib
   reduce no of perl recipe packages greatly.

Add zlib to depedancy

fix buildtime host contamination

This also fixes [BUGID #384]

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>

1 files changed, 104 insertions, 0 deletions

diff --git a/meta/recipes-devtools/perl/perl-native_5.12.2.bb b/meta/recipes-devtools/perl/perl-native_5.12.2.bb
new file mode 100644
index 0000000000..824d5076f8
--- /dev/null
+++ b/meta/recipes-devtools/perl/perl-native_5.12.2.bb
@@ -0,0 +1,104 @@
+DESCRIPTION = "Perl is a popular scripting language."
+HOMEPAGE = "http://www.perl.org/"
+SECTION = "libs"
+LICENSE = "Artistic|GPL"
+LIC_FILES_CHKSUM = "file://Copying;md5=2b4c6ffbcfcbdee469f02565f253d81a \
+		    file://Artistic;md5=f921793d03cc6d63ec4b15e9be8fd3f8"
+DEPENDS = "virtual/db-native gdbm-native"
+PR = "r0"
+
+LIC_FILES_CHKSUM = "file://Copying;md5=2b4c6ffbcfcbdee469f02565f253d81a \
+                    file://Artistic;md5=f921793d03cc6d63ec4b15e9be8fd3f8"
+
+SRC_URI = "http://ftp.funet.fi/pub/CPAN/src/perl-${PV}.tar.gz \
+           file://Configure-multilib.patch;patch=1 \
+           file://perl-configpm-switch.patch;patch=1 \
+           file://native-nopacklist.patch;patch=1 \
+           file://native-perlinc.patch;patch=1"
+
+SRC_URI[md5sum] = "af2df531d46b77fdf0d97eecb03eddb2"
+SRC_URI[sha256sum] = "cf888340021d5a2d1238bbd9b8b55aaf420a848d46e4d317cb8567f86ceb1022"
+
+S = "${WORKDIR}/perl-${PV}"
+
+inherit native
+
+do_configure () {
+	./Configure \
+		-Dcc="${CC}" \
+		-Dcflags="${CFLAGS}" \
+		-Dldflags="${LDFLAGS}" \
+		-Dcf_by="Open Embedded" \
+		-Dprefix=${prefix} \
+		-Dvendorprefix=${prefix} \
+		-Dvendorprefix=${prefix} \
+		-Dsiteprefix=${prefix} \
+		\
+		-Dprivlib=${STAGING_LIBDIR}/perl/${PV} \
+		-Darchlib=${STAGING_LIBDIR}/perl/${PV} \
+		-Dvendorlib=${STAGING_LIBDIR}/perl/${PV} \
+		-Dvendorarch=${STAGING_LIBDIR}/perl/${PV} \
+		-Dsitelib=${STAGING_LIBDIR}/perl/${PV} \
+		-Dsitearch=${STAGING_LIBDIR}/perl/${PV} \
+		\
+		-Duseshrplib \
+		-Dusethreads \
+		-Duseithreads \
+		-Duselargefiles \
+		-Dnoextensions=ODBM_File \
+		-Ud_dosuid \
+		-Ui_db \
+		-Ui_ndbm \
+		-Ui_gdbm \
+		-Di_shadow \
+		-Di_syslog \
+		-Duseperlio \
+		-Dman3ext=3pm \
+		-Uafs \
+		-Ud_csh \
+		-Uusesfio \
+		-Uusenm -des
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+
+	# We need a hostperl link for building perl
+	ln -sf perl${PV} ${D}${bindir}/hostperl
+
+        ln -sf perl ${D}${libdir}/perl5
+
+	install -d ${D}${libdir}/perl/${PV}/CORE \
+	           ${D}${datadir}/perl/${PV}/ExtUtils
+
+	# Save native config 
+	install config.sh ${D}${libdir}/perl
+	install lib/Config.pm ${D}${libdir}/perl/${PV}/
+	install lib/ExtUtils/typemap ${D}${libdir}/perl/${PV}/ExtUtils/
+
+	# perl shared library headers
+	for i in av.h embed.h gv.h keywords.h op.h perlio.h pp.h regexp.h \
+	         uconfig.h XSUB.h cc_runtime.h embedvar.h handy.h opnames.h \
+	         perliol.h pp_proto.h regnodes.h unixish.h config.h EXTERN.h \
+	         hv.h malloc_ctl.h pad.h perlsdio.h proto.h scope.h utf8.h \
+	         cop.h fakesdio.h INTERN.h mg.h patchlevel.h perlsfio.h \
+	         reentr.h sv.h utfebcdic.h cv.h fakethr.h intrpvar.h \
+	         nostdio.h perlapi.h perlvars.h util.h \
+	         dosish.h form.h iperlsys.h opcode.h perl.h perly.h regcomp.h \
+	         thread.h warnings.h; do
+		install $i ${D}${libdir}/perl/${PV}/CORE
+	done
+}
+do_install_append_nylon() {
+	# get rid of definitions not supported by the gcc version we use for nylon...
+	for i in ${D}${libdir}/perl/${PV}/Config_heavy.pl ${D}${libdir}/perl/config.sh; do
+		perl -pi -e 's/-Wdeclaration-after-statement //g' ${i}
+	done
+}
+
+PARALLEL_MAKE = ""
+
+# Perl encodes the staging path into the perl binary so we have to depend on this
+# as part of the checksum for now
+HARDPATH := "${STAGING_BINDIR}"
+do_populate_sysroot[vardeps] += "HARDPATH"