pango: update to 1.15.1, changes LIBV to 1.6.0

from the NEWS:
* Optimizations:
  - Rework PangoLayout algorithms to avoid calling a recursive call to
    pango_layout_get_extents().  Avoids one pango_font_get_glyph_extents()
    call per glyph per layout rendering.  We now make 2 such calls.
  - Don't cache run_logical_rect in PangoLayoutIter.
    Avoids one pango_font_get_glyph_extents() call per glyph per layout
    rendering.  We are down to 1 now.
  - Cache line extents.  This avoids the final pango_font_get_glyph_extents()
    call per glyph per layout rendering.  Now we don't make any
    pango_font_get_glyph_extents() calls when rendering a layout (some
    conditions apply)!
  - Replace PANGO_IS_RENDERER with PANGO_IS_RENDERER_FAST for most
    internal uses, that is, just a NULL-check.
  - Use simple, fast, casts instead of PANGO_CAIRO_*() macros where the
    object cannot have reached us if it wasn't of the right type.

1 files changed, 51 insertions, 0 deletions

diff --git a/packages/pango/pango_1.15.1.bb b/packages/pango/pango_1.15.1.bb
new file mode 100644
index 0000000000..8847b88549
--- /dev/null
+++ b/packages/pango/pango_1.15.1.bb
@@ -0,0 +1,51 @@
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+LICENSE = "LGPL"
+SECTION = "x11/libs"
+
+DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft gtk-doc cairo"
+
+PR = "r0"
+
+PACKAGES_DYNAMIC = "pango-module-*"
+
+RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc" 
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/pango/1.15/pango-${PV}.tar.bz2 \
+	   file://no-tests.patch;patch=1 \
+		"
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glibtest \
+		--enable-explicit-deps=no \
+	        --disable-debug"
+
+LEAD_SONAME = "libpango-1.0*"
+LIBV = "1.6.0"
+
+FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*.so.*"
+FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
+FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
+
+do_stage () {
+	autotools_stage_all
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+python populate_packages_prepend () {
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+	do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}