uboot-openmoko: create known-good version as seperate bb, make git/svn really uptodate again

3 files changed, 103 insertions, 13 deletions

diff --git a/conf/distro/include/sane-srcdates.inc b/conf/distro/include/sane-srcdates.inc
index 9fdf115781..e5db7a9ceb 100644
--- a/conf/distro/include/sane-srcdates.inc
+++ b/conf/distro/include/sane-srcdates.inc
@@ -40,9 +40,6 @@ SRCDATE_psplash ?= "20070330"
 SRCDATE_web ?= "20060613"
 SRCDATE_zaurusd ?= "20060628"
 
-# OpenMoko
-SRCDATE_uboot-openmoko = "20070829"
-
 # GPE
 SRCDATE_dasher-gpe  ?= "20060814"
 SRCDATE_rosetta ?= "20060804"
diff --git a/packages/uboot/uboot-openmoko_1.2.0+git8993e54b6f397973794f3d6f47d3b3c0c98dd4f6+svn20070819.bb b/packages/uboot/uboot-openmoko_1.2.0+git8993e54b6f397973794f3d6f47d3b3c0c98dd4f6+svn20070819.bb
new file mode 100644
index 0000000000..d660deef9a
--- /dev/null
+++ b/packages/uboot/uboot-openmoko_1.2.0+git8993e54b6f397973794f3d6f47d3b3c0c98dd4f6+svn20070819.bb
@@ -0,0 +1,92 @@
+DESCRIPTION = "U-boot bootloader w/ Neo1973 (GTA01) support"
+AUTHOR = "Harald Welte <laforge@openmoko.org>"
+LICENSE = "GPL"
+SECTION = "bootloader"
+PRIORITY = "optional"
+
+UBOOT_UPSTREAM_REV = "8993e54b6f397973794f3d6f47d3b3c0c98dd4f6"
+UBOOT_OPENMOKO_DATE = "20070819"
+UBOOT_MACHINES = "gta01bv2 gta01bv3 gta01bv4"
+
+PV = "1.2.0+git${UBOOT_UPSTREAM_REV}+svn${UBOOT_OPENMOKO_DATE}"
+PR = "r2"
+
+PROVIDES = "virtual/bootloader"
+S = "${WORKDIR}/git"
+
+SRC_URI = "\
+  git://www.denx.de/git/u-boot.git/;protocol=git;tag=${UBOOT_UPSTREAM_REV} \
+  svn://svn.openmoko.org/branches/u-boot/pre-20070822;module=patches;date=${UBOOT_OPENMOKO_DATE};proto=http \
+  file://uboot-eabi-fix-HACK.patch \
+  file://uboot-20070311-tools_makefile_ln_sf.patch;patch=1 \
+"
+
+EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
+TARGET_LDFLAGS = ""
+
+do_quilt() {
+        mv ${WORKDIR}/patches ${S}/patches && cd ${S} && quilt push -av
+        rm -Rf patches .pc
+}
+
+do_svnrev() {
+	FILE=${S}/tools/setlocalversion
+	OLDFILE=$FILE.old
+	NEWFILE=$FILE.new
+	cp $FILE $OLDFILE
+	LINES=`cat $OLDFILE | wc -l`
+	LINES_WE_WANT=$(($LINES-1))
+	LASTLINE=`cat $OLDFILE | tail -n 1`
+	cat $OLDFILE | head -n $LINES_WE_WANT > $NEWFILE
+	echo ${LASTLINE}_${PR} >> $NEWFILE
+	rm $FILE && mv $NEWFILE $FILE
+}
+
+do_configure_prepend() {
+	find . -name "*.mk" -exec sed -i 's,-mabi=apcs-gnu,,' {} \;
+	find . -name "Makefile" -exec sed -i 's,-mabi=apcs-gnu,,' {} \;
+	cat ${WORKDIR}/uboot-eabi-fix-HACK.patch |patch -p1
+}
+
+do_compile () {
+        chmod +x board/neo1973/gta*/split_by_variant.sh
+        for mach in ${UBOOT_MACHINES}
+        do
+                oe_runmake ${mach}_config
+                oe_runmake clean
+                find board -name lowlevel_foo.bin -exec rm '{}' \;
+                oe_runmake all
+                oe_runmake u-boot.udfu
+                if [ -f u-boot.udfu ]; then
+                        mv u-boot.udfu u-boot_${mach}.bin
+                else
+                        mv u-boot.bin u-boot_${mach}.bin
+                fi
+                if [ -f board/${mach}/lowlevel_foo.bin ]; then
+                        mv board/${mach}/lowlevel_foo.bin \
+                            lowlevel_foo_${mach}.bin
+                else
+                        find board -name lowlevel_foo.bin \
+                            -exec mv '{}' lowlevel_foo_${mach}.bin \;
+                fi
+        done
+}
+
+do_deploy () {
+	install -d ${DEPLOY_DIR_IMAGE}
+	for mach in ${UBOOT_MACHINES}
+	do
+		install -m 0644 ${S}/u-boot_${mach}.bin ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin
+		ln -sf ${DEPLOY_DIR_IMAGE}/u-boot-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/uboot-${mach}-latest.bin
+		if [ -f ${S}/lowlevel_foo_${mach}.bin ]; then
+			install -m 0644 ${S}/lowlevel_foo_${mach}.bin ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin
+			ln -sf ${DEPLOY_DIR_IMAGE}/lowlevel_foo-${mach}-${PV}-${PR}.bin ${DEPLOY_DIR_IMAGE}/lowlevel-foo-${mach}-latest.bin
+		fi
+	done
+	install -m 0755 tools/mkimage ${STAGING_BINDIR_NATIVE}/uboot-mkimage
+}
+
+do_deploy[dirs] = "${S}"
+addtask deploy before do_package after do_install
+addtask quilt before do_patch after do_unpack
+addtask svnrev before do_patch after do_quilt
diff --git a/packages/uboot/uboot-openmoko_svn.bb b/packages/uboot/uboot-openmoko_svn.bb
index e33f560b53..9b5dbb509b 100644
--- a/packages/uboot/uboot-openmoko_svn.bb
+++ b/packages/uboot/uboot-openmoko_svn.bb
@@ -3,23 +3,24 @@ AUTHOR = "Harald Welte <laforge@openmoko.org>"
 LICENSE = "GPL"
 SECTION = "bootloader"
 PRIORITY = "optional"
