blob: 764af7e6e8f6dd46ceb2e282bbb651793cbf4a07 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
DESCRIPTION = "DSPLINK 1.61.3 module for TI ARM/DSP processors"
inherit module
# compile and run time dependencies
DEPENDS += " virtual/kernel perl-native ti-dspbios-native ti-cgt6x-native update-modules"
# tconf from xdctools dislikes '.' in pwd :/
PR = "r11"
PV = "1613"
installdir = "${prefix}/ti"
SRC_URI = "http://install.source.dir.com/codec_engine_2_23_01.tar.gz \
file://loadmodules-ti-dsplink-apps.sh \
file://unloadmodules-ti-dsplink-apps.sh"
# Set the source directory
S = "${WORKDIR}/codec_engine_2_23_01"
# DSPLINK - Config Variable for different platform
DSPLINKPLATFORM ?= "DAVINCI"
DSPLINKPLATFORM_omap3evm ?= "OMAP3530"
DSPLINKPLATFORM_beagleboard ?= "OMAP3530"
DSPLINKPLATFORM_dm6446-evm ?= "DAVINCI"
DSPLINKDSPCFG ?= "DM6446GEMSHMEM"
DSPLINKDSPCFG_omap3evm ?= "OMAP3530SHMEM"
DSPLINKDSPCFG_beagleboard ?= "OMAP3530SHMEM"
DSPLINKDSPCFG_dm6446-evm ?= "DM6446GEMSHMEM"
DSPLINKGPPOS ?= "MVL5G"
DSPLINKGPPOS_omap3evm ?= "OMAPLSP"
DSPLINKGPPOS_beagleboard ?= "OMAPLSP"
DSPLINKGPPOS_dm6446-evm ?= "MVL5G"
export DSPLINK="${S}/cetools/packages/dsplink"
STAGING_TI_DSPBIOS_DIR="${STAGING_DIR_NATIVE}/ti-dspbios-native"
STAGING_TI_CGT6x_DIR="${STAGING_DIR_NATIVE}/ti-cgt6x-native"
do_compile() {
# Run perl script to create appropriate makefiles (v1.60 and up)
(
cd ${DSPLINK}
perl config/bin/dsplinkcfg.pl --platform=${DSPLINKPLATFORM} --nodsp=1 \
--dspcfg_0=${DSPLINKDSPCFG} --dspos_0=DSPBIOS5XX \
--gppos=${DSPLINKGPPOS} --comps=ponslrm
)
# dsplink makefile is hard-coded to use kbuild only on OMAP3530.
# we are forcing to use kbuild on other platforms.
sed -i 's/OMAP3530/${DSPLINKPLATFORM}/g' ${DSPLINK}/gpp/src/Makefile
# TODO :: KERNEL_CC, etc need replacing with user CC
# TODO :: Need to understand why OBJDUMP is required for kernel module
# Unset these since LDFLAGS gets picked up and used incorrectly.... need
# investigation
unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
# Build the gpp user space library
cd ${DSPLINK}/gpp/src/api
make \
CROSS_COMPILE="${TARGET_PREFIX}" \
CC="${KERNEL_CC}" \
AR="${KERNEL_AR}" \
LD="${KERNEL_LD}" \
COMPILER="${KERNEL_CC}" \
ARCHIVER="${KERNEL_AR}" \
KERNEL_DIR="${STAGING_KERNEL_DIR}" \
clean all
# Build the gpp kernel space (debug and release)
cd ${DSPLINK}/gpp/src
make \
OBJDUMP="${TARGET_PREFIX}objdump" \
CROSS_COMPILE="${TARGET_PREFIX}" \
CC="${KERNEL_CC}" \
AR="${KERNEL_AR}" \
LD="${KERNEL_LD}" \
COMPILER="${KERNEL_CC}" \
ARCHIVER="${KERNEL_AR}" \
KERNEL_DIR="${STAGING_KERNEL_DIR}" \
clean all
# Build the gpp samples
cd ${DSPLINK}/gpp/src/samples
make \
BASE_TOOLCHAIN="${CROSS_DIR}" \
BASE_CGTOOLS="${BASE_TOOLCHAIN}/bin" \
OSINC_PLATFORM="${CROSS_DIR}/lib/gcc/${TARGET_SYS}/$(${TARGET_PREFIX}gcc -dumpversion)/include" \
OSINC_TARGET="${BASE_TOOLCHAIN}/target/usr/include" \
CROSS_COMPILE="${TARGET_PREFIX}" \
CC="${KERNEL_CC}" \
AR="${KERNEL_AR}" \
LD="${KERNEL_LD}" \
COMPILER="${KERNEL_CC}" \
LINKER="${KERNEL_CC}" \
ARCHIVER="${KERNEL_AR}" \
KERNEL_DIR="${STAGING_KERNEL_DIR}" \
clean all
# Build the dsp library (debug and release)
cd ${DSPLINK}/dsp/src
make \
BASE_CGTOOLS="${STAGING_TI_CGT6x_DIR}" \
BASE_SABIOS="${STAGING_TI_DSPBIOS_DIR}" \
clean all
# Build the dsp samples (debug and release)
cd ${DSPLINK}/dsp/src/samples
make \
BASE_CGTOOLS="${STAGING_TI_CGT6x_DIR}" \
BASE_SABIOS="${STAGING_TI_DSPBIOS_DIR}" \
clean all
}
do_install () {
# DSPLINK driver - kernel module
install -d ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp
install -m 0755 ${DSPLINK}/gpp/export/BIN/Linux/${DSPLINKPLATFORM}/RELEASE/dsplinkk.ko ${D}/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/
# DSPLINK library
install -d ${D}/${installdir}/dsplink/libs
install -m 0755 ${DSPLINK}/gpp/export/BIN/Linux/${DSPLINKPLATFORM}/RELEASE/dsplink.lib ${D}/${installdir}/dsplink/libs
# DSPLINK sample apps
install -d ${D}/${installdir}/dsplink/apps
cp ${DSPLINK}/gpp/export/BIN/Linux/${DSPLINKPLATFORM}/RELEASE/*gpp ${D}/${installdir}/dsplink/apps
for i in $(find ${DSPLINK}/dsp/BUILD/ -name "*.out") ; do
cp ${i} ${D}/${installdir}/dsplink/apps
done
# DSPLINK test app module un/load scripts
install ${WORKDIR}/loadmodules-ti-dsplink-apps.sh ${D}/${installdir}/dsplink/apps
install ${WORKDIR}/unloadmodules-ti-dsplink-apps.sh ${D}/${installdir}/dsplink/apps
}
pkg_postrm () {
update-modules || true
}
pkg_postinst () {
if [ -n "$D" ]; then
exit 1
fi
depmod -a
update-modules || true
}
INHIBIT_PACKAGE_STRIP = "1"
PACKAGES += " ti-dsplink-apps"
FILES_${PN} = "/lib/modules/${KERNEL_VERSION}/kernel/drivers/dsp/*"
FILES_ti-dsplink-apps = "/${installdir}/dsplink/*"
# Disable QA check untils we figure out how to pass LDFLAGS in build
INSANE_SKIP_${PN} = True
INSANE_SKIP_ti-dsplink-apps = True
|
