libsdl: Add 1.2.14 (and native). Note: Does not use libsdl.inc as that has hacks for older SDL versions.

* Only tested on the OpenPandora under Angstrom currently.

3 files changed, 92 insertions, 0 deletions

diff --git a/conf/checksums.ini b/conf/checksums.ini
index 641632e0d1..f9abaf898b 100644
--- a/conf/checksums.ini
+++ b/conf/checksums.ini
@@ -1058,6 +1058,10 @@ sha256=df77eb883efdcc61220eaf7ade38324629c273c278ce8d700a5530369e9b6df9
 md5=c6660feea2a6834de10bc71b2f8e4d88
 sha256=94f99df1d60f296b57f4740650a71b6425da654044ca30f8f0ce34934429e132
 
+[http://www.libsdl.org/release/SDL-1.2.14.tar.gz]
+md5=e52086d1b508fa0b76c52ee30b55bec4
+sha256=5d927e287034cb6bb0ebccfa382cb1d185cb113c8ab5115a0759798642eed9b6
+
 [http://www.libsdl.org/release/SDL-1.2.7.tar.gz]
 md5=d29b34b6ba3ed213893fc9d8d35e357a
 sha256=f5708b3909261df2043859e771601a5ec973197b2c59d18c6649c1096b5151bd
diff --git a/recipes/libsdl/libsdl-native_1.2.14.bb b/recipes/libsdl/libsdl-native_1.2.14.bb
new file mode 100644
index 0000000000..35a73a6d18
--- /dev/null
+++ b/recipes/libsdl/libsdl-native_1.2.14.bb
@@ -0,0 +1,37 @@
+DESCRIPTION = "Simple DirectMedia Layer - native Edition"
+HOMEPAGE = "http://www.libsdl.org"
+SECTION = "libs"
+LICENSE = "LGPL"
+PR = "r0"
+
+SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz \
+"
+
+S = "${WORKDIR}/SDL-${PV}"
+
+inherit autotools binconfig pkgconfig native
+
+PARALLEL_MAKE = ""
+
+EXTRA_OECONF = "--disable-debug --disable-cdrom --enable-threads --enable-timers --enable-endian \
+                --enable-file --disable-oss --disable-alsa --disable-esd --disable-arts \
+                --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
+                --disable-mintaudio --disable-nasm --disable-video-x11 --disable-video-dga \
+                --disable-video-fbcon --disable-video-directfb --disable-video-ps2gs \
+                --disable-video-xbios --disable-video-gem --disable-video-dummy \
+                --disable-video-opengl --enable-input-events --enable-pthreads \
+                --disable-video-picogui --disable-video-qtopia --enable-dlopen"
+
+do_configure() {
+	gnu-configize
+	oe_runconf
+	cd ${S}
+	# prevent libtool from linking libs against libstdc++, libgcc, ...
+	cat ${TARGET_PREFIX}libtool | sed -e 's/postdeps=".*"/postdeps=""/' > ${TARGET_PREFIX}libtool.tmp
+	mv ${TARGET_PREFIX}libtool.tmp ${TARGET_PREFIX}libtool
+}
+
+do_stage() {
+	autotools_stage_all
+	install -m 0644 build/libSDLmain.a ${STAGING_LIBDIR}
+}
diff --git a/recipes/libsdl/libsdl-x11_1.2.14.bb b/recipes/libsdl/libsdl-x11_1.2.14.bb
new file mode 100644
index 0000000000..621f7b47c1
--- /dev/null
+++ b/recipes/libsdl/libsdl-x11_1.2.14.bb
@@ -0,0 +1,51 @@
+# Do not use the include in 1.2.14 as it has a lot of unneeded munging that applies to old versions.
+#require libsdl.inc
+
+DESCRIPTION = "Simple DirectMedia Layer (X11 and Framebuffer support)"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "LGPL"
+DEPENDS = "alsa-lib mesa virtual/libx11 libxext tslib"
+DEPENDS_avr32 = "alsa-lib virtual/libx11 libxext tslib"
+PROVIDES = "virtual/libsdl"
+PR = "r1"
+
+SRC_URI = " \
+  http://www.libsdl.org/release/SDL-${PV}.tar.gz \
+"
+
+S = "${WORKDIR}/SDL-${PV}"
+
+inherit autotools binconfig pkgconfig
+
+EXTRA_OECONF = " \
+  --disable-static --disable-debug --enable-cdrom --enable-threads --enable-timers --enable-endian \
+  --enable-file --enable-oss --enable-alsa --disable-esd --disable-arts \
+  --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
+  --disable-mintaudio --disable-nasm --enable-video-x11 --disable-video-dga \
+  --enable-video-fbcon --disable-video-directfb --disable-video-ps2gs \
+  --disable-video-xbios --disable-video-gem --disable-video-dummy \
+  --enable-video-opengl --enable-input-events --enable-pthreads \
+  --disable-video-picogui --disable-video-qtopia --enable-dlopen \
+  --enable-input-tslib \
+"
+
+do_configure() { 
+  oe_runconf
+}
+
+do_configure_append () {
+  cd ${S}
+
+  # prevent libtool from linking libs against libstdc++, libgcc, ...
+  cat ${TARGET_PREFIX}libtool | sed -e 's/postdeps=".*"/postdeps=""/' > ${TARGET_PREFIX}libtool.tmp
+  mv ${TARGET_PREFIX}libtool.tmp ${TARGET_PREFIX}libtool
+}
+
+do_stage() {
+  autotools_stage_all		
+  rm ${STAGING_LIBDIR}/libSDL.la
+}
+
+FILES_${PN} = "${libdir}/lib*.so.*"
+FILES_${PN}-dev += "${bindir}/*config"