handhelds-pxa-2.6_2.6.16-hh5: Recipe for the latest HH.org 2.6.16 tag.

Based on handhelds-pxa-2.6_2.6.15-hh0.bb.

1 files changed, 40 insertions, 0 deletions

diff --git a/packages/linux/handhelds-pxa-2.6_2.6.16-hh5.bb b/packages/linux/handhelds-pxa-2.6_2.6.16-hh5.bb
new file mode 100644
index 0000000000..555ec411ee
--- /dev/null
+++ b/packages/linux/handhelds-pxa-2.6_2.6.16-hh5.bb
@@ -0,0 +1,40 @@
+SECTION = "kernel"
+DESCRIPTION = "handhelds.org Linux kernel for PXA based devices."
+MAINTAINER = "Greg Gilbert <greg@treke.net>"
+LICENSE = "GPL"
+
+DEFAULT_PREFERENCE = "-1"
+
+COMPATIBLE_HOST = "arm.*-linux"
+COMPATIBLE_MACHINE = '(h3900|h2200|h4000|ipaq-pxa270)'
+
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/handhelds-pxa-${PV}"
+
+SRC_URI = "${HANDHELDS_CVS};module=linux/kernel26;tag=${@'K' + bb.data.getVar('PV',d,1).replace('.', '-')} \
+	file://ide_not_removable-r0.patch;patch=1 \
+	file://block-pio.patch;patch=1 \
+	file://defconfig"
+
+S = "${WORKDIR}/kernel26"
+
+inherit kernel
+
+K_MAJOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[0]}"
+K_MINOR = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[1]}"
+K_MICRO = "${@bb.data.getVar('PV',d,1).split('-')[0].split('.')[2]}"
+HHV     = "${@bb.data.getVar('PV',d,1).split('-')[1].split('hh')[-1]}"
+
+KERNEL_PRIORITY = "${@'%d' % (int(bb.data.getVar('K_MAJOR',d,1)) * 100000000 + int(bb.data.getVar('K_MINOR',d,1)) * 1000000 + int(bb.data.getVar('K_MICRO',d,1)) * 10000 + float(bb.data.getVar('HHV',d,1)))}"
+do_configure() {
+	install -m 0644 ${WORKDIR}/defconfig ${S}/.config || die "No default configuration for ${MACHINE} available."
+        yes '' | oe_runmake oldconfig
+}
+
+do_deploy() {
+	install -d ${DEPLOY_DIR_IMAGE}
+	install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}
+}   
+   
+do_deploy[dirs] = "${S}"
+
+addtask deploy before do_build after do_compile