1 files changed, 52 insertions, 0 deletions
diff --git a/ncurses/ncurses_5.4.oe b/ncurses/ncurses_5.4.oe
index e69de29bb2..0a80cc265e 100644
--- a/ncurses/ncurses_5.4.oe
+++ b/ncurses/ncurses_5.4.oe
@@ -0,0 +1,52 @@
+DESCRIPTION = "Ncurses library"
+SECTION = "libs"
+DEPENDS = "virtual/libc"
+PACKAGES_append = " ncurses-terminfo"
+FILES_ncurses_append = " ${datadir}/tabset"
+FILES_ncurses-terminfo = "${datadir}/terminfo"
+
+SRC_URI = "${GNU_MIRROR}/ncurses/ncurses-${PV}.tar.gz"
+S = "${WORKDIR}/ncurses-${PV}"
+
+inherit autotools
+
+EXTRA_OECONF = "--with-shared \
+	        --without-profile \
+	        --without-debug \
+	        --disable-rpath \
+	        --enable-echo \
+	        --enable-const \
+	        --without-ada \
+	        --enable-termcap \
+	        --without-cxx-binding \
+	        --with-terminfo-dirs=${sysconfdir}/terminfo:${datadir}/terminfo \
+	        --enable-overwrite"
+export BUILD_CCFLAGS = "-I${S}/ncurses -I${S}/include ${BUILD_CFLAGS}"
+export BUILD_LDFLAGS =
+
+do_configure_prepend () {
+	if [ -e aclocal.m4 -a ! -e acinclude.m4 ]; then
+		cat aclocal.m4 > acinclude.m4
+	fi
+}
+
+do_configure () {
+# override this function to avoid the autoconf/automake/aclocal/autoheader
+# calls for now
+	oe_runconf
+}
+
+do_compile () {
+	oe_runmake BUILD_LDFLAGS="" 'BUILD_CCFLAGS=${BUILD_CCFLAGS}'
+}
+
+do_stage () {
+	for i in ncurses panel form menu; do
+		oe_soinstall lib/lib$i.so.${PV} ${STAGING_LIBDIR}/
+	done
+	for h in ncurses_*.h curses.h eti.h form.h menu.h panel.h \
+		termcap.h term.h unctrl.h; do
+		       install -m 0644 include/$h ${STAGING_INCDIR}/
+	done
+	ln -sf curses.h ${STAGING_INCDIR}/ncurses.h
+}