+PROVIDES = "virtual/bootloader"
+PV = "1.2.0+git${SRCDATE}+svn${SRCDATE}"
+PR = "r0"
 
-UBOOT_UPSTREAM_REV = "3e66c078003607a7d1d214c15a5f262bc1b4032f"
-PV = "1.2.0+git${UBOOT_UPSTREAM_REV}+svn${SRCDATE}"
-PR = "r2"
+UBOOT_MACHINES = "gta01bv2 gta01bv3 gta01bv4 smdk2440 hxd8 qt2410 gta02v1 gta02v2"
 
-PROVIDES = "virtual/bootloader"
-S = "${WORKDIR}/git"
+DEFAULT_PREFERENCE = "-1"
 
-SRC_URI = "git://www.denx.de/git/u-boot.git/;protocol=git;tag=${UBOOT_UPSTREAM_REV} \
-           svn://svn.openmoko.org/trunk/src/target/u-boot;module=patches;proto=http \
-           file://uboot-eabi-fix-HACK.patch \
-           file://uboot-20070311-tools_makefile_ln_sf.patch;patch=1 \
+SRC_URI = "\
+  git://www.denx.de/git/u-boot.git/;protocol=git \
+  svn://svn.openmoko.org/trunk/src/target/u-boot;module=patches;proto=http \
+  file://uboot-eabi-fix-HACK.patch \
+  file://uboot-20070311-tools_makefile_ln_sf.patch;patch=1 \
 "
+S = "${WORKDIR}/git"
 
 EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
 TARGET_LDFLAGS = ""
-UBOOT_MACHINES = "gta01bv2 gta01bv3 gta01bv4 smdk2440 hxd8 qt2410 gta02v1 gta02v2"
 
 do_quilt() {
         mv ${WORKDIR}/patches ${S}/patches && cd ${S} && quilt push -av