hal: add 0.5.9 and hal-info_git from poky

* has a hack to work around autofoo >2.59 dep
* requires linux-libc-headers >= 2.6.18

2 files changed, 110 insertions, 0 deletions

diff --git a/packages/hal/hal-info_git.bb b/packages/hal/hal-info_git.bb
new file mode 100644
index 0000000000..fdbbae91fb
--- /dev/null
+++ b/packages/hal/hal-info_git.bb
@@ -0,0 +1,16 @@
+PV = "${SRCDATE}+git"
+
+DESCRIPTION = "Hardware Abstraction Layer device information"
+HOMEPAGE = "http://freedesktop.org/Software/hal"
+SECTION = "unknown"
+LICENSE = "GPL AFL"
+
+SRC_URI = "git://anongit.freedesktop.org/hal-info/;protocol=git"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--disable-recall --disable-video"
+
+FILES_${PN} += "/usr/share/hal/"
diff --git a/packages/hal/hal_0.5.9.bb b/packages/hal/hal_0.5.9.bb
new file mode 100644
index 0000000000..e021f03045
--- /dev/null
+++ b/packages/hal/hal_0.5.9.bb
@@ -0,0 +1,94 @@
+DESCRIPTION = "Hardware Abstraction Layer"
+HOMEPAGE = "http://freedesktop.org/Software/hal"
+SECTION = "unknown"
+LICENSE = "GPL LGPL AFL"
+
+DEPENDS = "virtual/kernel dbus-glib udev intltool expat libusb"
+RDEPENDS += "udev hal-info"
+#RDEPENDS_hal-device-manager = "python hal python-pygnome"
+RRECOMMENDS = "udev-utils"
+
+PR = "r0"
+
+SRC_URI = "http://freedesktop.org/~david/dist/hal-${PV}.tar.gz \
+        file://99_hal"
+
+S = "${WORKDIR}/hal-${PV}"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-hwdata=${datadir}/hwdata \
+                --with-expat=${STAGING_LIBDIR}/.. \
+                --with-dbus-sys=${sysconfdir}/dbus-1/system.d \
+                --with-hotplug=${sysconfdir}/hotplug.d \
+                --disable-docbook-docs \
+                --disable-policy-kit \
+                --disable-acpi --disable-pmu --disable-pci \
+                --disable-pci-ids --disable-pnp-ids \
+                "
+
+# work around autoconf >2.59 deps...
+do_configure() {
+	gnu-configize
+	libtoolize --force
+	oe_runconf
+}
+
+do_install_append() {
+	install -d ${D}/etc/default/volatiles
+	install -m 0644 ${WORKDIR}/99_hal ${D}/etc/default/volatiles
+}
+
+do_stage() {
+        autotools_stage_all
+        install -d ${STAGING_LIBDIR}
+        install -m 755 libhal/.libs/libhal.so.1.0.0 ${STAGING_LIBDIR}/libhal.so
+        install -m 755 libhal-storage/.libs/libhal-storage.so.1.0.0 ${STAGING_LIBDIR}/libhal-storage.so
+}
+
+# At the time the postinst runs, dbus might not be setup so only restart if running
+pkg_postinst_hal () {
+	# can't do this offline
+	if [ "x$D" != "x" ]; then
+		exit 1
+	fi
+
+	/etc/init.d/populate-volatile.sh update
+
+	grep haldaemon /etc/group || addgroup haldaemon
+	grep haldaemon /etc/passwd || adduser --disabled-password --system --home /var/run/hald --no-create-home haldaemon --ingroup haldaemon -g HAL
+
+	DBUSPID=`pidof dbus-daemon`
+
+	if [ "x$DBUSPID" != "x" ]; then
+		/etc/init.d/dbus-1 force-reload
+	fi
+}
+
+pkg_postrm_hal () {
+	deluser haldaemon || true
+	delgroup haldaemon || true
+}
+
+#PACKAGES += "hal-device-manager"
+
+#FILES_hal-device-manager = " \
+#               ${datadir}/hal/device-manager/ \
+#               ${bindir}/hal-device-manager"
+
+FILES_${PN} = "${sysconfdir} \
+                ${bindir}/lshal \
+                ${bindir}/hal-find-by-capability \
+                ${bindir}/hal-find-by-property \
+                ${bindir}/hal-device  \
+                ${bindir}/hal-get-property \
+                ${bindir}/hal-set-property  \
+                ${bindir}/hal-lock  \
+                ${bindir}/hal-is-caller-locked-out  \
+                ${sbindir} \
+                ${libdir}/libhal.so.* \
+                ${libdir}/libhal-storage.so.* \
+                ${libdir}/hal \
+                ${libexecdir} \
+                ${datadir}/hal/fdi \
+                ${datadir}/hal/scripts"