Move eglibc to a separate package. Adios glibc.

15 files changed, 563 insertions, 0 deletions

diff --git a/packages/eglibc/.mtn2git_empty b/packages/eglibc/.mtn2git_empty
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/eglibc/.mtn2git_empty
diff --git a/packages/eglibc/eglibc-initial.inc b/packages/eglibc/eglibc-initial.inc
new file mode 100644
index 0000000000..342711c157
--- /dev/null
+++ b/packages/eglibc/eglibc-initial.inc
@@ -0,0 +1,31 @@
+SECTION = "libs"
+DEPENDS = "linux-libc-headers"
+PROVIDES = "virtual/${TARGET_PREFIX}libc-initial"
+FILESPATH = "${@base_set_filespath([ '${FILE_DIRNAME}/eglibc', '${FILE_DIRNAME}/files', '${FILE_DIRNAME}' ], d)}"
+
+PACKAGES = ""
+PACKAGES_DYNAMIC = ""
+
+do_configure () {
+	sed -ie 's,{ (exit 1); exit 1; }; },{ (exit 0); }; },g' ${S}/configure
+	chmod +x ${S}/configure
+	CC="${BUILD_CC}" CPP="${BUILD_CPP}" LD="${BUILD_LD}" \
+	${S}/configure --host=${TARGET_SYS} --build=${BUILD_SYS} \
+		--without-cvs --disable-sanity-checks \
+		--with-headers=${STAGING_DIR_TARGET}${layout_includedir} \
+		--enable-hacker-mode
+}
+
+do_compile () {
+	:
+}
+
+do_stage () {
+	oe_runmake cross-compiling=yes install_root=${STAGING_DIR_HOST} \
+	includedir='${layout_includedir}' prefix='${layout_prefix}' install-headers
+
+}
+
+do_install () {
+	:
+}
diff --git a/packages/eglibc/eglibc-initial_svn.bb b/packages/eglibc/eglibc-initial_svn.bb
new file mode 100644
index 0000000000..787c762609
--- /dev/null
+++ b/packages/eglibc/eglibc-initial_svn.bb
@@ -0,0 +1,6 @@
+require eglibc_${PV}.bb
+require eglibc-initial.inc
+
+do_configure_prepend () {
+        unset CFLAGS
+}
diff --git a/packages/eglibc/eglibc-intermediate.inc b/packages/eglibc/eglibc-intermediate.inc
new file mode 100644
index 0000000000..c226d8658d
--- /dev/null
+++ b/packages/eglibc/eglibc-intermediate.inc
@@ -0,0 +1,12 @@
+SECTION = "libs"
+PACKAGES = ""
+PACKAGES_DYNAMIC = ""
+PROVIDES = "virtual/${TARGET_PREFIX}libc-for-gcc"
+DEPENDS = "virtual/${TARGET_PREFIX}gcc-initial linux-libc-headers"
+
+do_install () {
+	:
+}
+
+GLIBC_ADDONS = "nptl,ports"
+GLIBC_EXTRA_OECONF = ""
diff --git a/packages/eglibc/eglibc-intermediate_svn.bb b/packages/eglibc/eglibc-intermediate_svn.bb
new file mode 100644
index 0000000000..7150f56d26
--- /dev/null
+++ b/packages/eglibc/eglibc-intermediate_svn.bb
@@ -0,0 +1,8 @@
+require eglibc_${PV}.bb
+require eglibc-intermediate.inc
+
+# gcc uses -Werror which break on a "you have no thumb interwork" _warning_
+do_configure_prepend() {
+	find ${S} -name "configure" | xargs touch
+	sed -i s:-Werror:: ${S}/configure
+}
diff --git a/packages/eglibc/eglibc-package.bbclass b/packages/eglibc/eglibc-package.bbclass
new file mode 100644
index 0000000000..2de24db859
--- /dev/null
+++ b/packages/eglibc/eglibc-package.bbclass
@@ -0,0 +1,334 @@
+#
+# For now, we will skip building of a gcc package if it is a uclibc one
+# and our build is not a uclibc one, and we skip a eglibc one if our build
+# is a uclibc build.
+#
+# See the note in gcc/gcc_3.4.0.oe
+#
+
+python __anonymous () {
+    import bb, re
+    uc_os = (re.match('.*uclibc*', bb.data.getVar('TARGET_OS', d, 1)) != None)
+    if uc_os:
+        raise bb.parse.SkipPackage("incompatible with target %s" %
+                                   bb.data.getVar('TARGET_OS', d, 1))
+}
+
+
+# Binary locales are generated at build time if ENABLE_BINARY_LOCALE_GENERATION
+# is set. The idea is to avoid running localedef on the target (at first boot)
+# to decrease initial boot time and avoid localedef being killed by the OOM
+# killer which used to effectively break i18n on machines with < 128MB RAM.
+
+# default to disabled until qemu works for everyone
+ENABLE_BINARY_LOCALE_GENERATION ?= "0"
+
+# BINARY_LOCALE_ARCHES is a space separated list of regular expressions
+BINARY_LOCALE_ARCHES ?= "arm.*"
+
+PACKAGES = "eglibc-dbg eglibc catchsegv sln nscd ldd localedef eglibc-utils eglibc-dev eglibc-doc eglibc-locale libsegfault eglibc-extra-nss eglibc-thread-db eglibc-pcprofile"
+PACKAGES_DYNAMIC = "glibc-gconv-* glibc-charmap-* glibc-localedata-* glibc-binary-localedata-* eglibc-gconv-* eglibc-charmap-* eglibc-localedata-* eglibc-binary-localedata-* locale-base-*"
+
+RPROVIDES_eglibc = "glibc"
+RPROVIDES_eglibc-utils = "glibc-utils"
+RPROVIDES_eglibc-dev = "glibc-dev"
+RPROVIDES_eglibc-doc = "glibc-doc"
+RPROVIDES_eglibc-locale = "glibc-locale"
+RPROVIDES_eglibc-extra-nss = "glibc-extra-nss"
+RPROVIDES_eglibc-thread-db = "glibc-thread-db"
+RPROVIDES_eglibc-pcprofile = "glibc-pcprofile"
+RPROVIDES_eglibc-dbg = "glibc-dbg"
+
+libc_baselibs = "/lib/libc* /lib/libm* /lib/ld* /lib/libpthread* /lib/libresolv* /lib/librt* /lib/libutil* /lib/libnsl* /lib/libnss_files* /lib/libnss_compat* /lib/libnss_dns* /lib/libdl* /lib/libanl* /lib/libBrokenLocale*"
+
+FILES_${PN} = "${sysconfdir} ${libc_baselibs} /sbin/ldconfig ${libexecdir}/* ${datadir}/zoneinfo"
+FILES_ldd = "${bindir}/ldd"
+FILES_libsegfault = "/lib/libSegFault*"
+FILES_eglibc-extra-nss = "/lib/libnss*"
+FILES_sln = "/sbin/sln"
+FILES_eglibc-dev_append = " ${libdir}/*.o ${bindir}/rpcgen"
+FILES_nscd = "${sbindir}/nscd*"
+FILES_eglibc-utils = "${bindir}/* ${sbindir}/*"
+FILES_eglibc-gconv = "${libdir}/gconv/*"
+FILES_${PN}-dbg += "${libexecdir}/*/.debug ${libdir}/gconv/.debug"
+FILES_catchsegv = "${bindir}/catchsegv"
+RDEPENDS_catchsegv = "libsegfault"
+FILES_eglibc-pcprofile = "/lib/libpcprofile.so"
+FILES_eglibc-thread-db = "/lib/libthread_db*"
+FILES_localedef = "${bindir}/localedef"
+RPROVIDES_eglibc-dev += "libc-dev"
+
+DESCRIPTION_sln = "eglibc: create symbolic links between files"
+DESCRIPTION_nscd = "eglibc: name service cache daemon for passwd, group, and hosts"
+DESCRIPTION_eglibc-extra-nss = "eglibc: nis, nisplus and hesiod search services"
+DESCRIPTION_ldd = "eglibc: print shared library dependencies"
+DESCRIPTION_localedef = "eglibc: compile locale definition files"
+DESCRIPTION_eglibc-utils = "eglibc: misc utilities like iconf, local, gencat, tzselect, rpcinfo, ..."
+
+def get_eglibc_fpu_setting(bb, d):
+    if bb.data.getVar('TARGET_FPU', d, 1) in [ 'soft' ]:
+        return "--without-fp"
+    return ""
+
+EXTRA_OECONF += "${@get_eglibc_fpu_setting(bb, d)}"
+
+OVERRIDES_append = ":${TARGET_ARCH}-${TARGET_OS}"
+
+do_install() {
+	oe_runmake install_root=${D} install
+	for r in ${rpcsvc}; do
+		h=`echo $r|sed -e's,\.x$,.h,'`
+		install -m 0644 ${S}/sunrpc/rpcsvc/$h ${D}/${includedir}/rpcsvc/
+	done
+	install -m 0644 ${WORKDIR}/etc/ld.so.conf ${D}/${sysconfdir}/
+	install -d ${D}${libdir}/locale
+	make -f ${WORKDIR}/generate-supported.mk IN="${S}/localedata/SUPPORTED" OUT="${WORKDIR}/SUPPORTED"
+	# get rid of some broken files...
+	for i in ${GLIBC_BROKEN_LOCALES}; do
+		grep -v $i ${WORKDIR}/SUPPORTED > ${WORKDIR}/SUPPORTED.tmp
+		mv ${WORKDIR}/SUPPORTED.tmp ${WORKDIR}/SUPPORTED
+	done
+	rm -f ${D}/etc/rpc
+        rm -f ${D}${includedir}/scsi/sg.h
+        rm -f ${D}${includedir}/scsi/scsi_ioctl.h
+        rm -f ${D}${includedir}/scsi/scsi.h
+}
+
+TMP_LOCALE="/tmp/locale${libdir}/locale"
+
+locale_base_postinst() {
+#!/bin/sh
+
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+rm -rf ${TMP_LOCALE}
+mkdir -p ${TMP_LOCALE}
+if [ -f ${libdir}/locale/locale-archive ]; then
+        cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
+fi
+localedef --inputfile=${datadir}/i18n/locales/%s --charmap=%s --prefix=/tmp/locale %s
+mkdir -p ${libdir}/locale/
+mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
+rm -rf ${TMP_LOCALE}
+}
+
+locale_base_postrm() {
+#!/bin/sh
+
+rm -rf ${TMP_LOCALE}
+mkdir -p ${TMP_LOCALE}
+if [ -f ${libdir}/locale/locale-archive ]; then
+	cp ${libdir}/locale/locale-archive ${TMP_LOCALE}/
+fi
+localedef --delete-from-archive --inputfile=${datadir}/locales/%s --charmap=%s --prefix=/tmp/locale %s
+mv ${TMP_LOCALE}/locale-archive ${libdir}/locale/
+rm -rf ${TMP_LOCALE}
+}
+
+python __anonymous () {
+    enabled = bb.data.getVar("ENABLE_BINARY_LOCALE_GENERATION", d, 1)
+
+    if enabled and int(enabled):
+        import re
+
+        target_arch = bb.data.getVar("TARGET_ARCH", d, 1)
+        binary_arches = bb.data.getVar("BINARY_LOCALE_ARCHES", d, 1) or ""
+
+        for regexp in binary_arches.split(" "):
+            r = re.compile(regexp)
+
+            if r.match(target_arch):
+                depends = bb.data.getVar("DEPENDS", d, 1)
+                depends = "%s qemu-native" % depends
+                bb.data.setVar("DEPENDS", depends, d)
+                bb.data.setVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", "1", d)
+                break
+}
+
+do_prep_locale_tree() {
+	treedir=${WORKDIR}/locale-tree
+	rm -rf $treedir
+	mkdir -p $treedir/bin $treedir/lib $treedir/${datadir} $treedir/${libdir}/locale
+	cp -pPR ${D}${datadir}/i18n $treedir/${datadir}/i18n
+	# unzip to avoid parsing errors
+	for i in $treedir/${datadir}/i18n/charmaps/*gz; do 
+		gunzip $i
+	done
+	ls ${D}/lib/* | xargs -iBLAH cp -pPR BLAH $treedir/lib
+	if [ -f ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.* ]; then
+		cp -pPR ${CROSS_DIR}/${TARGET_SYS}/lib/libgcc_s.* $treedir/lib
+	fi
+	install -m 0755 ${D}${bindir}/localedef $treedir/bin
+}
+
+do_collect_bins_from_locale_tree() {
+	treedir=${WORKDIR}/locale-tree
+
+	mkdir -p ${D}${libdir}
+	cp -pPR $treedir/${libdir}/locale ${D}${libdir}
+}
+
+python package_do_split_gconvs () {
+	import os, re
+	if (bb.data.getVar('PACKAGE_NO_GCONV', d, 1) == '1'):
+		bb.note("package requested not splitting gconvs")
+		return
+
+	if not bb.data.getVar('PACKAGES', d, 1):
+		return
+
+	libdir = bb.data.getVar('libdir', d, 1)
+	if not libdir:
+		bb.error("libdir not defined")
+		return
+	datadir = bb.data.getVar('datadir', d, 1)
+	if not datadir:
+		bb.error("datadir not defined")
+		return
+
+	gconv_libdir = base_path_join(libdir, "gconv")
+	charmap_dir = base_path_join(datadir, "i18n", "charmaps")
+	locales_dir = base_path_join(datadir, "i18n", "locales")
+	binary_locales_dir = base_path_join(libdir, "locale")
+
+	do_split_packages(d, gconv_libdir, file_regex='^(.*)\.so$', output_pattern='eglibc-gconv-%s', description='gconv module for character set %s', extra_depends='eglibc-gconv')
+
+	do_split_packages(d, charmap_dir, file_regex='^(.*)\.gz$', output_pattern='eglibc-charmap-%s', description='character map for %s encoding', extra_depends='')
+
+	def calc_locale_deps(fn, pkg, file_regex, output_pattern, group):
+		deps = []
+		f = open(fn, "r")
+		c_re = re.compile('^copy "(.*)"')
+		i_re = re.compile('^include "(\w+)".*')
+		for l in f.readlines():
+			m = c_re.match(l) or i_re.match(l)
+			if m:
+				dp = legitimize_package_name('eglibc-localedata-%s' % m.group(1))
+				if not dp in deps:
+					deps.append(dp)
+		f.close()
+		if deps != []:
+			bb.data.setVar('RDEPENDS_%s' % pkg, " ".join(deps), d)
+		bb.data.setVar('RPROVIDES_%s' % pkg, 'glibc-localedata-%s' % group, d)
+
+	do_split_packages(d, locales_dir, file_regex='(.*)', output_pattern='eglibc-localedata-%s', description='locale definition for %s', hook=calc_locale_deps, extra_depends='')
+	bb.data.setVar('PACKAGES', bb.data.getVar('PACKAGES', d) + ' eglibc-gconv', d)
+
+	supported = bb.data.getVar('GLIBC_GENERATE_LOCALES', d, 1)
+	if not supported or supported == "all":
+	    f = open(base_path_join(bb.data.getVar('WORKDIR', d, 1), "SUPPORTED"), "r")
+	    supported = f.readlines()
+	    f.close()
+	else:
+	    supported = supported.split()
+	    supported = map(lambda s:s.replace(".", " ") + "\n", supported)
+
+	dot_re = re.compile("(.*)\.(.*)")
+
+	# Collate the locales by base and encoding
+	encodings = {}
+	for l in supported:
+		l = l[:-1]
+		(locale, charset) = l.split(" ")
+		m = dot_re.match(locale)
+		if m:
+			locale = m.group(1)
+		if not encodings.has_key(locale):
+			encodings[locale] = []
+		encodings[locale].append(charset)
+
+	def output_locale_source(name, locale, encoding):
+		pkgname = 'locale-base-' + legitimize_package_name(name)
+
+		bb.data.setVar('RDEPENDS_%s' % pkgname, 'localedef eglibc-localedata-%s eglibc-charmap-%s' % (legitimize_package_name(locale), legitimize_package_name(encoding)), d)
+		rprovides = 'virtual-locale-%s' % legitimize_package_name(name)
+		m = re.match("(.*)_(.*)", name)
+		if m:
+			rprovides += ' virtual-locale-%s' % m.group(1)
+		bb.data.setVar('RPROVIDES_%s' % pkgname, rprovides, d)
+		bb.data.setVar('PACKAGES', '%s %s' % (pkgname, bb.data.getVar('PACKAGES', d, 1)), d)
+		bb.data.setVar('ALLOW_EMPTY_%s' % pkgname, '1', d)
+		bb.data.setVar('pkg_postinst_%s' % pkgname, bb.data.getVar('locale_base_postinst', d, 1) % (locale, encoding, locale), d)
+		bb.data.setVar('pkg_postrm_%s' % pkgname, bb.data.getVar('locale_base_postrm', d, 1) % (locale, encoding, locale), d)
+
+	def output_locale_binary(name, locale, encoding):
+		target_arch = bb.data.getVar("TARGET_ARCH", d, 1)
+		qemu = "qemu-%s -r 2.6.16" % target_arch
+		pkgname = 'locale-base-' + legitimize_package_name(name)
+		m = re.match("(.*)\.(.*)", name)
+		if m:
+			eglibc_name = "%s.%s" % (m.group(1), m.group(2).lower().replace("-",""))
+		else:
+			eglibc_name = name
+		bb.data.setVar('RDEPENDS_%s' % pkgname, legitimize_package_name('eglibc-binary-localedata-%s' % eglibc_name), d)
+		bb.data.setVar('RPROVIDES_%s' % pkgname, 'glibc-binary-localedata-%s' % eglibc_name, d)
+		rprovides = 'virtual-locale-%s' % legitimize_package_name(name)
+		m = re.match("(.*)_(.*)", name)
+		if m:
+			rprovides += ' virtual-locale-%s' % m.group(1)
+		bb.data.setVar('RPROVIDES_%s' % pkgname, rprovides, d)
+		bb.data.setVar('ALLOW_EMPTY_%s' % pkgname, '1', d)
+		bb.data.setVar('PACKAGES', '%s %s' % (pkgname, bb.data.getVar('PACKAGES', d, 1)), d)
+
+		treedir = base_path_join(bb.data.getVar("WORKDIR", d, 1), "locale-tree")
+		path = bb.data.getVar("PATH", d, 1)
+		i18npath = base_path_join(treedir, datadir, "i18n")
+
+		localedef_opts = "--force --old-style --no-archive --prefix=%s --inputfile=%s/i18n/locales/%s --charmap=%s %s" % (treedir, datadir, locale, encoding, name)
+		cmd = "PATH=\"%s\" I18NPATH=\"%s\" %s -L %s %s/bin/localedef %s" % (path, i18npath, qemu, treedir, treedir, localedef_opts)
+		bb.note("generating locale %s (%s)" % (locale, encoding))
+		if os.system(cmd):
+			raise bb.build.FuncFailed("localedef returned an error (command was %s)." % cmd)
+
+	def output_locale(name, locale, encoding):
+		use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
+		if use_bin:
+			output_locale_binary(name, locale, encoding)
+		else:
+			output_locale_source(name, locale, encoding)
+
+	use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
+	if use_bin:
+		bb.note("preparing tree for binary locale generation")
+		bb.build.exec_func("do_prep_locale_tree", d)
+
+	# Reshuffle names so that UTF-8 is preferred over other encodings
+	non_utf8 = []
+	for l in encodings.keys():
+		if len(encodings[l]) == 1:
+			output_locale(l, l, encodings[l][0])
+			if encodings[l][0] != "UTF-8":
+				non_utf8.append(l)
+		else:
+			if "UTF-8" in encodings[l]:
+				output_locale(l, l, "UTF-8")
+				encodings[l].remove("UTF-8")
+			else:
+				non_utf8.append(l)
+			for e in encodings[l]:
+				output_locale('%s.%s' % (l, e), l, e)
+
+	if non_utf8 != []:
+		bb.note("the following locales are supported only in legacy encodings:")
+		bb.note("  " + " ".join(non_utf8))
+
+	use_bin = bb.data.getVar("GLIBC_INTERNAL_USE_BINARY_LOCALE", d, 1)
+	if use_bin:
+		bb.note("collecting binary locales from locale tree")
+		bb.build.exec_func("do_collect_bins_from_locale_tree", d)
+		do_split_packages(d, binary_locales_dir, file_regex='(.*)', output_pattern='eglibc-binary-localedata-%s', description='binary locale definition for %s', extra_depends='', allow_dirs=True)
+	else:
+		bb.note("generation of binary locales disabled. this may break i18n!")
+
+}
+
+# We want to do this indirection so that we can safely 'return'
+# from the called function even though we're prepending
+python populate_packages_prepend () {
+	if bb.data.getVar('DEBIAN_NAMES', d, 1):
+		bb.data.setVar('PKG_eglibc', 'libc6', d)
+		bb.data.setVar('PKG_eglibc-dev', 'libc6-dev', d)
+	bb.build.exec_func('package_do_split_gconvs', d)
+}
diff --git a/packages/eglibc/eglibc-stage.inc b/packages/eglibc/eglibc-stage.inc
new file mode 100644
index 0000000000..d4ddecfa4d
--- /dev/null
+++ b/packages/eglibc/eglibc-stage.inc
@@ -0,0 +1,21 @@
+do_stage() {
+	rm -f ${STAGING_DIR_HOST}${layout_base_libdir}/libc.so.6
+	oe_runmake 'install_root=${STAGING_DIR_HOST}' \
+		   'includedir=${layout_includedir}' 'libdir=${layout_libdir}' 'slibdir=${layout_base_libdir}' \
+		   '${STAGING_DIR_HOST}${layout_base_libdir}/libc.so.6' \
+		   install-headers install-lib install
+
+	install -d ${STAGING_INCDIR}/gnu \
+		   ${STAGING_INCDIR}/bits \
+		   ${STAGING_INCDIR}/rpcsvc
+	install -m 0644 ${S}/include/gnu/stubs.h ${STAGING_INCDIR}/gnu/
+	install -m 0644 ${B}/bits/stdio_lim.h ${STAGING_INCDIR}/bits/
+	install -m 0644 misc/syscall-list.h ${STAGING_INCDIR}/bits/syscall.h
+	for r in ${rpcsvc}; do
+		h=`echo $r|sed -e's,\.x$,.h,'`
+		install -m 0644 ${S}/sunrpc/rpcsvc/$h ${STAGING_INCDIR}/rpcsvc/
+	done
+	for i in libc.a libc_pic.a libc_nonshared.a; do
+		install -m 0644 ${B}/$i ${STAGING_DIR_HOST}/${layout_base_libdir}/ || die "failed to install $i"
+	done
+}
diff --git a/packages/eglibc/eglibc-svn/.mtn2git_empty b/packages/eglibc/eglibc-svn/.mtn2git_empty
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/eglibc/eglibc-svn/.mtn2git_empty
diff --git a/packages/eglibc/eglibc-svn/eglibc-svn-arm-lowlevellock-include-tls.patch b/packages/eglibc/eglibc-svn/eglibc-svn-arm-lowlevellock-include-tls.patch
new file mode 100644
index 0000000000..99c3fef802
--- /dev/null
+++ b/packages/eglibc/eglibc-svn/eglibc-svn-arm-lowlevellock-include-tls.patch
@@ -0,0 +1,19 @@
+In file included from ../nptl/sysdeps/unix/sysv/linux/libc-lowlevellock.c:21:
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c: In function '__lll_lock_wait_private':
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c:34: warning: implicit declaration of function 'THREAD_GETMEM'
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c:34: error: 'THREAD_SELF' undeclared (first use in this function)
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c:34: error: (Each undeclared identifier is reported only once
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c:34: error: for each function it appears in.)
+../nptl/sysdeps/unix/sysv/linux/lowlevellock.c:34: error: 'header' undeclared (first use in this function)
+make[4]: *** [/var/tmp/portage/sys-libs/glibc-2.7-r1/work/build-default-armv4l-unknown-linux-gnu-nptl/nptl/rtld-libc-lowlevellock.os] Error 1
+
+--- libc/ports/sysdeps/unix/sysv/linux/arm/nptl/lowlevellock.h.orig
++++ libc/ports/sysdeps/unix/sysv/linux/arm/nptl/lowlevellock.h
+@@ -25,6 +25,7 @@
+ #include <atomic.h>
+ #include <sysdep.h>
+ #include <kernel-features.h>
++#include <tls.h>
+ 
+ #define FUTEX_WAIT		0
+ #define FUTEX_WAKE		1
diff --git a/packages/eglibc/eglibc.inc b/packages/eglibc/eglibc.inc
new file mode 100644
index 0000000000..e1559e46e4
--- /dev/null
+++ b/packages/eglibc/eglibc.inc
@@ -0,0 +1,22 @@
+DESCRIPTION = "Embedded GNU C Library"
+HOMEPAGE = "http://www.eglibc.org/home"
+SECTION = "libs"
+PRIORITY = "required"
+LICENSE = "LGPL"
+# nptl needs unwind support in gcc, which can't be built without glibc.
+DEPENDS = "${@['virtual/${TARGET_PREFIX}gcc-initial', 'virtual/${TARGET_PREFIX}gcc']['nptl' in '${GLIBC_ADDONS}']} linux-libc-headers"
+#this leads to circular deps, so lets not add it yet
+#RDEPENDS_ldd += " bash"
+# nptl needs libgcc but dlopens it, so our shlibs code doesn't detect this
+RDEPENDS += "${@['','libgcc']['nptl' in '${GLIBC_ADDONS}']}"
+PROVIDES = "virtual/libc ${@['virtual/${TARGET_PREFIX}libc-for-gcc', '']['nptl' in '${GLIBC_ADDONS}']}"
+PROVIDES += "virtual/libintl virtual/libiconv"
+
+inherit autotools
+
+LEAD_SONAME = "libc.so"
+
+GLIBC_EXTRA_OECONF ?= ""
+INHIBIT_DEFAULT_DEPS = "1"
+
+PACKAGES = "glibc catchsegv sln nscd ldd localedef glibc-utils glibc-dev glibc-doc glibc-locale libsegfault glibc-extra-nss glibc-thread-db glibc-pcprofile"
diff --git a/packages/eglibc/eglibc_svn.bb b/packages/eglibc/eglibc_svn.bb
new file mode 100644
index 0000000000..e7a4a1ba75
--- /dev/null
+++ b/packages/eglibc/eglibc_svn.bb
@@ -0,0 +1,97 @@
+require eglibc.inc
+
+# DEFAULT_PREFERENCE = "-1"
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/eglibc-svn"
+PV = "2.8+svnr${SRCREV}"
+PR = "r6"
+SRC_URI = "svn://svn.eglibc.org;module=trunk \
+           file://eglibc-svn-arm-lowlevellock-include-tls.patch;patch=1 \
+           file://etc/ld.so.conf \
+           file://generate-supported.mk"
+S = "${WORKDIR}/trunk/libc"
+B = "${WORKDIR}/build-${TARGET_SYS}"
+
+PACKAGES_DYNAMIC = "libc6*"
+RPROVIDES_${PN}-dev = "libc6-dev"
+PROVIDES_${PN}-dbg = "glibc-dbg"
+
+# the -isystem in bitbake.conf screws up glibc do_stage
+BUILD_CPPFLAGS = "-I${STAGING_INCDIR_NATIVE}"
+TARGET_CPPFLAGS = "-I${STAGING_DIR_TARGET}${layout_includedir}"
+
+GLIBC_ADDONS ?= "ports,nptl,libidn"
+
+GLIBC_BROKEN_LOCALES = " _ER _ET so_ET yn_ER sid_ET tr_TR mn_MN gez_ET gez_ER bn_BD te_IN"
+
+#
+# For now, we will skip building of a gcc package if it is a uclibc one
+# and our build is not a uclibc one, and we skip a glibc one if our build
+# is a uclibc build.
+#
+# See the note in gcc/gcc_3.4.0.oe
+#
+
+python __anonymous () {
+    import bb, re
+    uc_os = (re.match('.*uclibc$', bb.data.getVar('TARGET_OS', d, 1)) != None)
+    if uc_os:
+        raise bb.parse.SkipPackage("incompatible with target %s" %
+                                   bb.data.getVar('TARGET_OS', d, 1))
+}
+
+           
+EXTRA_OECONF = "--enable-kernel=${OLDEST_KERNEL} \
+                --without-cvs --disable-profile --disable-debug --without-gd \
+                --enable-clocale=gnu \
+                --enable-add-ons=${GLIBC_ADDONS} \
+                --with-headers=${STAGING_INCDIR} \
+                --without-selinux \
+                ${GLIBC_EXTRA_OECONF}"
+
+EXTRA_OECONF += "${@get_eglibc_fpu_setting(bb, d)}"
+
+do_unpack_append() {
+	bb.build.exec_func('do_move_ports', d)
+}
+
+do_move_ports() {
+        if test -d ${WORKDIR}/trunk/ports ; then
+	    rm -rf ${S}/ports
+	    mv ${WORKDIR}/trunk/ports ${S}/
+	fi    
+}
+
+do_configure () {
+# override this function to avoid the autoconf/automake/aclocal/autoheader
+# calls for now
+# don't pass CPPFLAGS into configure, since it upsets the kernel-headers
+# version check and doesn't really help with anything
+        if [ -z "`which rpcgen`" ]; then
+                echo "rpcgen not found.  Install glibc-devel."
+                exit 1
+        fi
+        (cd ${S} && gnu-configize) || die "failure in running gnu-configize"
+        find ${S} -name "configure" | xargs touch
+        CPPFLAGS="" oe_runconf
+}
+
+rpcsvc = "bootparam_prot.x nlm_prot.x rstat.x \
+	  yppasswd.x klm_prot.x rex.x sm_inter.x mount.x \
+	  rusers.x spray.x nfs_prot.x rquota.x key_prot.x"
+
+do_compile () {
+	# -Wl,-rpath-link <staging>/lib in LDFLAGS can cause breakage if another glibc is in staging
+	unset LDFLAGS
+	base_do_compile
+	(
+		cd ${S}/sunrpc/rpcsvc
+		for r in ${rpcsvc}; do
+			h=`echo $r|sed -e's,\.x$,.h,'`
+			rpcgen -h $r -o $h || oewarn "unable to generate header for $r"
+		done
+	)
+}
+
+require eglibc-stage.inc
+
+require eglibc-package.bbclass
diff --git a/packages/eglibc/files/.mtn2git_empty b/packages/eglibc/files/.mtn2git_empty
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/eglibc/files/.mtn2git_empty
diff --git a/packages/eglibc/files/etc/.mtn2git_empty b/packages/eglibc/files/etc/.mtn2git_empty
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/eglibc/files/etc/.mtn2git_empty
diff --git a/packages/eglibc/files/etc/ld.so.conf b/packages/eglibc/files/etc/ld.so.conf
new file mode 100644
index 0000000000..dfa65edb85
--- /dev/null
+++ b/packages/eglibc/files/etc/ld.so.conf
@@ -0,0 +1,2 @@
+/usr/local/lib
+/usr/X11R6/lib
diff --git a/packages/eglibc/files/generate-supported.mk b/packages/eglibc/files/generate-supported.mk
new file mode 100644
index 0000000000..d2a28c2dc6
--- /dev/null
+++ b/packages/eglibc/files/generate-supported.mk
@@ -0,0 +1,11 @@
+#!/usr/bin/make
+
+include $(IN)
+
+all:
+	rm -f $(OUT)
+	touch $(OUT)
+	for locale in $(SUPPORTED-LOCALES); do \
+		[ $$locale = true ] && continue; \
+		echo $$locale | sed 's,/, ,' >> $(OUT); \
+	done