psplash: make splashscreen selectable with update-alternatives

* putting 'psplash' in your images will get you the same splash you are using now
* putting 'psplash-<name>' in your images will make u-a install that splash over the one 'psplash' provides now
* This makes splash screen an image property instead of a distro property, so even less need for creating a derived distro

5 files changed, 94 insertions, 35 deletions

diff --git a/packages/psplash/psplash-angstrom_svn.bb b/packages/psplash/psplash-angstrom_svn.bb
new file mode 100644
index 0000000000..401afdfda9
--- /dev/null
+++ b/packages/psplash/psplash-angstrom_svn.bb
@@ -0,0 +1,19 @@
+require psplash.inc
+require psplash-ua.inc
+
+ALTERNATIVE_PRIORITY = "20"
+
+# You can create your own pslash-hand-img.h by doing
+# ./make-image-header.sh <file>.png HAND
+# and rename the resulting .h to pslash-hand-img.h (for the logo)
+# respectively psplash-bar-img.h (BAR) for the bar.
+# You might also want to patch the colors (see patch)
+
+SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=psplash;proto=http \
+          file://logo-math.patch;patch=1 \
+          file://psplash-hand-img.h \
+          file://psplash-bar-img.h \
+          file://psplash-default \
+          file://psplash-init"
+S = "${WORKDIR}/psplash"
+
diff --git a/packages/psplash/psplash-openmoko_svn.bb b/packages/psplash/psplash-openmoko_svn.bb
new file mode 100644
index 0000000000..4e7dbcce59
--- /dev/null
+++ b/packages/psplash/psplash-openmoko_svn.bb
@@ -0,0 +1,19 @@
+require psplash.inc
+require psplash-ua.inc
+
+ALTERNATIVE_PRIORITY = "30"
+
+# You can create your own pslash-hand-img.h by doing
+# ./make-image-header.sh <file>.png HAND
+# and rename the resulting .h to pslash-hand-img.h (for the logo)
+# respectively psplash-bar-img.h (BAR) for the bar.
+# You might also want to patch the colors (see patch)
+
+SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=psplash;proto=http \
+          file://psplash-hand-img.h \
+          file://psplash-bar-img.h \
+          file://psplash-default \
+          file://psplash-init"
+S = "${WORKDIR}/psplash"
+
+SRC_URI_append_openmoko = " file://configurability.patch;patch=1 "
diff --git a/packages/psplash/psplash-ua.inc b/packages/psplash/psplash-ua.inc
new file mode 100644
index 0000000000..70fe94738e
--- /dev/null
+++ b/packages/psplash/psplash-ua.inc
@@ -0,0 +1,11 @@
+inherit update-alternatives
+
+SRCREV = "${SRCREV_pn-psplash}"
+
+do_install_append() {
+	mv ${D}${bindir}/psplash ${D}${bindir}/psplash.${PN}
+}
+
+ALTERNATIVE_NAME = "psplash"
+ALTERNATIVE_LINK = "${bindir}/psplash"
+ALTERNATIVE_PATH = "${bindir}/psplash.${PN}"
diff --git a/packages/psplash/psplash.inc b/packages/psplash/psplash.inc
new file mode 100644
index 0000000000..d1df18ff45
--- /dev/null
+++ b/packages/psplash/psplash.inc
@@ -0,0 +1,40 @@
+DESCRIPTION = "Userspace framebuffer boot logo based on usplash."
+HOMEPAGE = "http://projects.o-hand.com/psplash"
+SECTION = "base"
+LICENSE = "GPL"
+RDEPENDS = "initscripts"
+
+PV = "0.0+svnr${SRCREV}"
+
+# You can create your own pslash-hand-img.h by doing
+# ./make-image-header.sh <file>.png HAND
+# and rename the resulting .h to pslash-hand-img.h (for the logo)
+# respectively psplash-bar-img.h (BAR) for the bar.
+# You might also want to patch the colors (see patch)
+
+inherit autotools pkgconfig update-rc.d
+
+do_configure_append() {
+	install -m 0644 ${WORKDIR}/psplash-hand-img.h ${S}/
+	install -m 0644 ${WORKDIR}/psplash-bar-img.h ${S}/
+
+	if [ -e "${WORKDIR}/psplash.h" ]; then
+		install -m 0644 ${WORKDIR}/psplash.h ${S}/
+	fi
+}
+
+do_install_prepend() {
+	install -d ${D}/mnt/.psplash/
+	install -d ${D}${sysconfdir}/default/
+	install -m 0644 ${WORKDIR}/psplash-default ${D}${sysconfdir}/default/psplash
+	install -d ${D}${sysconfdir}/init.d/
+	install -m 0755 ${WORKDIR}/psplash-init ${D}${sysconfdir}/init.d/psplash
+}
+
+INITSCRIPT_NAME = "psplash"
+INITSCRIPT_PARAMS = "start 01 S . stop 20 0 1 6 ."
+
+PACKAGES =+ "psplash-support"
+
+RDEPENDS_${PN} += "psplash-support"
+FILES_psplash-support += "/mnt/.psplash ${sysconfdir} ${bindir}/psplash-write"
diff --git a/packages/psplash/psplash_svn.bb b/packages/psplash/psplash_svn.bb
index 36c8b3960d..603f1e03e6 100644
--- a/packages/psplash/psplash_svn.bb
+++ b/packages/psplash/psplash_svn.bb
@@ -1,16 +1,9 @@
-DESCRIPTION = "Userspace framebuffer boot logo based on usplash."
-HOMEPAGE = "http://projects.o-hand.com/psplash"
-SECTION = "base"
-LICENSE = "GPL"
-PV = "0.0+svnr${SRCREV}"
-PR = "r14"
-RDEPENDS = "initscripts"
+require psplash.inc
+require psplash-ua.inc
+
+ALTERNATIVE_PRIORITY = "10"
 
-# You can create your own pslash-hand-img.h by doing
-# ./make-image-header.sh <file>.png HAND
-# and rename the resulting .h to pslash-hand-img.h (for the logo)
-# respectively psplash-bar-img.h (BAR) for the bar.
-# You might also want to patch the colors (see patch)
+PR = "r14"
 
 SRC_URI = "svn://svn.o-hand.com/repos/misc/trunk;module=psplash;proto=http \
           file://psplash-hand-img.h \
@@ -24,26 +17,3 @@ SRC_URI_append_angstrom = " file://logo-math.patch;patch=1 "
 SRC_URI_append_openmoko = " file://configurability.patch;patch=1 "
 SRC_URI_append_boc01 = " file://psplash_1bpp.patch;patch=1 "
 
-inherit autotools pkgconfig update-rc.d
-
-do_configure_append() {
-	install -m 0644 ${WORKDIR}/psplash-hand-img.h ${S}/
-	install -m 0644 ${WORKDIR}/psplash-bar-img.h ${S}/
-
-	if [ -e "${WORKDIR}/psplash.h" ]; then
-		install -m 0644 ${WORKDIR}/psplash.h ${S}/
-	fi
-}
-
-do_install_prepend() {
-	install -d ${D}/mnt/.psplash/
-	install -d ${D}${sysconfdir}/default/
-	install -m 0644 ${WORKDIR}/psplash-default ${D}${sysconfdir}/default/psplash
-	install -d ${D}${sysconfdir}/init.d/
-	install -m 0755 ${WORKDIR}/psplash-init ${D}${sysconfdir}/init.d/psplash
-}
-
-INITSCRIPT_NAME = "psplash"
-INITSCRIPT_PARAMS = "start 01 S . stop 20 0 1 6 ."
-
-FILES_${PN} += "/mnt/.psplash"