gstreamer: updates

* switch to new-style staging
* add support for new-style checksums
* move plugins to newer versions, so plugins moved (e.g. ivorbis)
* fixup gstconfig header parsing

9 files changed, 98 insertions, 10 deletions

diff --git a/recipes/gstreamer/gst-common.inc b/recipes/gstreamer/gst-common.inc
index c6a3fd057d..c7420eede9 100644
--- a/recipes/gstreamer/gst-common.inc
+++ b/recipes/gstreamer/gst-common.inc
@@ -12,8 +12,3 @@ OE_LT_RPATH_ALLOW[export]="1"
 
 AUTOTOOLS_STAGE_PKGCONFIG = "1"
 
-do_stage() {
-	autotools_stage_all
-}
-
-
diff --git a/recipes/gstreamer/gst-plugins-bad_0.10.18.bb b/recipes/gstreamer/gst-plugins-bad_0.10.18.bb
new file mode 100644
index 0000000000..82710c7b25
--- /dev/null
+++ b/recipes/gstreamer/gst-plugins-bad_0.10.18.bb
@@ -0,0 +1,9 @@
+require gst-plugins.inc
+
+SRC_URI[archive.md5sum] = "84838893b447e774d401a698ff812b32"
+SRC_URI[archive.sha256sum] = "2f800127e00da0f157358f87b06563b3de23cbc630fbf6295b43405e52e02070"
+
+DEPENDS += "orc-native gst-plugins-base openssl directfb"
+
+# We don't have vdpau headers in OE and it creates crosscompile badness
+EXTRA_OECONF_append = " --disable-vdpau "
diff --git a/recipes/gstreamer/gst-plugins-base_0.10.28.bb b/recipes/gstreamer/gst-plugins-base_0.10.28.bb
new file mode 100644
index 0000000000..621a8918fe
--- /dev/null
+++ b/recipes/gstreamer/gst-plugins-base_0.10.28.bb
@@ -0,0 +1,26 @@
+require gst-plugins.inc
+
+SRC_URI += " \
+            file://gst-plugins-base_rowstride.patch;patch=1 \
+"
+
+SRC_URI[archive.md5sum] = "0107cf985ac90544bae70288220f5bab"
+SRC_URI[archive.sha256sum] = "132b6fd7749fcbfa9ad88c854aada44b6870c4175bda21cdb01a52b59a98e14f"
+
+PR = "${INC_PR}.0"
+
+PROVIDES += "gst-plugins"
+
+# gst-plugins-base only builds the alsa plugin
+# if alsa has been built and is present.  You will
+# not get an error if this is not present, just 
+# a missing alsa plugin
+DEPENDS += "udev cdparanoia pango libtheora alsa-lib libsm virtual/libx11 freetype gnome-vfs libxv"
+
+# Needs a udev that enabled gudev, which isn't the default
+EXTRA_OECONF_append = " --with-gudev"
+
+do_configure_prepend() {
+	sed -i -e s:QtGui:NoQtGui:g ${S}/configure.ac
+}
+
diff --git a/recipes/gstreamer/gst-plugins-good_0.10.21.bb b/recipes/gstreamer/gst-plugins-good_0.10.21.bb
new file mode 100644
index 0000000000..d93a37d53c
--- /dev/null
+++ b/recipes/gstreamer/gst-plugins-good_0.10.21.bb
@@ -0,0 +1,16 @@
+require gst-plugins.inc
+
+SRC_URI += "file://flvdemux-ecma.diff;patch=1 \
+"
+
+SRC_URI[archive.md5sum] = "9bc5c9b390edbb96bda42fc553eae5ae"
+SRC_URI[archive.sha256sum] = "24445a1cf56302ab4ad5f56055d5c3d81c704b8f9f6875fe78a25d4f72716d22"
+
+inherit gconf 
+
+DEPENDS += "hal pulseaudio speex libsoup-2.4 flac gst-plugins-base openssl popt esound libv4l"
+
+PACKAGES =+ "gst-plugin-gconfelements"
+FILES_gst-plugin-gconfelements += "${sysconfdir}/gconf"
+
+EXTRA_OECONF += " --with-libv4l2 "
diff --git a/recipes/gstreamer/gst-plugins-ugly_0.10.14.bb b/recipes/gstreamer/gst-plugins-ugly_0.10.14.bb
new file mode 100644
index 0000000000..d8295f5763
--- /dev/null
+++ b/recipes/gstreamer/gst-plugins-ugly_0.10.14.bb
@@ -0,0 +1,21 @@
+require gst-plugins.inc
+
+PR = "${INC_PR}.0"
+
+DEPENDS += "gst-plugins-base mpeg2dec libsidplay"
+
+SRC_URI += "\
+  file://gstmad_16bit.patch;patch=1 \
+  file://gstsid_autofoo_HACK.patch;patch=1 \
+"
+
+SRC_URI[archive.md5sum] = "0bc0d27bcce88c73ef6c81e88624e686"
+SRC_URI[archive.sha256sum] = "78dba9963e130cfd09f294b60219e6562459c5d848bc3b38a653db7f21fc850b"
+
+python() {
+	# Don't build, if we are building an ENTERPRISE distro
+	enterprise = bb.data.getVar("ENTERPRISE_DISTRO", d, 1)
+	if enterprise == "1":
+		raise bb.parse.SkipPackage("gst-plugins-ugly will only build if ENTERPRISE_DISTRO != 1")
+}
+
diff --git a/recipes/gstreamer/gst-plugins.inc b/recipes/gstreamer/gst-plugins.inc
index 32df9ece21..b060eb2bd4 100644
--- a/recipes/gstreamer/gst-plugins.inc
+++ b/recipes/gstreamer/gst-plugins.inc
@@ -9,13 +9,24 @@ INC_PR = "r7"
 
 PACKAGES_DYNAMIC = "gst-plugin-*"
 
