gnuradio : Add recipe to build GNU Radio from git.

3 files changed, 115 insertions, 1 deletions

diff --git a/conf/distro/include/sane-srcrevs.inc b/conf/distro/include/sane-srcrevs.inc
index 900f4b9e82..941d265287 100644
--- a/conf/distro/include/sane-srcrevs.inc
+++ b/conf/distro/include/sane-srcrevs.inc
@@ -63,7 +63,6 @@ SRCREV_pn-gcc-cross-intermediate ?= ${GCCREV}
 SRCREV_pn-gcc-cross-sdk ?= ${GCCREV}
 SRCREV_pn-gconf-dbus ?= "641"
 SRCREV_pn-gnet ?= "495"
-SRCREV_pn-gnuradio ?= "11418"
 SRCREV_pn-gpe-conf ?= "9900"
 SRCREV_pn-gpe-contacts ?= "9312"
 SRCREV_pn-gpe-gallery ?= "9376"
diff --git a/recipes/gnuradio/gnuradio.inc b/recipes/gnuradio/gnuradio.inc
new file mode 100644
index 0000000000..d1d0c12fea
--- /dev/null
+++ b/recipes/gnuradio/gnuradio.inc
@@ -0,0 +1,90 @@
+DESCRIPTION = "GNU Radio"
+SECTION =  "apps"
+PRIORITY = "optional"
+LICENSE = "GPLv3"
+DEPENDS = "virtual/libusb0 guile-native fftwf python virtual/libsdl alsa-lib jack boost cppunit sdcc-native swig-native python-numpy"
+INC_PR = "r7"
+
+inherit distutils-base autotools autotools_stage pkgconfig
+
+export BUILD_SYS
+export HOST_SYS=${MULTIMACH_TARGET_SYS}
+
+CXXFLAGS_powerpc += "-lstdc++"
+
+EXTRA_OECONF = " \
+  --program-prefix= \
+  --disable-gr-atsc \
+  --enable-gr-video-sdl \
+  --enable-gr-audio-alsa  \
+  --enable-gr-audio-jack \
+  --enable-gr-audio-oss \
+  --enable-mblock \
+  --disable-html-docs \
+  --with-pythondir=/usr/lib/${PYTHON_DIR}/site-packages \
+  PYTHON_CPPFLAGS=-I${STAGING_INCDIR}/${PYTHON_DIR} \
+"
+
+#export USB_CFLAGS="-I${STAGING_INCDIR}"
+#export USB_LIBS="-L${STAGING_LIBDIR}"
+
+do_configure_prepend() {
+	if [ -e ${WORKDIR}/acinclude.m4 ] ; then
+		cp ${WORKDIR}/acinclude.m4 ${S}
+	fi
+}
+
+do_configure_append() {
+	find ${S} -name Makefile | xargs sed -i s:'-I/usr/include':'-I${STAGING_INCDIR}':g
+	find ${S} -name Makefile | xargs sed -i s:' /usr/include':' ${STAGING_INCDIR}':g
+}
+
+do_stage() {
+	autotools_stage_all
+	sed -i s,-l:libusb-gnur.a,,g ${STAGING_LIBDIR}/libusrp.la
+}
+
+RDEPENDS_${PN} = "python-core python-audio python-threading python-codecs python-lang python-textutils \
+                  python-shell python-pickle python-compiler python-pkgutil python-pydoc python-mmap \
+                  python-netclient python-unittest python-difflib python-pprint python-numpy \
+"
+
+RDEPENDS_gnuradio-usrp = "python-core"
+
+PACKAGES =+ "\
+  libpmt libpmt-qa \
+  libmblock libmblock-qa \
+  libgr-audio-alsa libgr-audio-oss libgr-audio-jack\
+  libusrp libusrp-inband libusrp-inband-qa \
+  libgromnithread \
+  libgnuradio-core libgnuradio-core-qa \
+  gnuradio-usrp-dbg gnuradio-usrp gnuradio-examples \
+"
+
+FILES_gnuradio-examples = "${datadir}/gnuradio/examples"
+
+FILES_libpmt = "${libdir}/libpmt.so"
+FILES_libpmt-qa = "${libdir}/libpmt-qa.so"
+FILES_libmblock = "${libdir}/libmblock.so"
+FILES_libmblock-qa = "${libdir}/libmblock-qa.so"
+FILES_libgr-audio-alsa = "${libdir}/libgr_audio_alsa.so ${sysconfdir}/gnuradio/conf.d/gr-audio-alsa.conf"
+FILES_libgr-audio-oss = "${libdir}/libgr_audio_oss.so ${sysconfdir}/gnuradio/conf.d/gr-audio-oss.conf"
+FILES_libgr-audio-jack = "${libdir}/libgr_audio_jack.so ${sysconfdir}/gnuradio/conf.d/gr-audio-jack.conf"
+
+
+FILES_libusrp = "${libdir}/libusrp.so.*"
+FILES_libusrp-inband = "${libdir}/libusrp_inband.so.*"
+FILES_libusrp-inband-qa = "${libdir}/libusrp_inband-qa.so"
+FILES_libgnuradio-core = "${libdir}/libgnuradio-core.so.* ${sysconfdir}/gnuradio/conf.d/*core*"
+FILES_libgnuradio-core-qa = "${libdir}/libgnuradio-core-qa.so.*"
+FILES_libgromnithread = "${libdir}/libgromnithread.so*"
+
+FILES_${PN} += "${libdir}/python*/site-packages/gnuradio/*"
+FILES_${PN}-dbg += "${libdir}/python*/site-packages/gnuradio/.debug \
+                    ${libdir}/python*/site-packages/gnuradio/*/.debug \
+		   "
+
+FILES_gnuradio-usrp = "${libdir}/python*/site-packages/usrp/* \
+                       ${bindir}/usrp* \
+                       ${datadir}/usrp/*/*"
+FILES_gnuradio-usrp-dbg = "${libdir}/python*/site-packages/usrp/.debug"
diff --git a/recipes/gnuradio/gnuradio_git.bb b/recipes/gnuradio/gnuradio_git.bb
new file mode 100644
index 0000000000..37b21fdcb2
--- /dev/null
+++ b/recipes/gnuradio/gnuradio_git.bb
@@ -0,0 +1,25 @@
+require gnuradio.inc
+
+#DEFAULT_PREFERENCE = "-1"
+
+DEPENDS += " gsl "
+
+SRCREV = "0cd478fdc090123e09b7ee21c88e5657abab8ae0"
+#SRCREV = "0f4226088ba84e25139bf77957c80ca7a64cba11"
+PR = "${INC_PR}.1"
+PV = "3.2.1-${PR}+gitr${SRCREV}"
+
+EXTRA_OECONF += "--with-boost=${STAGING_DIR_TARGET}/usr CXXFLAGS=-DBOOST_SP_USE_PTHREADS --disable-usrp2 --disable-usrp2-firmware --with-fusb-tech=libusb1"
+
+SRC_URI = "git://gnuradio.org/git/gnuradio.git;protocol=http \
+     ${SOURCEFORGE_MIRROR}/libusb/libusb-0.1.12.tar.gz \
+"
+
+S="${WORKDIR}/git"
+
+do_compile_append() {
+        sed -i -e s:${STAGING_DIR_TARGET}::g \
+               -e s:/${TARGET_SYS}::g \
+                  gnuradio-core/gnuradio-core.pc
+}
+