gnumeric: update to 1.8.4

We updated it to latest stable release and droped the old versions
since noone is preferring those. Another small change is to depends on
gdk-pixbuf-csource-native otherwise the build can fail if the host
doesn't has the development files of GTK+ installed.

The only reference to a gnumeric version has been found at
preferred-om-2008-versions.inc and it referred to a missing
version. This also makes it to point to the latest one.

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

1 files changed, 31 insertions, 0 deletions

diff --git a/recipes/gnumeric/gnumeric_1.8.4.bb b/recipes/gnumeric/gnumeric_1.8.4.bb
new file mode 100644
index 0000000000..e375f278f2
--- /dev/null
+++ b/recipes/gnumeric/gnumeric_1.8.4.bb
@@ -0,0 +1,31 @@
+LICENSE = "GPL"
+SECTION = "x11/utils"
+S = "${WORKDIR}/gnumeric-${PV}"
+DEPENDS = "gdk-pixbuf-csource-native libgsf gtk+ libxml2 goffice libglade libart-lgpl intltool-native libgnomecanvas libgnomeprint libgnomeprintui libbonoboui orbit2-native"
+DESCRIPTION = "Gnumeric spreadsheet for GNOME"
+
+PR = "r0"
+
+PARALLEL_MAKE = ""
+
+inherit gnome flow-lossage
+
+SRC_URI += "file://remove-docs.patch;patch=1"
+
+EXTRA_OECONF=" --without-perl "
+
+PACKAGES_DYNAMIC += "gnumeric-plugin-*"
+
+FILES_${PN}-dbg += "${libdir}/gnumeric/${PV}/plugins/*/.debug"
+FILES_gnumeric_append = " /usr/lib/libspreadsheet-${PV}.so "
+
+# We need native orbit-idl with target idl files. No way to say it in a clean way:
+do_configure_append () {
+	find -name Makefile -exec sed -i '/\/usr\/bin\/orbit-idl-2/{s:/usr/bin:${STAGING_BINDIR_NATIVE}:;s:/usr/share:${STAGING_DATADIR}:g}' {} \;
+}
+
+python populate_packages_prepend () {
+	gnumeric_libdir = bb.data.expand('${libdir}/gnumeric/${PV}/plugins', d)
+
+	do_split_packages(d, gnumeric_libdir, '(.*)', 'gnumeric-plugin-%s', 'Gnumeric plugin for %s', allow_dirs=True)
+}