1 files changed, 59 insertions, 0 deletions
diff --git a/recipes/multitech/mts-io_0.2.0.bb b/recipes/multitech/mts-io_0.2.0.bb
new file mode 100644
index 0000000000..67b7d65875
--- /dev/null
+++ b/recipes/multitech/mts-io_0.2.0.bb
@@ -0,0 +1,59 @@
+DESCRIPTION = "mts-io controller and sysfs wrapper"
+HOMEPAGE = "http://www.multitech.net/"
+SECTION = "base"
+PRIORITY = "optional"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel"
+RDEPENDS = "kernel (${KERNEL_VERSION})"
+PV = "${SRCPV}"
+
+SRC_URI = " \
+    file://mts-io.init \
+    git://multitech.net/cdp-io-controller.git;protocol=git;tag=v0.2.0 \
+"
+S = "${WORKDIR}/git/io-module"
+
+inherit module-base
+inherit update-rc.d
+
+PR = "r0"
+
+EXTRA_OEMAKE = " -C ${STAGING_KERNEL_DIR} \
+                M=${S} \
+                modules \
+                "
+
+do_configure () {
+   echo "Nothing to configure for mts-io"
+}
+
+do_compile () {
+    unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+    oe_runmake
+}
+
+PACKAGES = "${PN}"
+
+FILES_${PN} = "${base_libdir}/modules/${KERNEL_VERSION}/extra/mts_io.ko"
+FILES_${PN} += "${sysconfdir}/init.d/mts-io"
+FILES_${PN} += "${libdir}/mts-io-sysfs*"
+FILES_${PN} += "${sbindir}/mts-io-sysfs"
+
+INITSCRIPT_NAME = "mts-io"
+INITSCRIPT_PARAMS = "start 90 S ."
+
+PARALLEL_MAKE = ""
+
+fakeroot do_install () {
+    install -m 0755 -d ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra
+    # use cp instead of install so the driver doesn't get stripped
+    cp ${S}/mts_io.ko ${D}${base_libdir}/modules/${KERNEL_VERSION}/extra
+
+    install -d ${D}${sysconfdir}/init.d
+    install -m 0755 ${WORKDIR}/mts-io.init ${D}${sysconfdir}/init.d/mts-io
+
+    install -m 0755 -d ${D}${sbindir}
+    install -d ${D}${libdir}/mts-io-sysfs
+    install -m 0755 ${WORKDIR}/git/io-tool/mts-io-sysfs-inc.sh ${D}${libdir}/mts-io-sysfs
+    install -m 0755 ${WORKDIR}/git/io-tool/mts-io-sysfs ${D}${sbindir}/mts-io-sysfs
+}