psmisc 22.2: Add 22.2 and use a common .inc file for 21.8 and 22.8.

Added to fix some IPv6 related bugs. See the changelog in 22.2 source
for full list.

1 files changed, 42 insertions, 0 deletions

diff --git a/packages/psmisc/psmisc.inc b/packages/psmisc/psmisc.inc
new file mode 100644
index 0000000000..31647c7b4b
--- /dev/null
+++ b/packages/psmisc/psmisc.inc
@@ -0,0 +1,42 @@
+LICENSE = "GPL"
+DESCRIPTION = "procfs tools"
+SECTION = "base"
+PRIORITY = "required"
+MAINTAINER = "Greg Gilbert <greg@treke.net>"
+DEPENDS = "ncurses virtual/libintl"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/psmisc/psmisc-${PV}.tar.gz \
+	   file://libintl-link.patch;patch=1"
+S = "${WORKDIR}/psmisc-${PV}"
+
+inherit autotools gettext
+
+ALLOW_EMPTY = "1"
+
+PACKAGES = "${PN} fuser fuser-doc \
+	    killall killall-doc \
+	    pstree pstree-doc"
+
+FILES_${PN} = ""
+RDEPENDS_${PN} = "fuser killall pstree"
+
+FILES_fuser = "${bindir}/fuser"
+FILES_fuser-doc = "${mandir}/man1/fuser*"
+
+FILES_killall = "${bindir}/killall.${PN}"
+FILES_killall-doc = "${mandir}/man1/killall*"
+
+FILES_pstree = "${bindir}/pstree"
+FILES_pstree-doc = "${mandir}/man1/pstree*"
+
+do_install_append() {
+	mv ${D}${bindir}/killall ${D}${bindir}/killall.${PN}
+}
+
+pkg_postinst_killall() {
+	update-alternatives --install ${bindir}/killall killall killall.${PN} 90
+}
+
+pkg_postrm_killall() {
+	update-alternatives --remove ${bindir}/killall killall.${PN}
+}