9 files changed, 89 insertions, 43 deletions
diff --git a/packages/kexecboot/kexecboot-cfg_0.1.bb b/packages/kexecboot/kexecboot-cfg_0.1.bb
new file mode 100644
index 0000000000..394e531760
--- /dev/null
+++ b/packages/kexecboot/kexecboot-cfg_0.1.bb
@@ -0,0 +1,25 @@
+LICENSE = "GPL"
+SECTION = "base"
+DESCRIPTION = "Configuration file for kexecboot"
+
+PR = "r1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+CMDLINE_CON = "console=ttyS0,115200n8 console=tty1 noinitrd"
+CMDLINE_CON_collie = "console=ttySA0,115200n8 console=tty1 noinitrd"
+CMDLINE_CON_qemuarm = "console=ttyAMA0,115200n8 console=tty1 noinitrd"
+
+CMDLINE_DEBUG = '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug",d)}'
+
+CMDLINE_MEM_collie = "mem=${mem}M"
+
+CMDLINE_ROTATE_spitz = "fbcon=rotate:1"
+CMDLINE_ROTATE_akita = "fbcon=rotate:1"
+CMDLINE_ROTATE_collie = "fbcon=rotate:1"
+CMDLINE_ROTATE_poodle = "fbcon=rotate:1"
+FILES_${PN} += "/boot/*"
+
+do_install () {
+	install -d ${D}/boot
+	echo "${CMDLINE_CON} ${CMDLINE_MEM} ${CMDLINE_ROTATE} ${CMDLINE_OTHER} ${CMDLINE_DEBUG}"> ${D}/boot/kernel-cmdline
+}
diff --git a/packages/kexecboot/kexecboot.inc b/packages/kexecboot/kexecboot.inc
new file mode 100644
index 0000000000..5f3f34948e
--- /dev/null
+++ b/packages/kexecboot/kexecboot.inc
@@ -0,0 +1,39 @@
+LICENSE = "GPL"
+
+DEPENDS = "klibc"
+RDEPENDS = "kexec-static"
+
+inherit autotools
+
+# You can create your own *-img.h by doing
+# ./make-image-header.sh <file>.png HAND
+
+SRC_URI += "file://logo-img.h \
+	    file://logo.png \
+	    "
+
+export CC=${TARGET_PREFIX}klcc
+
+# standard oe cflags don't work with klcc
+export CFLAGS = ""
+export CPPFLAGS = ""
+export LDFLAGS = ""
+
+do_configure_prepend () {
+    install -m 0644 ${WORKDIR}/logo-img.h ${S}/res/
+    install -m 0644 ${WORKDIR}/logo.png ${S}/res/
+}
+
+do_install () {
+	install -d ${D}${bindir}
+	install -m 0755 kexecboot ${D}${bindir}/
+
+	install -d ${D}/proc
+	install -d ${D}/mnt
+}
+
+FILES_${PN} += " ${bindir}/kexecboot /init /proc /mnt"
+
+pkg_postinst_${PN} () {
+	ln -sf ${bindir}/kexecboot $D/init
+}
diff --git a/packages/kexecboot/kexecboot_0.4.bb b/packages/kexecboot/kexecboot_0.4.bb
index 4eed4d0482..c38b2b402c 100644
--- a/packages/kexecboot/kexecboot_0.4.bb
+++ b/packages/kexecboot/kexecboot_0.4.bb
@@ -1,12 +1,4 @@
-LICENSE = "GPL"
-PR = "r4"
-DEPENDS = "klibc"
-RDEPENDS = "kexec-static"
-
-inherit autotools
-
-# You can create your own *-img.h by doing
-# ./make-image-header.sh <file>.png HAND
+PR = "r5"
 
 SRC_URI = "http://projects.linuxtogo.org/~jay7/kexecboot-${PV}.tar.gz \
 	file://add-reboot-option.patch;patch=1 \
@@ -16,35 +8,8 @@ SRC_URI = "http://projects.linuxtogo.org/~jay7/kexecboot-${PV}.tar.gz \
 	file://add-sleep.patch;patch=1 \
 	file://silent-output-hack.patch;patch=1 \
 	file://kexecboot-tosa.patch;patch=1 \
-	file://fb-render-16bit.patch;patch=1 \
-	file://logo-img.h \
-	file://logo.png \
-	"
+	file://fb-render-16bit.patch;patch=1"
 
 S = "${WORKDIR}/kexecboot-${PV}"
 