-SRC_URI = "http://gstreamer.freedesktop.org/src/${PN}/${PN}-${PV}.tar.bz2"
+SRC_URI = "http://gstreamer.freedesktop.org/src/${PN}/${PN}-${PV}.tar.bz2;name=archive"
 
 EXTRA_OECONF = "--enable-introspection=no --disable-aalib --disable-shout2 --disable-sdl --disable-cdaudio --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR} "
 EXTRA_OECONF_append_shr = " --disable-dvdnav "
 
 acpaths = "-I ${S}/common/m4 -I ${S}/m4"
 
+# Fix up path to gstconfig.h
+do_configure_prepend() {
+	sed -i -e 's:`$PKG_CONFIG --variable=includedir gstreamer-0.10`:${STAGING_INCDIR}/gstreamer-0.10:g' ${S}/configure.ac
+}
+
+do_configure_append() {
+	for i in $(find ${S} -name "Makefile") ; do
+		sed -i -e s:/usr/bin/orcc:${STAGING_BINDIR_NATIVE}/orcc:g $i
+	done
+}
+
 OE_LT_RPATH_ALLOW = "any"
 OE_LT_RPATH_ALLOW[export]="1"
 
diff --git a/recipes/gstreamer/gst-rtsp_0.10.4.bb b/recipes/gstreamer/gst-rtsp_0.10.4.bb
index 11c57aa71f..ac7565bd9b 100644
--- a/recipes/gstreamer/gst-rtsp_0.10.4.bb
+++ b/recipes/gstreamer/gst-rtsp_0.10.4.bb
@@ -5,8 +5,7 @@ DEPENDS = "gst-plugins-base gstreamer"
 
 SRC_URI = "http://people.freedesktop.org/~wtay/gst-rtsp-${PV}.tar.bz2"
 
-inherit autotools_stage
+inherit autotools
 
-AUTOTOOLS_STAGE_PKGCONFIG = "1"
 
 
diff --git a/recipes/gstreamer/gstreamer.inc b/recipes/gstreamer/gstreamer.inc
index 87a6f82135..aff25e7baa 100644
--- a/recipes/gstreamer/gstreamer.inc
+++ b/recipes/gstreamer/gstreamer.inc
@@ -5,10 +5,10 @@ It supports a wide range of formats including mp3, ogg, avi, mpeg and quicktime.
 
 DEPENDS = "libxml2 glib-2.0 gettext-native popt"
 
-SRC_URI = "http://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.bz2"
+SRC_URI = "http://gstreamer.freedesktop.org/src/gstreamer/gstreamer-${PV}.tar.bz2;name=archive"
 EXTRA_OECONF = "--disable-docs-build --disable-dependency-tracking --with-check=no"
 
 FILES_${PN} += " ${libdir}/gstreamer-0.10/*.so"
 FILES_${PN}-dev += " ${libdir}/gstreamer-0.10/*.la ${libdir}/gstreamer-0.10/*.a"
-FILES_${PN}-dbg += "${libdir}/gstreamer-0.10/.debug"
+FILES_${PN}-dbg += "${libexecdir}/gstreamer-0.10/.debug ${libdir}/gstreamer-0.10/.debug"
 
diff --git a/recipes/gstreamer/gstreamer_0.10.28.bb b/recipes/gstreamer/gstreamer_0.10.28.bb
new file mode 100644
index 0000000000..c44646c60d
--- /dev/null
+++ b/recipes/gstreamer/gstreamer_0.10.28.bb
@@ -0,0 +1,11 @@
+require gstreamer.inc
+
+SRC_URI[archive.md5sum] = "1c7accac718fe211ff91323c27d4ae02"
+SRC_URI[archive.sha256sum] = "61613ec7574d22230e8cc893f91b66faec6b21288a22d2f21c9d9eeb7667eb2c"
+
+EXTRA_OECONF += "ac_cv_func_register_printf_function=no"
+
+do_configure_prepend() {
+	sed -i -e s:docs::g Makefile.am
+}
+