4 files changed, 124 insertions, 2 deletions
diff --git a/packages/lirc/lirc-config.inc b/packages/lirc/lirc-config.inc
index 9106e556cf..03bfc61e39 100644
--- a/packages/lirc/lirc-config.inc
+++ b/packages/lirc/lirc-config.inc
@@ -1,7 +1,8 @@
 EXTRA_OECONF = "--with-kerneldir=${STAGING_KERNEL_DIR} --with-driver=${DRIVER}"
 
 DRIVER ?= "serial"
-DRIVER_collie = "sa1100"
+# fails to build at the moment, re-enable later
+#DRIVER_collie = "sa1100"
 DRIVER_h3600 = "sa1100"
 DRIVER_simpad = "sa1100"
 DRIVER_nslu2 = "nslu2"
diff --git a/packages/lirc/lirc-modules_0.8.1+cvs20070307.bb b/packages/lirc/lirc-modules_0.8.1+cvs20070307.bb
new file mode 100644
index 0000000000..3ecfb76b3c
--- /dev/null
+++ b/packages/lirc/lirc-modules_0.8.1+cvs20070307.bb
@@ -0,0 +1,47 @@
+DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls. This package contains the lirc kernel modules."
+SECTION = "base"
+PRIORITY = "optional"
+HOMEPAGE = "http://www.lirc.org"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel fakeroot-native setserial"
+RDEPENDS_nslu2 = "setserial"
+PR = "r0"
+
+# enable this bb file until the other packages compile again
+#DEFAULT_PREFERENCE = "-1"
+
+SRCDATE=${@bb.data.getVar('PV', d, 1)[9:]}
+
+SRC_URI = "cvs://anonymous@lirc.cvs.sourceforge.net/cvsroot/lirc;module=lirc;method=pserver;cvsdate=${SRCDATE}"
+S = "${WORKDIR}/lirc"
+
+inherit autotools module
+
+require lirc-config.inc
+
+MAKE_TARGETS = "KERNEL_PATH=${STAGING_KERNEL_DIR} MAKE='make -e' -C drivers"
+
+fakeroot do_install() {
+	oe_runmake -C drivers DESTDIR="${D}" moduledir="/lib/modules/${KERNEL_VERSION}/lirc" install
+	rm -rf ${D}/dev
+}
+
+# nslu2 uses udev, so /dev/lirc0 will be created automatically
+# and /dev/lirc will be created by /etc/udev/rules.d/lirc.rules
+# (that's the kernel-2.6+udev solution)
+do_install_append_nslu2() {
+	install -d ${D}${sysconfdir}/modutils/
+	echo 'lirc_serial' > ${D}${sysconfdir}/modutils/lirc_serial
+	install -d ${D}${sysconfdir}/modprobe.d/
+	echo 'install lirc_serial /bin/setserial /dev/ttyS1 uart none; /sbin/leds ready on; /sbin/modprobe --ignore-install lirc_serial' >${D}${sysconfdir}/modprobe.d/lirc_serial
+	install -d ${D}${sysconfdir}/udev/rules.d/
+	echo 'KERNEL="lirc0", SYMLINK="lirc"' > ${D}${sysconfdir}/udev/rules.d/lirc.rules
+}
+
+# this is for distributions that don't use udev
+pkg_postinst_append() {
+if [ ! -c $D/dev/lirc -a ! -f /sbin/udevd ]; then mknod $D/dev/lirc c 61 0; fi
+}
+
+FILES_${PN} = "/lib/modules"
+FILES_${PN}_append_nslu2 = " ${sysconfdir}/modutils ${sysconfdir}/modprobe.d ${sysconfdir}/udev/rules.d"
diff --git a/packages/lirc/lirc_0.8.0.bb b/packages/lirc/lirc_0.8.0.bb
index 57be891c89..f24d63a21c 100644
--- a/packages/lirc/lirc_0.8.0.bb
+++ b/packages/lirc/lirc_0.8.0.bb
@@ -15,7 +15,7 @@ RDEPENDS_lirc-x = "lirc"
 RDEPENDS_lirc-exec = "lirc"
 RDEPENDS_lirc-nslu2example = "lirc lirc-exec"
 RRECOMMENDS_lirc = "lirc-exec"
-PR = "r3"
+PR = "r4"
 
 SRC_URI = "${SOURCEFORGE_MIRROR}/lirc/lirc-${PV}.tar.gz \
            file://lircd.init file://lircmd.init file://lircexec.init"
