hostap-daemon: use version 0.5.10 by default

1 files changed, 42 insertions, 0 deletions

diff --git a/packages/hostap/hostap-daemon_0.5.10.bb b/packages/hostap/hostap-daemon_0.5.10.bb
new file mode 100644
index 0000000000..f75efc4a34
--- /dev/null
+++ b/packages/hostap/hostap-daemon_0.5.10.bb
@@ -0,0 +1,42 @@
+DESCRIPTION = "User space daemon for extended IEEE 802.11 management"
+HOMEPAGE = "http://hostap.epitest.fi"
+SECTION = "kernel/userland"
+PRIORITY = "optional"
+LICENSE = "GPL"
+DEPENDS = "openssl ${@base_contains("COMBINED_FEATURES", "pci", "madwifi-ng", "",d)}"
+
+#we introduce MY_ARCH to get 'armv5te' as arch instead of the misleading 'arm' on armv5te builds
+MY_ARCH := "${PACKAGE_ARCH}"
+PACKAGE_ARCH = "${@base_contains('COMBINED_FEATURES', 'pci', '${MACHINE_ARCH}', '${MY_ARCH}', d)}"
+
+SRC_URI = "http://hostap.epitest.fi/releases/hostapd-${PV}.tar.gz \
+	file://makefile-cross.diff;patch=1 \
+	file://defconfig \
+	file://init"
+
+S = "${WORKDIR}/hostapd-${PV}"
+
+export HAS_PCI = "${@base_contains('COMBINED_FEATURES', 'pci', 1, 0,d)}"
+
+inherit update-rc.d
+INITSCRIPT_NAME=hostapd
+
+do_configure() {
+	install -m 0644 ${WORKDIR}/defconfig ${S}/.config
+	if [ "x$HAS_PCI" == "x1" ] ; then
+		echo "CONFIG_DRIVER_MADWIFI=y" >> .config
+		echo "CFLAGS += -I${STAGING_INCDIR}/madwifi-ng" >> .config
+	fi
+}
+
+do_compile() {
+	make
+}
+
+do_install() {
+	install -d ${D}${sbindir} ${D}${sysconfdir}/init.d
+	make TARGET_PREFIX=${D}${sbindir} install
+	install -m 0644 hostapd.conf ${D}${sysconfdir}
+	install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
+}
+