lighttpd: switch to .inc file and INC_PR

3 files changed, 60 insertions, 95 deletions

diff --git a/recipes/lighttpd/lighttpd.inc b/recipes/lighttpd/lighttpd.inc
new file mode 100644
index 0000000000..1638fb8fce
--- /dev/null
+++ b/recipes/lighttpd/lighttpd.inc
@@ -0,0 +1,51 @@
+DESCRIPTION = "Web server"
+SECTION = "net"
+LICENSE = "BSD"
+DEPENDS = "libpcre"
+
+INC_PR = "r3"
+
+SRC_URI = "http://www.lighttpd.net/download/lighttpd-${PV}.tar.gz \
+	   file://index.html \
+	   file://lighttpd.conf \
+	   file://lighttpd \
+          "
+
+
+EXTRA_OECONF=" \
+              --without-bzip2 \
+              --without-ldap \
+              --without-lua \
+              --without-memcache \
+              --with-pcre \
+              --without-webdav-props \
+              --without-webdav-locks \
+              --without-openssl \
+              --disable-nls \
+              --disable-static \
+             "
+
+inherit autotools pkgconfig update-rc.d
+
+INITSCRIPT_NAME = "lighttpd"
+INITSCRIPT_PARAMS = "defaults 70"
+
+do_install_append() {
+	install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
+	install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
+	install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
+	install -m 0644 ${WORKDIR}/index.html ${D}/www/pages/
+}
+
+do_stage() {
+	autotools_stage_all
+}
+
+FILES_${PN} += "${sysconfdir} /www"
+
+PACKAGES_DYNAMIC = "lighttpd-module-*"
+
+python populate_packages_prepend () {
+        lighttpd_libdir = bb.data.expand('${libdir}', d)
+        do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
+}
diff --git a/recipes/lighttpd/lighttpd_1.4.18.bb b/recipes/lighttpd/lighttpd_1.4.18.bb
index d5870ba5af..3d47a211cf 100644
--- a/recipes/lighttpd/lighttpd_1.4.18.bb
+++ b/recipes/lighttpd/lighttpd_1.4.18.bb
@@ -1,49 +1,9 @@
-DESCRIPTION = "Web server"
-SECTION = "net"
-LICENSE = "BSD"
-DEPENDS = "libpcre"
-PR = "r3"
+require lighttpd.inc
 
-SRC_URI = "http://www.lighttpd.net/download/lighttpd-${PV}.tar.gz \
-	   file://configure.in.patch;patch=1 \
-	   file://mod_redirect.c.patch;patch=1 \
-	   file://src-server.c.patch;patch=1 \
-	   file://index.html \
-	   file://lighttpd.conf \
-	   file://lighttpd"
+PR = "${INC_PR}.1"
 
-EXTRA_OECONF="--without-bzip2 \
-		--without-ldap \
-		--without-lua \
-		--without-memcache \
-		--with-pcre \
-		--without-webdav-props \
-		--without-webdav-locks \
-		--without-openssl \
-		--disable-nls \
-		--disable-static"
+SRC_URI += "file://configure.in.patch;patch=1 \
+	    file://mod_redirect.c.patch;patch=1 \
+	    file://src-server.c.patch;patch=1 \
+           "
 
-inherit autotools pkgconfig update-rc.d
-
-INITSCRIPT_NAME = "lighttpd"
-INITSCRIPT_PARAMS = "defaults 70"
-
-do_install_append() {
-	install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
-	install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
-	install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
-	install -m 0644 ${WORKDIR}/index.html ${D}/www/pages/
-}
-
-do_stage() {
-	autotools_stage_all
-}
-
-FILES_${PN} += "${sysconfdir} /www"
-
-PACKAGES_DYNAMIC = "lighttpd-module-*"
-
-python populate_packages_prepend () {
-        lighttpd_libdir = bb.data.expand('${libdir}', d)
-        do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
-}
diff --git a/recipes/lighttpd/lighttpd_1.4.23.bb b/recipes/lighttpd/lighttpd_1.4.23.bb
index 79d9e39f8b..4e8a6a6511 100644
--- a/recipes/lighttpd/lighttpd_1.4.23.bb
+++ b/recipes/lighttpd/lighttpd_1.4.23.bb
@@ -1,52 +1,6 @@
-DESCRIPTION = "Web server"
-SECTION = "net"
-LICENSE = "BSD"
-DEPENDS = "libpcre"
-PR = "r0"
+require lighttpd.inc
 
-DEFAULT_PREFERENCE = "-1"
-
-SRC_URI = "http://www.lighttpd.net/download/lighttpd-${PV}.tar.gz \
-	   file://index.html \
-	   file://lighttpd.conf \
-	   file://lighttpd"
-#	   file://configure.in.patch;patch=1 \
-#	   file://mod_redirect.c.patch;patch=1 \
-
-
-EXTRA_OECONF="\
---without-bzip2 \
---without-ldap \
---without-lua \
---without-memcache \
---with-pcre \
---without-webdav-props \
---without-webdav-locks \
---without-openssl \
---disable-nls \
---disable-static"
-
-inherit autotools pkgconfig update-rc.d
+PR = "${INC_PR}.1"
 
-INITSCRIPT_NAME = "lighttpd"
-INITSCRIPT_PARAMS = "defaults 70"
-
-do_install_append() {
-	install -d ${D}${sysconfdir}/init.d ${D}/www/logs ${D}/www/pages/dav ${D}/www/var
-	install -m 0755 ${WORKDIR}/lighttpd ${D}${sysconfdir}/init.d
-	install -m 0755 ${WORKDIR}/lighttpd.conf ${D}${sysconfdir}
-	install -m 0644 ${WORKDIR}/index.html ${D}/www/pages/
-}
-
-do_stage() {
-	autotools_stage_all
-}
-
-FILES_${PN} += "${sysconfdir} /www"
-
-PACKAGES_DYNAMIC = "lighttpd-module-*"
+DEFAULT_PREFERENCE = "-1"
 
-python populate_packages_prepend () {
-        lighttpd_libdir = bb.data.expand('${libdir}', d)
-        do_split_packages(d, lighttpd_libdir, '^mod_(.*)\.so$', 'lighttpd-module-%s', 'Lighttpd module for %s', extra_depends='')
-}