@@ -59,6 +59,7 @@ do_install_append_nslu2() {
 PACKAGES =+ "lirc-x lirc-exec lirc-remotes"
 PACKAGES_prepend_nslu2 = "lirc-nslu2example "
 
+FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug"
 FILES_${PN} = "${bindir} ${sbindir} ${libdir} ${sysconfdir}/init.d"
 FILES_lirc-x = "${bindir}/irxevent ${bindir}/xmode2"
 FILES_lirc-exec = "${bindir}/irexec ${sysconfdir}/init.d/lircexec"
diff --git a/packages/lirc/lirc_0.8.1+cvs20070307.bb b/packages/lirc/lirc_0.8.1+cvs20070307.bb
new file mode 100644
index 0000000000..61f7019b2e
--- /dev/null
+++ b/packages/lirc/lirc_0.8.1+cvs20070307.bb
@@ -0,0 +1,73 @@
+DESCRIPTION = "LIRC is a package that allows you to decode and send infra-red signals of many commonly used remote controls."
+DESCRIPTION_append_lirc = " This package contains the lirc daemon, libraries and tools."
+DESCRIPTION_append_lirc-x = " This package contains lirc tools for X11."
+DESCRIPTION_append_lirc-exec = " This package contains a daemon that runs programs on IR signals."
+DESCRIPTION_append_lirc-remotes = " This package contains some config files for remotes."
+DESCRIPTION_append_lirc-nslu2example = " This package contains a working config for RC5 remotes and a modified NSLU2."
+SECTION = "console/network"
+PRIORITY = "optional"
+HOMEPAGE = "http://www.lirc.org"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel virtual/libx11 libxau libsm libice"
+DEPENDS_nslu2 = "virtual/kernel lirc-modules"
+RDEPENDS = "lirc-modules"
+RDEPENDS_lirc-x = "lirc"
+RDEPENDS_lirc-exec = "lirc"
+RDEPENDS_lirc-nslu2example = "lirc lirc-exec"
+RRECOMMENDS_lirc = "lirc-exec"
+PR = "r1"
+
+# enable cvs version since until compilation issues for other packages have been fixed (cf. bug 2284 et al).
+#DEFAULT_PREFERENCE = "-1"
+
+SRCDATE=${@bb.data.getVar('PV', d, 1)[9:]}
+
+SRC_URI = "cvs://anonymous@lirc.cvs.sourceforge.net/cvsroot/lirc;module=lirc;method=pserver;cvsdate=${SRCDATE} \
+           file://lircd.init file://lircmd.init file://lircexec.init"
+SRC_URI_append_nslu2 = " file://lircd.conf_nslu2 file://lircrc_nslu2"
+
+S = "${WORKDIR}/lirc"
+
+inherit autotools module-base update-rc.d
+
+INITSCRIPT_PACKAGES = "lirc lirc-exec"
+INITSCRIPT_NAME = "lircd"
+INITSCRIPT_PARAMS = "defaults 20"
+INITSCRIPT_NAME_lirc-exec = "lircexec"
+INITSCRIPT_PARAMS_lirc-exec = "defaults 21"
+
+require lirc-config.inc
+
+EXTRA_OEMAKE = 'SUBDIRS="daemons tools"'
+
+do_stage() {
+        oe_libinstall -so -C tools liblirc_client ${STAGING_LIBDIR}
+	install -d ${STAGING_INCDIR}/lirc/
+	install -m 0644 tools/lirc_client.h ${STAGING_INCDIR}/lirc/
+}
+
+do_install_append() {
+	install -d ${D}${sysconfdir}/init.d
+	install ${WORKDIR}/lircd.init ${D}${sysconfdir}/init.d/lircd
+	install ${WORKDIR}/lircexec.init ${D}${sysconfdir}/init.d/lircexec
+        install -d ${D}${datadir}/lirc/
+        cp -pPR ${S}/remotes ${D}${datadir}/lirc/
+	rm -rf ${D}/dev
+}
+
+do_install_append_nslu2() {
+	install -d ${D}${sysconfdir}
+	install ${WORKDIR}/lircd.conf_nslu2 ${D}${sysconfdir}/lircd.conf
+	install ${WORKDIR}/lircrc_nslu2 ${D}${sysconfdir}/lircrc
+}
+
+PACKAGES =+ "lirc-x lirc-exec lirc-remotes"
+PACKAGES_prepend_nslu2 = "lirc-nslu2example "
+
+FILES_${PN}-dbg += "${bindir}/.debug ${sbindir}/.debug"
+FILES_${PN} = "${bindir} ${sbindir} ${libdir} ${sysconfdir}/init.d"
+FILES_lirc-x = "${bindir}/irxevent ${bindir}/xmode2"
+FILES_lirc-exec = "${bindir}/irexec ${sysconfdir}/init.d/lircexec"
+FILES_lirc-remotes = "${datadir}/lirc/remotes"
+FILES_lirc-nslu2example = "${sysconfdir}/lircd.conf ${sysconfdir}/lircrc"
+CONFFILES_lirc-nslu2example = "${FILES_lirc-nslu2example}"