gtk: add 2.12.0 from poky

1 files changed, 47 insertions, 0 deletions

diff --git a/packages/gtk+/gtk+_2.12.0.bb b/packages/gtk+/gtk+_2.12.0.bb
new file mode 100644
index 0000000000..6b724bab80
--- /dev/null
+++ b/packages/gtk+/gtk+_2.12.0.bb
@@ -0,0 +1,47 @@
+require gtk+.inc
+
+DEPENDS += "cairo"
+
+# disable per default - untested and not all patches included.
+DEFAULT_PREFERENCE = "-1" 
+
+SRC_URI = "http://download.gnome.org/sources/gtk+/2.12/gtk+-${PV}.tar.bz2 \
+           file://xsettings.patch;patch=1 \
+           file://run-iconcache.patch;patch=1 \
+           file://disable-print.patch;patch=1 \
+           file://hardcoded_libtool.patch;patch=1 \
+           file://no-demos.patch;patch=1 \
+           file://cellrenderer-cairo.patch;patch=1;pnum=0 \
+           file://entry-cairo.patch;patch=1;pnum=0 \
+           file://toggle-font.diff;patch=1;pnum=0 \
+           file://scrolled-placement.patch;patch=1;pnum=0"
+# temporary
+#           file://gtklabel-resize-patch;patch=1 \
+#           file://menu-deactivate.patch;patch=1 \
+#           file://combo-arrow-size.patch;patch=1;pnum=0 \
+# die die die
+#           file://pangoxft2.10.6.diff;patch=1"
+
+EXTRA_OECONF = "--without-libtiff --disable-xkb --disable-glibtest --enable-display-migration"
+
+LIBV = "2.10.0"
+
+PACKAGES_DYNAMIC = "gdk-pixbuf-loader-* gtk-immodule-* gtk-printbackend-*"
+
+python populate_packages_prepend () {
+	import os.path
+
+	prologue = bb.data.getVar("postinst_prologue", d, 1)
+
+	gtk_libdir = bb.data.expand('${libdir}/gtk-2.0/${LIBV}', d)
+	loaders_root = os.path.join(gtk_libdir, 'loaders')
+	immodules_root = os.path.join(gtk_libdir, 'immodules')
+	printmodules_root = os.path.join(gtk_libdir, 'printbackends');
+
+	do_split_packages(d, loaders_root, '^libpixbufloader-(.*)\.so$', 'gdk-pixbuf-loader-%s', 'GDK pixbuf loader for %s', prologue + 'gdk-pixbuf-query-loaders > /etc/gtk-2.0/gdk-pixbuf.loaders')
+	do_split_packages(d, immodules_root, '^im-(.*)\.so$', 'gtk-immodule-%s', 'GTK input module for %s', prologue + 'gtk-query-immodules-2.0 > /etc/gtk-2.0/gtk.immodules')
+	do_split_packages(d, printmodules_root, '^libprintbackend-(.*)\.so$', 'gtk-printbackend-%s', 'GTK printbackend module for %s')
+
+        if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
+                bb.data.setVar('PKG_${PN}', 'libgtk-2.0', d)
+}