-export CC=${TARGET_PREFIX}klcc
-
-# standard oe cflags don't work with klcc
-export CFLAGS = ""
-export CPPFLAGS = ""
-export LDFLAGS = ""
-
-do_configure_prepend () {
-    install -m 0644 ${WORKDIR}/logo-img.h ${S}/res/
-    install -m 0644 ${WORKDIR}/logo.png ${S}/res/
-}
-
-do_install () {
-	install -d ${D}${bindir}
-	install -m 0755 kexecboot ${D}${bindir}/
-
-	install -d ${D}/proc
-	install -d ${D}/mnt
-}
-
-FILES_${PN} += " ${bindir}/kexecboot /init /proc /mnt"
-
-pkg_postinst_${PN} () {
-	ln -sf ${bindir}/kexecboot $D/init
-}
+require kexecboot.inc
diff --git a/packages/kexecboot/kexecboot_0.5.bb b/packages/kexecboot/kexecboot_0.5.bb
new file mode 100644
index 0000000000..b901903a2a
--- /dev/null
+++ b/packages/kexecboot/kexecboot_0.5.bb
@@ -0,0 +1,4 @@
+SRC_URI = "http://projects.linuxtogo.org/frs/download.php/226/kexecboot-${PV}.tar.gz \
+          "
+
+require kexecboot.inc
diff --git a/packages/kexecboot/kexecboot_git.bb b/packages/kexecboot/kexecboot_git.bb
new file mode 100644
index 0000000000..97a3f27512
--- /dev/null
+++ b/packages/kexecboot/kexecboot_git.bb
@@ -0,0 +1,15 @@
+PR = "r0"
+DEFAULT_PREFERENCE = "-1"
+
+SRC_URI = "git://git.linuxtogo.org/home/thesing/kexecboot.git;protocol=git "
+SRCREV = "8823a939a38a8a3287f90dee062e8ab8569f884f"
+
+# v0.5
+#tag=8823a939a38a8a3287f90dee062e8ab8569f884f
+
+# v0.4
+#tag=d7af5356df4f25203831403c69f1a263c163f31a
+
+S = "${WORKDIR}/git"
+
+require kexecboot.inc
diff --git a/packages/kexecboot/linux-kexecboot.inc b/packages/kexecboot/linux-kexecboot.inc
index 86c4ebbbbe..2056758796 100644
--- a/packages/kexecboot/linux-kexecboot.inc
+++ b/packages/kexecboot/linux-kexecboot.inc
@@ -1,3 +1,6 @@
+# We set PR here, since a change in the kexecboot recipe will need to get picked up by *all* the kernels:
+PR = "r12"
+
 SRC_URI = "file://defconfig"
 
 LOGO_SIZE = '${@base_conditional("GUI_MACHINE_CLASS", "bigscreen", "vga", "qvga", d)}'
diff --git a/packages/kexecboot/linux-kexecboot_2.6.21-hh20.bb b/packages/kexecboot/linux-kexecboot_2.6.21-hh20.bb
index 8ed15596ab..7667037037 100644
--- a/packages/kexecboot/linux-kexecboot_2.6.21-hh20.bb
+++ b/packages/kexecboot/linux-kexecboot_2.6.21-hh20.bb
@@ -4,8 +4,6 @@ DEFAULT_PREFERENCE = "-1"
 DEFAULT_PREFERENCE_hx4700 = "1"
 DEFAULT_PREFERENCE_h2200 = "1"
 
-PR = "r1"
-
 SRC_URI = "${HANDHELDS_CVS};module=linux/kernel26;tag=${@'K' + bb.data.getVar('PV',d,1).replace('.', '-')} \
            file://linux-2.6.git-9d20fdd58e74d4d26dc5216efaaa0f800c23dd3a.patch;patch=1 \
            http://www.rpsys.net/openzaurus/patches/archive/export_atags-r0a.patch;patch=1 \
diff --git a/packages/kexecboot/linux-kexecboot_2.6.24.bb b/packages/kexecboot/linux-kexecboot_2.6.24.bb
index 4dd8edbde4..f728c7adc1 100644
--- a/packages/kexecboot/linux-kexecboot_2.6.24.bb
+++ b/packages/kexecboot/linux-kexecboot_2.6.24.bb
@@ -1,7 +1,5 @@
 require linux-kexecboot.inc
 
-PR = "r6"
-
 DEFAULT_PREFERENCE = "-1"
 DEFAULT_PREFERENCE_collie = "-1"
 DEFAULT_PREFERENCE_poodle = "1"
diff --git a/packages/kexecboot/linux-kexecboot_2.6.26.bb b/packages/kexecboot/linux-kexecboot_2.6.26.bb
index 69b8075f6c..bf1dbb62bf 100644
--- a/packages/kexecboot/linux-kexecboot_2.6.26.bb
+++ b/packages/kexecboot/linux-kexecboot_2.6.26.bb
@@ -1,6 +1,5 @@
 require linux-kexecboot.inc
 
-PR = "r10"
 DEFAULT_PREFERENCE = "-1"
 DEFAULT_PREFERENCE_qemuarm = "-1"
 DEFAULT_PREFERENCE_qemux86 = "-1"