Add centericq 4.11.0, which doesn't compile at the moment.

BKrev: 4113022epmw3-iofOHlmhB5uc63vGw

1 files changed, 111 insertions, 0 deletions

diff --git a/binutils/binutils_2.14.90.0.7.oe b/binutils/binutils_2.14.90.0.7.oe
new file mode 100644
index 0000000000..88ad697273
--- /dev/null
+++ b/binutils/binutils_2.14.90.0.7.oe
@@ -0,0 +1,111 @@
+inherit autotools
+
+DESCRIPTION = "A GNU collection of binary utilities"
+LICENSE = "GPL"
+MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
+
+PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
+
+FILES_${PN} = " \
+	${bindir}/${TARGET_PREFIX}* \
+	${libdir}/lib*-*.so"
+
+FILES_${PN}-dev = " \
+	${includedir} \
+	${libdir}/*.a \
+	${libdir}/*.la \
+	${libdir}/libbfd.so \
+	${libdir}/libopcodes.so"
+
+FILES_${PN}-symlinks = " \
+	${bindir}/addr2line \
+	${bindir}/ar \
+	${bindir}/as \
+	${bindir}/c++filt \
+	${bindir}/gprof \
+	${bindir}/ld \
+	${bindir}/nm \
+	${bindir}/objcopy \
+	${bindir}/objdump \
+	${bindir}/ranlib \
+	${bindir}/readelf \
+	${bindir}/size \
+	${bindir}/strings \
+	${bindir}/strip"
+
+SRC_URI = \
+    "http://ftp.kernel.org/pub/linux/devel/binutils/binutils-${PV}.tar.bz2 \
+     file://binutils-uclibc-001-debian.patch;patch=1 \
+     file://binutils-uclibc-100-conf.patch;patch=1 \
+     file://binutils-uclibc-200-build_modules.patch;patch=1 \
+     file://binutils-uclibc-210-cflags.patch;patch=1 \
+     file://binutils-006_better_file_error.patch;patch=1 \
+     file://binutils-100_cflags_for_build.patch;patch=1 \
+     file://plt32trunc.patch;patch=1"
+
+S = "${WORKDIR}/binutils-${PV}"
+B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
+
+EXTRA_OECONF = "--with-sysroot=${prefix} \
+		--disable-nls \
+		--program-prefix=${TARGET_PREFIX} \
+		--enable-shared"
+
+# This is necessary due to a bug in the binutils Makefiles
+EXTRA_OEMAKE = "configure-build-libiberty all"
+
+export AR = "${HOST_PREFIX}ar"
+export AS = "${HOST_PREFIX}as"
+export LD = "${HOST_PREFIX}ld"
+export NM = "${HOST_PREFIX}nm"
+export RANLIB = "${HOST_PREFIX}ranlib"
+export OBJCOPY = "${HOST_PREFIX}objcopy"
+export OBJDUMP = "${HOST_PREFIX}objdump"
+
+export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
+export AS_FOR_TARGET = "${TARGET_PREFIX}as"
+export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
+export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
+export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
+
+export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
+export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
+
+export CC_FOR_BUILD = "${BUILD_CC}"
+
+export CC = "${CCACHE} ${HOST_PREFIX}gcc"
+
+do_configure () {
+	(cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
+	oe_runconf
+}
+
+do_stage () {
+	oe_libinstall -so -a -C opcodes libopcodes ${STAGING_LIBDIR}/
+	oe_libinstall -a -C libiberty libiberty ${STAGING_LIBDIR}/
+	oe_libinstall -so -a -C bfd libbfd ${STAGING_LIBDIR}/
+	install -m 0644 ${S}/include/dis-asm.h ${STAGING_INCDIR}/
+	install -m 0644 ${S}/include/symcat.h ${STAGING_INCDIR}/
+	install -m 0644 ${S}/include/libiberty.h ${STAGING_INCDIR}/
+	install -m 0644 ${S}/include/ansidecl.h ${STAGING_INCDIR}/
+	install -m 0644 ${S}/include/bfdlink.h ${STAGING_INCDIR}/
+	install -m 0644 bfd/bfd.h ${STAGING_INCDIR}/
+}
+
+do_install () {
+	autotools_do_install
+
+	# We don't really need these, so we'll remove them...
+	rm -rf ${D}/${libdir}/ldscripts
+
+	# Install the libiberty header
+	install -m 644 ${S}/include/ansidecl.h ${D}/${includedir}
+	install -m 644 ${S}/include/libiberty.h ${D}/${includedir}
+
+	cd ${D}/${bindir}
+
+	# Symlinks for ease of running these on the native target
+	for p in ${TARGET_SYS}-* ; do
+		ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
+	done
+}