fix for tool overrides in gcc 3.4

BKrev: 408ef618ODA-Gd6eX41K1qX4z0Zc-A

1 files changed, 86 insertions, 0 deletions

diff --git a/gcc/gcc-uclibc-cross_3.4.0.oe b/gcc/gcc-uclibc-cross_3.4.0.oe
index e69de29bb2..e8e6f47b75 100644
--- a/gcc/gcc-uclibc-cross_3.4.0.oe
+++ b/gcc/gcc-uclibc-cross_3.4.0.oe
@@ -0,0 +1,86 @@
+inherit cross
+include gcc-uclibc_${PV}.oe
+
+DEPENDS = "virtual/${TARGET_PREFIX}binutils uclibc patcher-native"
+PROVIDES = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
+
+# Files for these are defined in the main gcc.oe
+PACKAGES = "libgcc libstdc++ libg2c"
+
+EXTRA_OECONF = "--with-local-prefix=${CROSS_DIR}/local \
+		--with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++ \
+		--enable-target-optspace \
+		--disable-nls \
+		--with-gnu-ld \
+		--disable-__cxa_atexit \
+		--enable-languages=c,c++,f77 \
+		--enable-shared \
+		--enable-threads \
+		--enable-multilib \
+		--program-prefix=${TARGET_PREFIX}"
+
+export CPPFLAGS = ""
+export CXXFLAGS = ""
+export CFLAGS = ""
+export LDFLAGS = ""
+
+do_configure () {
+	oe_runconf
+}
+
+do_compile_prepend () {
+	export CC="${BUILD_CC}"
+	export AR_FOR_TARGET="${TARGET_SYS}-ar"
+	export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
+	export LD_FOR_TARGET="${TARGET_SYS}-ld"
+	export NM_FOR_TARGET="${TARGET_SYS}-nm"
+	export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
+}
+
+do_stage_append () {
+	for d in info man share/doc share/locale ; do
+		rm -rf ${CROSS_DIR}/$d
+	done
+
+	# These aren't useful on the cross toolchain
+	rm -f ${CROSS_DIR}/bin/*gcov
+	rm -f ${CROSS_DIR}/bin/*gccbug
+
+	# Fix a few include links so cross builds are happier
+	if [ ! -e ${STAGING_INCDIR}/c++ ]; then
+		mkdir -p ${STAGING_INCDIR}
+		ln -s ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
+			${STAGING_INCDIR}/
+	fi
+
+	# We use libiberty from binutils
+	rm -f ${CROSS_DIR}/lib/libiberty.a
+
+	# We probably don't need this
+	rmdir ${CROSS_DIR}/include || :
+
+	# We don't really need to keep this around
+	rm -rf ${CROSS_DIR}/share
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/lib
+	if [ -f ${D}/lib/libgcc_s.so.? ]; then
+		# Already in the right location
+		:
+	elif [ -f ${D}/${prefix}/lib/libgcc_s.so.? ]; then
+		mv -f ${D}/${prefix}/lib/libgcc_s.so.* ${D}/lib
+	else
+		mv -f ${D}/${prefix}/*/lib/libgcc_s.so.* ${D}/lib
+	fi
+
+	# Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
+	TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
+	mkdir -p ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libstdc++.so.* ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libg2c.so.* ${D}/${TGT_LIBDIR}
+}
+