1 files changed, 68 insertions, 0 deletions
diff --git a/packages/networkmanager/networkmanager-0.7.inc b/packages/networkmanager/networkmanager-0.7.inc
new file mode 100644
index 0000000000..f3927e8a1b
--- /dev/null
+++ b/packages/networkmanager/networkmanager-0.7.inc
@@ -0,0 +1,68 @@
+DESCRIPTION = "NetworkManager"
+SECTION = "net/misc"
+LICENSE = "GPL"
+PRIORITY = "optional"
+DEPENDS = "libnl dbus dbus-glib hal wireless-tools policykit gnutls e2fsprogs-libs ppp"
+RDEPENDS = "wpa-supplicant dhcp-client \
+           ${@base_contains('COMBINED_FEATURES', '3gmodem', 'ppp', '', d)} \
+           "
+
+EXTRA_OECONF = " \
+		--with-distro=debian \
+		--with-crypto=gnutls \
+		--disable-more-warnings"
+
+inherit autotools pkgconfig update-rc.d
+
+INITSCRIPT_NAME = "NetworkManager"
+INITSCRIPT_PARAMS = "defaults 28"
+
+do_stage () {
+	autotools_stage_all
+}
+
+do_install_append () {
+        install -d ${D}/etc/default/volatiles
+        install -d ${D}/etc/dbus-1/event.d
+        # Test binaries
+        install -d ${D}/usr/bin
+        install -m 0755 ${S}/test/.libs/nm-tool ${D}/usr/bin
+        install -m 0755 ${S}/test/.libs/libnm_glib_test ${D}/usr/bin
+        install -m 0755 ${S}/test/.libs/nm-online ${D}/usr/bin
+}
+
+pkg_postinst_${PN} () {
+	if [ "x$D" != "x" ]; then
+		exit 1
+	fi
+	/etc/init.d/populate-volatile.sh update
+}
+
+PACKAGES =+ "libnmutil libnmglib libnmglib-vpn ${PN}-tests" 
+
+FILES_libnmutil += "${libdir}/libnm-util.so.*"
+FILES_libnmglib += "${libdir}/libnm_glib.so.*"
+FILES_libnmglib-vpn += "${libdir}/libnm_glib_vpn.so.*"
+
+FILES_${PN} += " \
+		${libexecdir} \
+		${libdir}/pppd/*/nm-pppd-plugin.so \
+		${libdir}/NetworkManager/*.so \
+		${datadir}/PolicyKit \
+		${datadir}/dbus-1"
+
+FILES_${PN}-dbg += "${libdir}/NetworkManager/.debug/ \
+		    ${libdir}/pppd/*/.debug/ "
+
+FILES_${PN}-dev += "${datadir}/NetworkManager/gdb-cmd \
+                    ${libdir}/pppd/*/*.a \
+                    ${libdir}/pppd/*/*.la \
+                    ${libdir}/NetworkManager/*.a \
+                    ${libdir}/NetworkManager/*.la"
+
+FILES_${PN}-tests = "${bindir}/nm-tool \
+                     ${bindir}/libnm_glib_test \
+                     ${bindir}/nminfotest \
+                     ${bindir}/nm-online \
+                     ${bindir}/nm-supplicant \
+                     ${bindir}/nm-testdevices"