Major layout change to the packages directory

Having one monolithic packages directory makes it hard to find things
and is generally overwhelming. This commit splits it into several
logical sections roughly based on function, recipes.txt gives more
information about the classifications used.

The opportunity is also used to switch from "packages" to "recipes"
as used in OpenEmbedded as the term "packages" can be confusing to
people and has many different meanings.

Not all recipes have been classified yet, this is just a first pass
at separating things out. Some packages are moved to meta-extras as
they're no longer actively used or maintained.

Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>

1 files changed, 63 insertions, 0 deletions

diff --git a/meta/recipes-devtools/apt/apt-native.inc b/meta/recipes-devtools/apt/apt-native.inc
new file mode 100644
index 0000000000..b16f99e93c
--- /dev/null
+++ b/meta/recipes-devtools/apt/apt-native.inc
@@ -0,0 +1,63 @@
+require apt.inc
+inherit native
+
+DEPENDS += "dpkg-native gettext-native"
+PACKAGES = ""
+USE_NLS = "yes"
+
+SRC_URI += "file://db_linking_hack.patch"
+
+python do_install () {
+	bb.build.exec_func('do_install_base', d)
+	bb.build.exec_func('do_install_config', d)
+}
+
+python do_install_config () {
+	indir = os.path.dirname(bb.data.getVar('FILE',d,1))
+	infile = file(os.path.join(indir, 'files', 'apt.conf'), 'r')
+	data = infile.read()
+	infile.close()
+
+	data = bb.data.expand(data, d)
+
+	outdir = os.path.join(bb.data.getVar('D', d, 1), bb.data.getVar('sysconfdir', d, 1), 'apt')
+	if not os.path.exists(outdir):
+		os.makedirs(outdir)
+	outpath = os.path.join(outdir, 'apt.conf.sample')
+
+	outfile = file(outpath, 'w')
+	outfile.write(data)
+	outfile.close()
+}
+
+do_install_base () {
+	install -d ${D}${bindir}
+	install -m 0755 bin/apt-cdrom ${D}${bindir}/
+	install -m 0755 bin/apt-get ${D}${bindir}/
+	install -m 0755 bin/apt-config ${D}${bindir}/
+	install -m 0755 bin/apt-cache ${D}${bindir}/
+	install -m 0755 bin/apt-sortpkgs ${D}${bindir}/
+	install -m 0755 bin/apt-extracttemplates ${D}${bindir}/
+
+	eval `cat environment.mak | grep ^GLIBC_VER | sed -e's, = ,=,'`
+	oe_libinstall -so -C bin libapt-pkg$GLIBC_VER-6 ${D}${libdir}/
+	ln -sf libapt-pkg$GLIBC_VER-6.so ${D}${libdir}/libapt-pkg.so
+	oe_libinstall -so -C bin libapt-inst$GLIBC_VER-6 ${D}${libdir}/
+	ln -sf libapt-inst$GLIBC_VER-6.so ${D}${libdir}/libapt-inst.so
+
+	install -d ${D}${libdir}/apt/methods
+	install -m 0755 bin/methods/* ${D}${libdir}/apt/methods/
+
+	install -d ${D}${libdir}/dpkg/methods/apt
+	install -m 0644 dselect/desc.apt ${D}${libdir}/dpkg/methods/apt/ 
+	install -m 0644 dselect/names ${D}${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/install ${D}${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/setup ${D}${libdir}/dpkg/methods/apt/ 
+	install -m 0755 dselect/update ${D}${libdir}/dpkg/methods/apt/ 
+
+	install -d ${D}${sysconfdir}/apt
+	install -d ${D}${localstatedir}/lib/apt/lists/partial
+	install -d ${D}${localstatedir}/cache/apt/archives/partial
+
+	install -d ${D}${localstatedir}/log/apt/
+}