pango: update to 1.14

1 files changed, 49 insertions, 0 deletions

diff --git a/packages/pango/pango_1.14.0.bb b/packages/pango/pango_1.14.0.bb
new file mode 100644
index 0000000000..77eee85214
--- /dev/null
+++ b/packages/pango/pango_1.14.0.bb
@@ -0,0 +1,49 @@
+LICENSE = "LGPL"
+SECTION = "x11/libs"
+# Xt needed to keep autoconf's check for X11 happy
+DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libx11 libxft xt gtk-doc cairo"
+DESCRIPTION = "The goal of the Pango project is to provide an \
+Open Source framework for the layout and rendering of \
+internationalized text."
+PR = "r0"
+
+RRECOMMENDS_${PN} = "pango-module-basic-x pango-module-basic-fc" 
+
+# seems to go wrong with default cflags
+FULL_OPTIMIZATION_arm = "-O2"
+
+SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/pango/1.14/pango-${PV}.tar.bz2 \
+	   file://no-tests.patch;patch=1 \
+		"
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-glibtest \
+		--enable-explicit-deps=no \
+	        --disable-debug"
+
+FILES_${PN} = "/etc ${bindir} ${libdir}/libpango*.so.*"
+
+LIBV = "1.5.0"
+
+do_stage () {
+	for lib in pango pangox pangoft2 pangoxft pangocairo; do
+		oe_libinstall -so -C pango lib$lib-1.0 ${STAGING_LIBDIR}/
+	done
+	install -d ${STAGING_INCDIR}/pango
+	install -m 0644 ${S}/pango/pango*.h ${STAGING_INCDIR}/pango/
+}
+
+postinst_prologue() {
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+}
+
+python populate_packages_prepend () {
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
+
+	do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
+}