alsa: updated to 1.0.11

4 files changed, 124 insertions, 0 deletions

diff --git a/packages/alsa/alsa-lib_1.0.11.bb b/packages/alsa/alsa-lib_1.0.11.bb
new file mode 100644
index 0000000000..5075db6273
--- /dev/null
+++ b/packages/alsa/alsa-lib_1.0.11.bb
@@ -0,0 +1,32 @@
+DESCRIPTION = "Alsa sound library"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+PR = "r0"
+
+# configure.in sets -D__arm__ on the command line for any arm system
+# (not just those with the ARM instruction set), this should be removed,
+# (or replaced by a permitted #define).
+#FIXME: remove the following
+ARM_INSTRUCTION_SET = "arm"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/lib/alsa-lib-${PV}.tar.bz2"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-cards=pdaudiocf --with-oss=yes"
+
+do_stage () {
+	oe_libinstall -so -C src libasound ${STAGING_LIBDIR}/
+	install -d ${STAGING_INCDIR}/alsa/sound
+	install -m 0644 include/*.h ${STAGING_INCDIR}/alsa/
+	install -m 0644 include/sound/ainstr*.h ${STAGING_INCDIR}/alsa/sound/
+	install -d ${STAGING_DATADIR}/aclocal
+	install -m 0644 utils/alsa.m4 ${STAGING_DATADIR}/aclocal/
+}
+
+PACKAGES = "libasound alsa-server alsa-conf alsa-doc alsa-dev"
+FILES_libasound = "${libdir}/libasound.so*"
+FILES_alsa-server = "${bindir}"
+FILES_alsa-conf = "${datadir}"
+FILES_alsa-dev = "${libdir}/pkgconfig/ /usr/include/"
diff --git a/packages/alsa/alsa-oss_1.0.11.bb b/packages/alsa/alsa-oss_1.0.11.bb
new file mode 100644
index 0000000000..7d388e679a
--- /dev/null
+++ b/packages/alsa/alsa-oss_1.0.11.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "Alsa OSS Compatibility Package"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "libs/multimedia"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/oss-lib/alsa-oss-${PV}.tar.bz2"
+
+inherit autotools 
+
+do_configure_prepend () {
+	touch NEWS README AUTHORS ChangeLog
+}
+
+do_stage () {
+	oe_libinstall -C alsa -a -so libaoss ${STAGING_LIBDIR}
+	oe_libinstall -C alsa -a -so libalsatoss ${STAGING_LIBDIR}
+}
diff --git a/packages/alsa/alsa-tools_1.0.11.bb b/packages/alsa/alsa-tools_1.0.11.bb
new file mode 100644
index 0000000000..9512ae8036
--- /dev/null
+++ b/packages/alsa/alsa-tools_1.0.11.bb
@@ -0,0 +1,17 @@
+BROKEN = "1"
+
+DESCRIPTION = "Alsa Tools"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/tools/alsa-tools-${PV}.tar.bz2"
+
+inherit autotools
+
+# this bb file requires quite some work.
+# There is no top level makefile in tools
+# that is why install fails, but actually nothing is compiled
+# in order to fix this, the bb file needs heavy work 
+# (but the tools are not very useful for oe, so I'll leave it for now)
diff --git a/packages/alsa/alsa-utils_1.0.11.bb b/packages/alsa/alsa-utils_1.0.11.bb
new file mode 100644
index 0000000000..3c5b964c16
--- /dev/null
+++ b/packages/alsa/alsa-utils_1.0.11.bb
@@ -0,0 +1,56 @@
+DESCRIPTION = "ALSA Utilities"
+MAINTAINER = "Lorn Potter <lpotter@trolltech.com>"
+SECTION = "console/utils"
+LICENSE = "GPL"
+DEPENDS = "alsa-lib ncurses"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.alsa-project.org/pub/utils/alsa-utils-${PV}.tar.bz2"
+
+inherit autotools
+
+# This are all packages that we need to make. Also, the now empty alsa-utils
+# ipk depend on them.
+
+PACKAGES += "alsa-utils-alsamixer"
+PACKAGES += "alsa-utils-midi"
+PACKAGES += "alsa-utils-aplay"
+PACKAGES += "alsa-utils-amixer"
+PACKAGES += "alsa-utils-aconnect"
+PACKAGES += "alsa-utils-iecset"
+PACKAGES += "alsa-utils-speakertest"
+PACKAGES += "alsa-utils-aseqnet"
+PACKAGES += "alsa-utils-alsactl"
+
+
+# We omit alsaconf, because
+# a) this is a bash script
+# b) it creates config files for RedHat, Debian, Mandrake etc, but not
+#    for Familiar, OpenZaurus etc
+
+
+FILES_${PN} = ""
+FILES_alsa-utils-aplay       = "${bindir}/aplay ${bindir}/arecord"
+FILES_alsa-utils-amixer      = "${bindir}/amixer"
+FILES_alsa-utils-alsamixer   = "${bindir}/alsamixer"
+FILES_alsa-utils-speakertest = "${bindir}/speaker-test"
+FILES_alsa-utils-midi        = "${bindir}/aplaymidi ${bindir}/arecordmidi ${bindir}/amidi"
+FILES_alsa-utils-aconnect    = "${bindir}/aconnect"
+FILES_alsa-utils-aseqnet     = "${bindir}/aseqnet"
+FILES_alsa-utils-iecset      = "${bindir}/iecset"
+FILES_alsa-utils-alsactl     = "${sbindir}/alsactl"
+
+DESCRIPTION_alsa-utils-aplay        = "play (and record) sound files via ALSA"
+DESCRIPTION_alsa-utils-amixer       = "command-line based control for ALSA mixer and settings"
+DESCRIPTION_alsa-utils-alsamixer    = "ncurses based control for ALSA mixer and settings"
+#DESCRIPTION_alsa-utils-speaker-test= "??"
+DESCRIPTION_alsa-utils-midi         = "miscalleanous MIDI utilities for ALSA"
+DESCRIPTION_alsa-utils-aconnect     = "ALSA sequencer connection manager"
+DESCRIPTION_alsa-utils-aseqnet      = "network client/server on ALSA sequencer"
+DESCRIPTION_alsa-utils-alsactl      = "saves/restores ALSA-settings in /etc/asound.state"
+DESCRIPTION_alsa-utils-alsaconf     = "a bash script that creates ALSA configuration files"
+
+RDEPENDS_alsa-utils-aplay  += "alsa-conf"
+RDEPENDS_alsa-utils-amixer += "alsa-conf"
+
+ALLOW_EMPTY_alsa-utils = "1"