xerces-j 2.9.1: Added (from Jalimo SVN).

xerces-j-native 2.9.1: Dito.

2 files changed, 53 insertions, 0 deletions

diff --git a/recipes/xerces-j/xerces-j-native_2.9.1.bb b/recipes/xerces-j/xerces-j-native_2.9.1.bb
new file mode 100644
index 0000000000..9238ad9ff2
--- /dev/null
+++ b/recipes/xerces-j/xerces-j-native_2.9.1.bb
@@ -0,0 +1,8 @@
+require xerces-j_${PV}.bb
+
+S = "${WORKDIR}/xerces-2_9_1"
+
+inherit java-native
+
+DEPENDS = "fastjar-native jaxp1.3-native xml-commons-resolver1.1-native"
+RDEPENDS = ""
diff --git a/recipes/xerces-j/xerces-j_2.9.1.bb b/recipes/xerces-j/xerces-j_2.9.1.bb
new file mode 100644
index 0000000000..9a1b4c7956
--- /dev/null
+++ b/recipes/xerces-j/xerces-j_2.9.1.bb
@@ -0,0 +1,45 @@
+DESCRIPTION = "Reference implementation of XNI, the Xerces Native Interface, and also a fully conforming XML Schema processor."
+LICENSES = "AL2.0"
+AUTHOR = "Apache Software Foundation"
+
+SRC_URI = "http://www.apache.org/dist/xerces/j/Xerces-J-src.${PV}.tar.gz"
+
+S = "${WORKDIR}/xerces-2_9_1"
+
+inherit java-library
+
+JPN = "libxerces2-java"
+
+DEPENDS = "fastjar-native jaxp1.3 xml-commons-resolver1.1"
+RDEPENDS = "libjaxp1.3-java libxml-commons-resolver1.1-java"
+
+do_unpackpost() {
+  find src -exec \
+    sed -i -e "s|@impl.name@|Xerces-J ${PV}|" \
+           -e "s|@impl.version@|${PV}|" {} \;
+}
+
+addtask unpackpost after do_unpack before do_patch
+
+JARFILENAME = "xercesImpl.jar"
+ALTJARFILENAMES = ""
+
+do_compile() {
+  mkdir -p build
+
+  # Prepend the bootclasspath with the earlier XML API to make
+  # compilation succeed.
+  oe_makeclasspath bcp -s jaxp-1.3 resolver
+	bcp=$bcp:${STAGING_DATADIR_NATIVE}/classpath/glibj.zip
+
+  javac -sourcepath src -d build -bootclasspath $bcp `find src -name "*.java"`
+
+  (cd src && find org ! -name "*.java" -exec cp {} ../build/{} \;)
+
+  fastjar -C build -c -m src/manifest.xerces -f ${JARFILENAME} .
+
+  # Like Debian we provide a symlink called xmlParserAPIs.jar pointing to the JAXP
+  # classes.
+  ln -sf ${D}${datadir_java}/xmlParserAPIs.jar jaxp-1.3.jar
+
+}