dbus: add 0.62

3 files changed, 94 insertions, 0 deletions

diff --git a/packages/dbus/dbus-native_0.62.bb b/packages/dbus/dbus-native_0.62.bb
new file mode 100644
index 0000000000..c91231f6f9
--- /dev/null
+++ b/packages/dbus/dbus-native_0.62.bb
@@ -0,0 +1,17 @@
+include dbus_${PV}.inc
+
+SRC_URI_EXTRA=""
+
+inherit native
+
+S = "${WORKDIR}/dbus-${PV}"
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/dbus"
+DEPENDS = "glib-2.0-native"
+
+do_stage() {
+	oe_runmake install
+	install -d ${STAGING_DATADIR}/dbus
+	install -m 0644 tools/dbus-bus-introspect.xml ${STAGING_DATADIR}/dbus
+	install -m 0644 tools/dbus-glib-bindings.h ${STAGING_DATADIR}/dbus
+}
+
diff --git a/packages/dbus/dbus_0.62.bb b/packages/dbus/dbus_0.62.bb
new file mode 100644
index 0000000000..f8e16815e7
--- /dev/null
+++ b/packages/dbus/dbus_0.62.bb
@@ -0,0 +1,13 @@
+include dbus_${PV}.inc
+
+FILESPATH = "${FILE_DIRNAME}/dbus-0.6x:${FILE_DIRNAME}/dbus"
+DEPENDS = "expat glib-2.0 virtual/libintl dbus-native"
+SRC_URI_EXTRA = "file://no-introspect.patch;patch=1 file://no-bindings.patch;patch=1"
+
+FILES_${PN} += "${bindir}/dbus-daemon"
+FILES_${PN}-dev += "${bindir}/dbus-binding-tool"
+
+do_configure_prepend() {
+	install -m 0644 ${STAGING_DIR}/${BUILD_SYS}/share/dbus/dbus-bus-introspect.xml ${S}/tools/
+	install -m 0644 ${STAGING_DIR}/${BUILD_SYS}/share/dbus/dbus-glib-bindings.h ${S}/tools/
+}
diff --git a/packages/dbus/dbus_0.62.inc b/packages/dbus/dbus_0.62.inc
new file mode 100644
index 0000000000..c1dcc0e4a3
--- /dev/null
+++ b/packages/dbus/dbus_0.62.inc
@@ -0,0 +1,64 @@
+SECTION = "base"
+PR = "r0"
+HOMEPAGE = "http://www.freedesktop.org/Software/dbus"
+DESCRIPTION = "message bus system for applications to talk to one another"
+LICENSE = "GPL"
+DEPENDS = "expat glib-2.0 virtual/libintl"
+
+SRC_URI = "http://freedesktop.org/software/dbus/releases/dbus-${PV}.tar.gz \
+	   file://cross.patch;patch=1 \
+	   file://tmpdir.patch;patch=1 \
+	   file://dbus-1.init \
+	   file://no-examples.patch;patch=1 \
+	   ${SRC_URI_EXTRA}"
+
+inherit autotools pkgconfig update-rc.d gettext
+
+INITSCRIPT_NAME = "dbus-1"
+INITSCRIPT_PARAMS = "defaults"
+
+CONFFILES_${PN} = "${sysconfdir}/dbus-1/system.conf ${sysconfdir}/dbus-1/session.conf"
+
+FILES_${PN} = "${bindir}/dbus-daemon ${bindir}/dbus-launch ${bindir}/dbus-cleanup-sockets ${bindir}/dbus-send ${bindir}/dbus-monitor ${sysconfdir} ${datadir}/dbus-1/services ${libdir}/lib*.so.*"
+FILES_${PN}-dev += "${libdir}/dbus-1.0/include ${bindir}/dbus-glib-tool"
+
+pkg_postinst_dbus() {
+#!/bin/sh
+
+# can't do adduser stuff offline
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+MESSAGEUSER=messagebus
+MESSAGEHOME=/var/run/dbus
+
+mkdir -p $MESSAGEHOME || true
+chgrp "$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || addgroup "$MESSAGEUSER"
+chown "$MESSAGEUSER"."$MESSAGEUSER" "$MESSAGEHOME" 2>/dev/null || adduser --system --home "$MESSAGEHOME" --no-create-home --disabled-password --ingroup "$MESSAGEUSER" "$MESSAGEUSER"
+}
+
+EXTRA_OECONF = "--disable-qt  --disable-qt3 --disable-gtk --disable-tests \
+		--disable-checks --disable-xml-docs --disable-doxygen-docs \
+		--with-xml=expat --without-x"
+
+
+do_stage () {
+	oe_libinstall -so -C dbus libdbus-1 ${STAGING_LIBDIR}
+	oe_libinstall -so -C glib libdbus-glib-1 ${STAGING_LIBDIR}
+
+	autotools_stage_includes
+
+	mkdir -p ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
+	install -m 0644 dbus/dbus-arch-deps.h ${STAGING_LIBDIR}/dbus-1.0/include/dbus/
+}
+
+do_install_append () {
+	install -d ${D}${sysconfdir}/init.d
+	install -m 0755 ${WORKDIR}/dbus-1.init ${D}${sysconfdir}/init.d/dbus-1
+}
+
+python populate_packages_prepend () {
+	if (bb.data.getVar('DEBIAN_NAMES', d, 1)):
+		bb.data.setVar('PKG_dbus', 'dbus-1', d)
+}