vsftpd-charconv 2.0.5: Add version patched for on-the-file filenames transcoding,

* This patch is extracted and cleaned up version of filename character 
set conversion patches for vsftpd by Dmitriy Balashov,  
http://vsftpd.devnet.ru/eng/ . It provides dirty-pragmatics approach 
towards serving Windows codepages encoded filenames to Windows clients 
out of normal utf-8 filesystem. 
 
These patches will never be accepted upstream, they should never be merged 
to main vsftpd package, and they for sure void "vs" in "vsftpd". So again, 
they are for users to prefer stone-dead pragmatics. Use at you own risk. 

1 files changed, 50 insertions, 0 deletions

diff --git a/packages/vsftpd/vsftpd-charconv_2.0.5.bb b/packages/vsftpd/vsftpd-charconv_2.0.5.bb
new file mode 100644
index 0000000000..cc559c6259
--- /dev/null
+++ b/packages/vsftpd/vsftpd-charconv_2.0.5.bb
@@ -0,0 +1,50 @@
+DESCRIPTION = "Secure ftp daemon with filename charconv"
+SECTION = "console/network"
+LICENSE = "GPL"
+PR = "r1"
+
+FILESPATH_append = ":${@os.path.dirname(bb.data.getVar('FILE',d,1))}/vsftpd-2.0.5"
+
+SRC_URI = "ftp://vsftpd.beasts.org/users/cevans/vsftpd-${PV}.tar.gz \
+           file://vsftpd-charconv.patch;patch=1 \
+           file://makefile.patch;patch=1 \
+           file://nopam.patch;patch=1 \
+           file://syscall.patch;patch=1 \
+           file://init \
+           file://vsftpd.conf"
+	   
+S = "${WORKDIR}/vsftpd-2.0.5"
+
+inherit update-rc.d
+
+do_configure() {
+        # Fix hardcoded /usr, /etc, /var mess.
+        cat tunables.c|sed s:\"/usr:\"${prefix}:g|sed s:\"/var:\"${localstatedir}:g \
+        |sed s:\"${prefix}/share/empty:\"${localstatedir}/share/empty:g |sed s:\"/etc:\"${sysconfdir}:g > tunables.c.new
+        mv tunables.c.new tunables.c
+}
+
+do_compile() {
+        oe_runmake "LIBS=-lcrypt -L${STAGING_LIBDIR}"
+}
+
+do_install() {
+        install -d ${D}${sbindir}
+        install -d ${D}${mandir}/man8
+        install -d ${D}${mandir}/man5
+        oe_runmake 'DESTDIR=${D}' install
+        install -d ${D}${sysconfdir}
+        install -m 0755 ${WORKDIR}/vsftpd.conf ${D}${sysconfdir}/vsftpd.conf
+        install -d ${D}${sysconfdir}/init.d/
+        install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/vsftpd
+}
+
+pkg_postinst() {
+        addgroup ftp
+        adduser --system --home /var/tmp/ftp --no-create-home --ingroup ftp --disabled-password -s /bin/false ftp
+        mkdir -p ${localstatedir}/share/empty
+}
+
+INITSCRIPT_NAME = "vsftpd"
+
+INITSCRIPT_PARAMS = "defaults"