2 files changed, 64 insertions, 0 deletions
diff --git a/packages/libetpan/libetpan_0.48.bb b/packages/libetpan/libetpan_0.48.bb
new file mode 100644
index 0000000000..dfef3b19c6
--- /dev/null
+++ b/packages/libetpan/libetpan_0.48.bb
@@ -0,0 +1,23 @@
+DESCRIPTION = "libetpan is a library for communicating with mail and news servers. \
+It supports the protocols SMTP, POP3, IMAP and NNTP."
+HOMEPAGE = "http://www.etpan.org"
+SECTION = "libs"
+DEPENDS = "gnutls"
+LICENSE = "BSD"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/libetpan/libetpan-${PV}.tar.gz \
+           file://honor-oe-lflags.patch;patch=1"
+
+inherit autotools pkgconfig gettext binconfig
+
+EXTRA_OECONF = "--without-openssl --with-gnutls --disable-db"
+
+PARALLEL_MAKE = ""
+
+do_stage() {
+	autotools_stage_all
+}
+
+FILES_${PN} = "${libdir}/lib*.so.*"
+FILES_${PN}-dev = "${bindir} ${includedir} ${libdir}/lib*.so ${libdir}/*.la ${libdir}/*.a ${libdir}/pkgconfig"
diff --git a/packages/sylpheed/claws-mail_2.6.1.bb b/packages/sylpheed/claws-mail_2.6.1.bb
new file mode 100644
index 0000000000..bed205766b
--- /dev/null
+++ b/packages/sylpheed/claws-mail_2.6.1.bb
@@ -0,0 +1,41 @@
+SECTION = "x11/network"
+DESCRIPTION = "Mail user agent"
+DEPENDS = "gtk+ gpgme libetpan libgnomeprint aspell"
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/sylpheed-claws/claws-mail-${PV}.tar.bz2"
+
+FILES_${PN} = "${bindir} ${datadir}/pixmaps ${datadir}/applications"
+
+EXTRA_OECONF = "--disable-openssl --disable-aspell-test \
+ --disable-dillo-viewer-plugin --with-aspell-prefix=${STAGING_DIR}/${HOST_SYS} \
+ --enable-aspell"
+
+CFLAGS += "-D_GNU_SOURCE"
+
+inherit autotools pkgconfig
+
+do_configure() {
+    gnu-configize
+    libtoolize --force
+    oe_runconf
+}
+
+do_install_append() {
+	install -d ${D}${datadir}/applications
+	install -m 0644 claws-mail.desktop ${D}${datadir}/applications/
+	install -d ${D}${datadir}/pixmaps
+	install -m 0644 claws-mail.png ${D}${datadir}/pixmaps/
+	mv ${D}${bindir}/${TARGET_SYS}-claws-mail ${D}${bindir}/${PN}
+}
+
+do_stage () {
+	autotools_stage_all
+}
+
+python populate_packages_prepend () {
+	abiword_libdir = bb.data.expand('${libdir}/claws-mail/plugins', d)
+
+	do_split_packages(d, abiword_libdir, '^(.*)\.so$', 'claws-mail-plugin-%s', 'Claws plugin for %s', extra_depends='')
+}