blob: 5305730a9f6010a03883bbeb4100404f07998670 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
DESCRIPTION = "Base system password/group files."
SECTION = "base"
LICENSE = "GPL"
PR = "r1"
SRC_URI = "\
${DEBIAN_MIRROR}/main/b/base-passwd/base-passwd_${PV}.tar.gz \
file://nobash.patch;patch=1 \
file://root-home.patch;patch=1 \
file://mysql.patch;patch=1 \
"
S = "${WORKDIR}/base-passwd"
inherit autotools
do_install_docs () {
install -d -m 755 \
${D}${mandir}/man8 ${D}${mandir}/pl/man8
install -p -m 644 man/update-passwd.8 \
${D}${mandir}/man8/
install -p -m 644 man/update-passwd.pl.8 \
${D}${mandir}/pl/man8/update-passwd.8
gzip -9 ${D}${mandir}/man8/* \
${D}${mandir}/pl/man8/*
install -d -m 755 ${D}${docdir}/${PN}
install -p -m 644 debian/changelog ${D}${docdir}/${PN}/
gzip -9 ${D}${docdir}/${PN}/*
install -p -m 644 README ${D}${docdir}/${PN}/
install -p -m 644 debian/copyright ${D}${docdir}/${PN}/
}
do_install () {
do_install_docs
install -d -m 755 ${D}${sbindir}
install -p -m 755 update-passwd ${D}${sbindir}/
install -d -m 755 ${D}${datadir}/base-passwd
install -p -m 644 passwd.master \
${D}${datadir}/base-passwd/
install -p -m 644 group.master \
${D}${datadir}/base-passwd/
}
do_install_micro () {
install -d -m 755 ${D}${sysconfdir}
install -p -m 644 passwd.master ${D}${sysconfdir}/passwd
install -p -m 644 group.master ${D}${sysconfdir}/group
}
do_install_append_openmn() {
echo "0:Jn6tcg/qjqvUE:0:0:root:/root:/bin/sh" >>${D}${datadir}/base-passwd/passwd.master
}
FILES_${PN}-doc += "${docdir}"
pkg_postinst () {
set -e
if [ ! -e $D${sysconfdir}/passwd ] ; then
cp $D${datadir}/base-passwd/passwd.master $D${sysconfdir}/passwd
fi
if [ ! -e $D${sysconfdir}/group ] ; then
cp $D${datadir}/base-passwd/group.master $D${sysconfdir}/group
fi
exit 0
}
|
