4 files changed, 75 insertions, 0 deletions
diff --git a/packages/exmap-console/.mtn2git_empty b/packages/exmap-console/.mtn2git_empty
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/exmap-console/.mtn2git_empty
diff --git a/packages/exmap-console/exmap-console.inc b/packages/exmap-console/exmap-console.inc
new file mode 100644
index 0000000000..6744aed49f
--- /dev/null
+++ b/packages/exmap-console/exmap-console.inc
@@ -0,0 +1,61 @@
+DESCRIPTION = "Console based version of exmap, a memory usage analysis tool"
+HOMEPAGE = "http://projects.o-hand.com/exmap-console"
+SECTION = "devel"
+LICENSE = "GPL"
+DEPENDS = "virtual/kernel readline"
+
+SRC_URI = "http://projects.o-hand.com/sources/exmap-console/exmap-console-${PV}.tgz"
+
+TEMPPACKAGE_ARCH := "${PACKAGE_ARCH}"
+
+inherit module-base
+inherit autotools
+
+MYPV := "${PV}"
+PACKAGE_ARCH = "${TEMPPACKAGE_ARCH}"
+
+PACKAGES =+ "exmap-server kernel-module-exmap"
+
+FILES_exmap-console = "${bindir}/exmap ${bindir}/exmapd"
+RDEPENDS_exmap-console += "kernel-module-exmap"
+
+FILES_exmap-server = "${bindir}/exmapserver"
+RDEPENDS_exmap-server += "kernel-module-exmap"
+
+FILES_kernel-module-exmap = "${base_libdir}"
+PACKAGE_ARCH_kernel-module-exmap = "${MACHINE_ARCH}"
+PV_kernel-module-exmap = "${MYPV}-${KERNEL_VERSION}"
+RDEPENDS_kernel-module-exmap += "update-modules kernel-image-${KERNEL_VERSION}"
+
+S = "${WORKDIR}/exmap-console-${PV}"
+
+export MODULE_PATH="${D}${base_libdir}/modules/${KERNEL_VERSION}"
+
+do_compile() {
+	cd ${S}/src
+	make
+
+	cd ${S}/kernel
+	unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS
+	oe_runmake KERNEL_PATH=${STAGING_KERNEL_DIR}   \
+		   KERNEL_SRC=${STAGING_KERNEL_DIR}    \
+		   KERNEL_VERSION=${KERNEL_VERSION}    \
+		   CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
+		   ${MAKE_TARGETS}
+}
+
+do_install() {
+	oe_runmake 'DESTDIR=${D}' 'DEPMOD=/bin/true' install
+}
+
+pkg_postinst_append_kernel-module-exmap () {
+	if [ -n "$D" ]; then
+		exit 1
+	fi
+	depmod -a
+	update-modules || true
+}
+
+pkg_postrm_append_kernel-module-exmap () {
+	update-modules || true
+}
diff --git a/packages/exmap-console/exmap-console_0.4.1.bb b/packages/exmap-console/exmap-console_0.4.1.bb
new file mode 100644
index 0000000000..17703321e8
--- /dev/null
+++ b/packages/exmap-console/exmap-console_0.4.1.bb
@@ -0,0 +1,3 @@
+require exmap-console.inc
+
+PR = "r4"
diff --git a/packages/exmap-console/exmap-console_svn.bb b/packages/exmap-console/exmap-console_svn.bb
new file mode 100644
index 0000000000..7c21222d84
--- /dev/null
+++ b/packages/exmap-console/exmap-console_svn.bb
@@ -0,0 +1,11 @@
+require exmap-console.inc
+
+PV = "0.4+svn${SRCDATE}"
+PR = "r14"
+
+SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=exmap-console;proto=http"
+
+S = "${WORKDIR}/exmap-console"
+
+MYPV := "${PV}"
+PV_kernel-module-exmap = "${MYPV}-${KERNEL_VERSION}"