1 files changed, 79 insertions, 0 deletions
diff --git a/packages/gcc/gcc3-cross-build.inc b/packages/gcc/gcc3-cross-build.inc
index e69de29bb2..611b021b11 100644
--- a/packages/gcc/gcc3-cross-build.inc
+++ b/packages/gcc/gcc3-cross-build.inc
@@ -0,0 +1,79 @@
+OLD_INHIBIT_PACKAGE_STRIP := "${INHIBIT_PACKAGE_STRIP}"
+INHIBIT_PACKAGE_STRIP = "1"
+
+EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
+		      --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
+
+do_configure_prepend () {
+	rm -f ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/${PV}/libgcc_eh.a
+}
+
+do_compile_prepend () {
+	export CC="${BUILD_CC}"
+	export AR_FOR_TARGET="${TARGET_SYS}-ar"
+	export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
+	export LD_FOR_TARGET="${TARGET_SYS}-ld"
+	export NM_FOR_TARGET="${TARGET_SYS}-nm"
+	export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
+}
+
+do_stage_append () {
+	for d in info man share/doc share/locale ; do
+		rm -rf ${CROSS_DIR}/$d
+	done
+
+	# These aren't useful on the cross toolchain
+	rm -f ${CROSS_DIR}/bin/*gcov
+	rm -f ${CROSS_DIR}/bin/*gccbug
+
+	# Fix a few include links so cross builds are happier
+	if [ ! -e ${STAGING_INCDIR}/c++ ]; then
+		mkdir -p ${STAGING_INCDIR}
+		ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
+			${STAGING_INCDIR}/
+	fi
+
+	# We use libiberty from binutils
+	rm -f ${CROSS_DIR}/lib/libiberty.a
+
+	# We probably don't need these
+	rmdir ${CROSS_DIR}/include || :
+
+	# We don't really need to keep this around
+	rm -rf ${CROSS_DIR}/share
+}
+
+python do_package() {
+	if bb.data.getVar('DEBIAN_NAMES', d, 1):
+		bb.data.setVar('PKG_libgcc', 'libgcc1', d)
+	bb.build.exec_func('package_do_package', d)
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/${base_libdir}
+	if [ -f ${D}/${base_libdir}/libgcc_s.so.? ]; then
+		# Already in the right location
+		:
+	elif [ -f ${D}/${prefix}/lib/libgcc_s.so.? ]; then
+		mv -f ${D}/${prefix}/lib/libgcc_s.so.* ${D}/${base_libdir}
+	else
+		mv -f ${D}/${prefix}/*/lib/libgcc_s.so.* ${D}/${base_libdir}
+	fi
+
+	# Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
+	TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
+	mkdir -p ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libstdc++.so.* ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libg2c.so.* ${D}/${TGT_LIBDIR}
+
+	# Manually run the target stripper since we won't get it run by
+	# the packaging.
+	if [ "x${OLD_INHIBIT_PACKAGE_STRIP}" != "x1" ]; then
+		${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libstdc++.so.*
+		${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libg2c.so.*
+		${TARGET_PREFIX}strip ${D}/${base_libdir}/libgcc_s.so.*
+	fi
+}