1 files changed, 49 insertions, 0 deletions
diff --git a/packages/qmake/qmake2-native_2.01a.bb b/packages/qmake/qmake2-native_2.01a.bb
new file mode 100644
index 0000000000..dab5b6a3b4
--- /dev/null
+++ b/packages/qmake/qmake2-native_2.01a.bb
@@ -0,0 +1,49 @@
+DESCRIPTION = "TrollTech Makefile Generator"
+PRIORITY = "optional"
+HOMEPAGE = "http://www.trolltech.com"
+SECTION = "devel"
+LICENSE = "GPL QPL"
+
+QTVER = "qt-x11-opensource-src-4.2.3"
+
+SRC_URI = "ftp://ftp.trolltech.com/pub/qt/source/${QTVER}.tar.gz \
+           file://linux-oe-qmake.conf"
+S = "${WORKDIR}/${QTVER}"
+
+# we need the real target system here
+CROSS_SYS := "${TARGET_SYS}"
+inherit autotools native
+
+export QTDIR = "${S}"
+EXTRA_OEMAKE = "-e"
+
+do_configure() {
+        # Install the OE build templates
+        for template in linux-oe-g++ linux-uclibc-oe-g++ linux-gnueabi-oe-g++
+        do
+                install -d ${S}/mkspecs/$template
+                install -m 0644 ${WORKDIR}/linux-oe-qmake.conf ${S}/mkspecs/$template/qmake.conf
+                ln -sf ../linux-g++/qplatformdefs.h ${S}/mkspecs/$template/qplatformdefs.h
+        done
+
+	QMAKESPEC=
+	PLATFORM=${HOST_OS}-oe-g++
+	export PLATFORM
+	# yes, TARGET_SYS is correct, because this is a 'cross'-qmake-native :) :M:
+	echo yes | ./configure -prefix ${STAGING_DIR}/${CROSS_SYS}/qt4 ${EXTRA_OECONF} || die "Configuring qt failed"
+}
+
+do_compile() {
+	:
+}
+
+do_stage() {
+	install -m 0755 bin/qmake ${STAGING_BINDIR}/qmake2
+	install -m 0755 bin/qmake ${STAGING_BINDIR}/qmake-qt4
+	install -d ${STAGING_DIR}/${CROSS_SYS}/qt4/
+	cp -PfR mkspecs ${STAGING_DIR}/${CROSS_SYS}/qt4/
+}
+
+do_install() {
+        :
+}