update to wpa_supplicant 0.6.3 (also add 0.6.0 in) and build packages for

it.

1 files changed, 65 insertions, 0 deletions

diff --git a/packages/wpa-supplicant/wpa-supplicant-0.6.inc b/packages/wpa-supplicant/wpa-supplicant-0.6.inc
new file mode 100644
index 0000000000..6198958cd5
--- /dev/null
+++ b/packages/wpa-supplicant/wpa-supplicant-0.6.inc
@@ -0,0 +1,65 @@
+DESCRIPTION = "A Client for Wi-Fi Protected Access (WPA)."
+SECTION = "network"
+LICENSE = "GPL"
+HOMEPAGE = "http://hostap.epitest.fi/wpa_supplicant/"
+DEPENDS = "dbus gnutls ${@base_contains("COMBINED_FEATURES", "pci", "madwifi-ng", "",d)}"
+
+#we introduce MY_ARCH to get 'armv5te' as arch instead of the misleading 'arm' on armv5te builds
+MY_ARCH := "${PACKAGE_ARCH}"
+PACKAGE_ARCH = "${@base_contains('COMBINED_FEATURES', 'pci', '${MACHINE_ARCH}', '${MY_ARCH}', d)}"
+
+DEFAULT_PREFERENCE = "-2"
+
+SRC_URI = "http://hostap.epitest.fi/releases/wpa_supplicant-${PV}.tar.gz \
+	file://defconfig-0.6.0-gnutls \
+	file://ifupdown.sh \
+	file://functions.sh"
+
+#	file://gnutlsfix.patch;patch=1 \
+
+S = "${WORKDIR}/wpa_supplicant-${PV}/wpa_supplicant"
+
+PACKAGES_prepend = "wpa-supplicant-passphrase "
+FILES_wpa-supplicant-passphrase = "/usr/sbin/wpa_passphrase"
+
+RREPLACES = "wpa-supplicant-cli"
+
+RRECOMMENDS_${PN} = "wpa-supplicant-passphrase"
+
+export HAS_PCI = "${@base_contains('COMBINED_FEATURES', 'pci', 1, 0,d)}"
+
+do_configure () {
+        install -m 0755 ${WORKDIR}/defconfig-0.6.0-gnutls  .config
+
+        if [ "x$HAS_PCI" == "x1" ] ; then
+                echo "CONFIG_DRIVER_MADWIFI=y" >> .config
+                echo "CFLAGS += -I${STAGING_INCDIR}/madwifi-ng" >> .config
+        fi
+}
+
+do_compile () {
+	make
+}
+
+do_install () {
+	install -d ${D}${sbindir}
+	install -m 755 wpa_supplicant ${D}${sbindir}
+	install -m 755 wpa_passphrase ${D}${sbindir}
+	install -m 755 wpa_cli        ${D}${sbindir}
+
+	install -d ${D}${localstatedir}/run/wpa_supplicant
+
+	install -d ${D}${docdir}/wpa_supplicant
+	install -m 644 README ${D}${docdir}/wpa_supplicant
+
+	install -d ${D}${sysconfdir}/network/if-pre-up.d/
+	install -d ${D}${sysconfdir}/network/if-post-down.d/
+	install -d ${D}${sysconfdir}/network/if-down.d/
+
+	install -d ${D}${sysconfdir}/wpa_supplicant
+	install -m 755 ${WORKDIR}/ifupdown.sh ${D}${sysconfdir}/wpa_supplicant/
+	install -m 755 ${WORKDIR}/functions.sh ${D}${sysconfdir}/wpa_supplicant
+	
+	ln -s /etc/wpa_supplicant/ifupdown.sh ${D}${sysconfdir}/network/if-pre-up.d/wpasupplicant
+	ln -s /etc/wpa_supplicant/ifupdown.sh ${D}${sysconfdir}/network/if-post-down.d/wpasupplicant
+}