add tentative patch for busybox rmmod problem with 2.4 kernel

BKrev: 41ba272cewmwTwy0ah_MnncdxxTCNg

2 files changed, 77 insertions, 0 deletions

diff --git a/packages/busybox/busybox-1.00/rmmod.patch b/packages/busybox/busybox-1.00/rmmod.patch
new file mode 100644
index 0000000000..e69de29bb2
--- /dev/null
+++ b/packages/busybox/busybox-1.00/rmmod.patch
diff --git a/packages/busybox/busybox_1.00.bb b/packages/busybox/busybox_1.00.bb
index e69de29bb2..6868bb4f45 100644
--- a/packages/busybox/busybox_1.00.bb
+++ b/packages/busybox/busybox_1.00.bb
@@ -0,0 +1,77 @@
+DESCRIPTION = "BusyBox version ${PV}. \
+BusyBox combines tiny versions of many common UNIX utilities into a single \
+small executable. It provides minimalist replacements for most of the \
+utilities you usually find in GNU fileutils, shellutils, etc. The utilities \
+in BusyBox generally have fewer options than their full-featured GNU \
+cousins; however, the options that are included provide the expected \
+functionality and behave very much like their GNU counterparts. BusyBox \
+provides a fairly complete POSIX environment for any small or embedded \
+system."
+HOMEPAGE = "http://www.busybox.net"
+LICENSE = "GPL"
+SECTION = "base"
+PRIORITY = "required"
+PR = "r11"
+
+SRC_URI = "http://www.busybox.net/downloads/busybox-${PV}.tar.gz \
+           file://add-getkey-applet.patch;patch=1 \
+	   file://udhcpscript.patch;patch=1 \
+	   file://dhcpretrytime.patch;patch=1 \
+	   file://hdparm_M.patch;patch=1 \
+	   file://udhcppidfile.patch;patch=1 \
+	   file://udhcppidfile-breakage.patch;patch=1 \
+	   file://readlink.patch;patch=1 \
+	   file://iproute-flush-cache.patch;patch=1;pnum=0 \
+	   file://rmmod.patch;patch=1 \
+           file://defconfig \
+           file://busybox-cron \
+	   file://busybox-httpd \
+	   file://busybox-udhcpd \
+	   file://syslog \
+           file://hwclock.sh \
+	   file://default.script"
+	   
+S = "${WORKDIR}/busybox-${PV}"
+
+export EXTRA_CFLAGS = "${CFLAGS}"
+EXTRA_OEMAKE_append = " CROSS=${HOST_PREFIX}"
+FILES_${PN} += " ${datadir}/udhcpc"
+
+inherit cml1 update-rc.d
+
+INITSCRIPT_NAME = "syslog"
+INITSCRIPT_PARAMS = "defaults"
+
+do_configure () {
+	install -m 0644 ${WORKDIR}/defconfig ${S}/.config
+	cml1_do_configure
+}
+
+do_compile () {
+	unset CFLAGS
+	base_do_compile
+}
+
+do_install () {
+	install -d ${D}/etc/init.d
+	oe_runmake 'PREFIX=${D}' install
+	install -m 0755 ${WORKDIR}/syslog ${D}/etc/init.d/
+	if grep "CONFIG_CROND=y" ${WORKDIR}/defconfig; then 
+		install -m 0755 ${WORKDIR}/busybox-cron ${D}/etc/init.d/
+	fi
+	if grep "CONFIG_HTTPD=y" ${WORKDIR}/defconfig; then 
+		install -m 0755 ${WORKDIR}/busybox-httpd ${D}/etc/init.d/
+	fi
+	if grep "CONFIG_UDHCPD=y" ${WORKDIR}/defconfig; then 
+		install -m 0755 ${WORKDIR}/busybox-udhcpd ${D}/etc/init.d/
+	fi
+	if grep "CONFIG_HWCLOCK=y" ${WORKDIR}/defconfig; then 
+		install -m 0755 ${WORKDIR}/hwclock.sh ${D}/etc/init.d/hwclock.sh
+	fi
+	if grep "CONFIG_UDHCPC=y" ${WORKDIR}/defconfig; then 
+		install -d ${D}/etc/udhcpc.d
+		install -d ${D}${datadir}/udhcpc
+		install -m 0755 ${S}/examples/udhcp/simple.script ${D}/etc/udhcpc.d/50default
+		install -m 0755 ${WORKDIR}/default.script ${D}${datadir}/udhcpc/default.script
+	fi
+}