1 files changed, 63 insertions, 0 deletions
diff --git a/packages/linux/linux-openmoko_2.6.24.bb b/packages/linux/linux-openmoko_2.6.24.bb
new file mode 100644
index 0000000000..19c0119f2f
--- /dev/null
+++ b/packages/linux/linux-openmoko_2.6.24.bb
@@ -0,0 +1,63 @@
+require linux.inc
+require linux-openmoko.inc
+
+DESCRIPTION = "Linux 2.6.x (development) kernel for FIC SmartPhones shipping w/ OpenMoko"
+VANILLA_VERSION = "2.6.24"
+KERNEL_RELEASE = "2.6.24"
+
+PV = "${KERNEL_RELEASE}+svnr${SRCREV}"
+PR = "r0"
+
+KERNEL_IMAGETYPE = "uImage"
+UBOOT_ENTRYPOINT = "30008000"
+
+##############################################################
+# source and patches
+#
+SRCREV_FORMAT = "patches-rconfig"
+
+SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
+#           ${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/patch-${KERNEL_RELEASE}.bz2;patch=1 \
+           svn://svn.openmoko.org/branches/src/target/kernel/2.6.24.x;module=patches;proto=http;name=patches \
+           svn://svn.openmoko.org/branches/src/target/kernel/2.6.24.x;module=config;proto=http;name=config "
+
+S = "${WORKDIR}/linux-${VANILLA_VERSION}"
+
+##############################################################
+# kernel image resides on a seperate flash partition (for now)
+#
+ALLOW_EMPTY = "1"
+
+COMPATIBLE_HOST = "arm.*-linux"
+COMPATIBLE_MACHINE = 'fic-gta01|fic-gta02'
+
+CMDLINE = "unused -- bootloader passes ATAG list"
+
+###############################################################
+# module configs specific to this kernel
+#
+
+# usb
+module_autoload_ohci-hcd = "ohci-hcd"
+module_autoload_hci_usb = "hci_usb"
+module_autoload_g_ether = "g_ether"
+# audio
+module_autoload_snd-soc-neo1973-wm8753 = "snd-soc-neo1973-wm8753"
+# sd/mmc
+module_autoload_s3cmci = "s3cmci"
+
+python do_patch_prepend() {
+	def runcmd(cmd):
+		import commands
+		(status, output) = commands.getstatusoutput(cmd)
+		if status != 0:
+			raise Exception, "Status %i: %s" % (status >> 8, output)
+		return output
+	runcmd('mv %(WORKDIR)s/patches %(S)s/patches && cd %(S)s && '
+	       'quilt push -av && mv patches patches.openmoko && '
+	       'mv .pc .pc.old && mv %(WORKDIR)s/config/defconfig-%(KERNEL_RELEASE)s %(WORKDIR)s/defconfig' %
+	       {'WORKDIR': bb.data.getVar('WORKDIR', d, 1),
+		'S': bb.data.getVar('S', d, 1),
+		'KERNEL_RELEASE': bb.data.getVar('KERNEL_RELEASE', d, 1)})
+	del runcmd
+}