add gconf to gst-plugins depends

BKrev: 41422f185Cst-27o1F5q7SkKqypezQ

2 files changed, 54 insertions, 1 deletions

diff --git a/gstreamer/gst-plugins-small_0.8.1.oe b/gstreamer/gst-plugins-small_0.8.1.oe
index 7c559b8e2e..a1ad01a35f 100644
--- a/gstreamer/gst-plugins-small_0.8.1.oe
+++ b/gstreamer/gst-plugins-small_0.8.1.oe
@@ -4,7 +4,7 @@ PRIORITY = "optional"
 MAINTAINER = "Phil Blundell <pb@handhelds.org>"
 PROVIDES = "gst-plugins"
 
-DEPENDS = "gstreamer libmad libogg tremor libvorbis libid3tag esound-gpe"
+DEPENDS = "gstreamer libmad libogg tremor libvorbis libid3tag esound-gpe gconf"
 
 SRC_URI = "http://gstreamer.freedesktop.org/src/gst-plugins/gst-plugins-${PV}.tar.bz2 \
 	   file://ivorbis.patch;patch=1"
diff --git a/gstreamer/gst-plugins_0.8.3.oe b/gstreamer/gst-plugins_0.8.3.oe
index e69de29bb2..8102ddb4de 100644
--- a/gstreamer/gst-plugins_0.8.3.oe
+++ b/gstreamer/gst-plugins_0.8.3.oe
@@ -0,0 +1,53 @@
+DESCRIPTION = "Plugins for GStreamer"
+SECTION = "base"
+PRIORITY = "optional"
+MAINTAINER = "Phil Blundell <pb@handhelds.org>"
+PR = "r0"
+
+DEPENDS = "gstreamer zlib libmikmod libmad libogg tremor libvorbis libid3tag gnome-vfs esound-gpe gconf"
+
+SRC_URI = "http://gstreamer.freedesktop.org/src/gst-plugins/gst-plugins-${PV}.tar.bz2 \
+	   file://ivorbis.patch;patch=1 \
+	   file://try-esdsink.patch;patch=1"
+
+EXTRA_OECONF = "--disable-docs-build --disable-dependency-tracking --disable-aalib --disable-arts \
+                --disable-artsc --disable-libfame --disable-sdl --disable-shout2"
+
+inherit autotools pkgconfig gconf
+
+acpaths = "-I ${S}/common/m4 -I ${S}/m4"
+
+LIBV = "0.8"
+
+plugin_postinst() {
+	if [ x"$D" = "x" ]; then
+		gst-register --gst-registry=/var/cache/gstreamer-0.8/registry.xml
+	fi
+}
+
+python populate_packages_prepend () {
+	gst_libdir = oe.data.expand('${libdir}/gstreamer-${LIBV}', d)
+	postinst = oe.data.getVar('plugin_postinst', d, 1)
+
+	do_split_packages(d, gst_libdir, '^libgst(.*)\.so$', 'gst-plugin-%s', 'GStreamer plugin for %s', postinst=postinst)
+	do_split_packages(d, gst_libdir, '^libgst(.*)\.l?a$', 'gst-plugin-%s-dev', 'GStreamer plugin for %s (development files)')
+}
+
+do_stage() {
+	autotools_stage_includes
+	while read a b; do
+		oe_libinstall -C gst-libs/gst/$a -so libgst$b ${STAGING_LIBDIR}
+	done <<EOF
+. interfaces-0.8
+audio audio
+audio audiofilter
+gconf gconf-0.8
+idct idct
+media-info media-info-0.8
+play play-0.8
+resample resample
+riff riff
+video video
+xwindowlistener xwindowlistener
+EOF
+}