Merge bk://oe-devel@oe-devel.bkbits.net/openembedded

into t.(none):/home/OE/speedracer/packages

2004/12/09 16:29:29-06:00 ti.com!kergoth
In some kernel packages, move the set of PACKAGE_ARCH to below the inherit of kernel.

BKrev: 41b8d1capsuSJAmgsLcGU1QsukrfIA

1 files changed, 59 insertions, 0 deletions

diff --git a/packages/linux/handhelds-pxa_2.4.19-rmk6-pxa1-hh36.14.bb b/packages/linux/handhelds-pxa_2.4.19-rmk6-pxa1-hh36.14.bb
index e69de29bb2..718a188297 100644
--- a/packages/linux/handhelds-pxa_2.4.19-rmk6-pxa1-hh36.14.bb
+++ b/packages/linux/handhelds-pxa_2.4.19-rmk6-pxa1-hh36.14.bb
@@ -0,0 +1,59 @@
+SECTION = "kernel"
+DESCRIPTION = "handhelds.org Linux kernel for PXA25x based devices."
+MAINTAINER = "Phil Blundell <pb@handhelds.org>"
+LICENSE = "GPL"
+PR = "r3"
+
+KERNEL_CCSUFFIX = "-3.3.3"
+COMPATIBLE_HOST = "arm.*-linux"
+
+SRC_URI = "${HANDHELDS_CVS};module=linux/kernel;tag=${@'K' + bb.data.getVar('PV',d,1).replace('.', '-')} \
+	   file://defconfig-ipaqpxa \
+	   file://ipaq-hal.init \
+	   file://linux-2.4-no-short-loads.patch;patch=1 \
+	   file://linux-2.4-cpufreq.patch;patch=1"
+
+S = "${WORKDIR}/kernel"
+
+inherit kernel update-rc.d
+
+PACKAGE_ARCH = "ipaqpxa"
+
+K_MAJOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[0]}"
+K_MINOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[1]}"
+K_MICRO = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[2]}"
+RMKV    = "${@bb.data.getVar('PV',d,1).split('-')[1].split('rmk')[-1]}"
+PXAV    = "${@bb.data.getVar('PV',d,1).split('-')[2].split('pxa')[-1]}"
+HHV     = "${@bb.data.getVar('PV',d,1).split('-')[3].split('hh')[-1]}"
+
+KERNEL_PRIORITY = "${@'%d' % (int(bb.data.getVar('K_MAJOR',d,1)) * 100000000 + int(bb.data.getVar('K_MINOR',d,1)) * 1000000 + int(bb.data.getVar('K_MICRO',d,1)) * 10000 + int(bb.data.getVar('RMKV',d,1)) * 1000 + int(bb.data.getVar('PXAV',d,1)) * 100 + float(bb.data.getVar('HHV',d,1)))}"
+
+module_conf_h3900_asic = "alias ipaq_hal_3900 h3900_asic"
+module_conf_h5400_asic = "alias ipaq_hal_5400 h5400_asic"
+module_conf_pxa_ir = "alias irda0 pxa_ir"
+module_conf_i2c_algo_pxa = "options i2c-algo-pxa pxa_scan=0"
+module_conf_pcmcia_core = "options pcmcia_core ignore_cis_vcc=1"
+module_conf_ppp_async = "alias ppp0 ppp_async"
+module_conf_orinoco_cs = "options orinoco_cs ignore_cis_vcc=1"
+module_conf_hostap_cs = "options hostap_cs ignore_cis_vcc=1"
+
+module_autoload_h3600_generic_sleeve = "h3600_generic_sleeve"
+module_autoload_h3600_ts = "h3600_ts"
+module_autoload_apm = "apm"
+module_autoload_af_packet = "af_packet"
+module_autoload_usb-ohci-h5400 = "usb-ohci-h5400"
+module_autoload_ppp_async = "ppp_async"
+module_autoload_usb_eth = "usb-eth"
+
+FILES_kernel += "/etc/init.d/ipaq-hal"
+INITSCRIPT_NAME = "ipaq-hal"
+INITSCRIPT_PARAMS = "start 21 S ."
+
+do_configure_prepend() {
+	install -m 0644 ${WORKDIR}/defconfig-${PACKAGE_ARCH} ${S}/.config
+}
+
+do_install_append() {
+	install -d ${D}/etc/init.d
+	install ${WORKDIR}/ipaq-hal.init ${D}/etc/init.d/ipaq-hal
+}