Merge openembedded@openembedded.bkbits.net:packages

into hyperion.(none):/home/kergoth/code/projects/packages

2004/05/16 18:37:05-05:00 (none)!kergoth
Correct pv in gcc-snapshot

2004/05/15 13:14:32-05:00 (none)!kergoth
Set package version to CVSDATE in gcc-snapshot .oes

BKrev: 40a8046e8hAEDP_WsNgtx59OFuy3IA

3 files changed, 331 insertions, 0 deletions

diff --git a/gcc-snapshot/gcc-snapshot-cross-initial_cvs.oe b/gcc-snapshot/gcc-snapshot-cross-initial_cvs.oe
index e69de29bb2..311f2bc7aa 100644
--- a/gcc-snapshot/gcc-snapshot-cross-initial_cvs.oe
+++ b/gcc-snapshot/gcc-snapshot-cross-initial_cvs.oe
@@ -0,0 +1,29 @@
+include gcc-snapshot-cross_cvs.oe
+
+DEPENDS = "virtual/${TARGET_PREFIX}binutils virtual/${TARGET_PREFIX}libc-initial"
+PROVIDES = "virtual/${TARGET_PREFIX}gcc-initial"
+
+PACKAGES = ""
+
+# This is intended to be a -very- basic config
+EXTRA_OECONF = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
+		--with-newlib \
+		--disable-nls \
+		--disable-shared \
+		--disable-threads \
+		--disable-multilib \
+		--disable-__cxa_atexit \
+		--enable-languages=c \
+		--enable-target-optspace \
+		--program-prefix=${TARGET_PREFIX}"
+
+do_stage_prepend () {
+	mkdir -p ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/${PV}
+	ln -sf libgcc.a ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/${PV}/libgcc_eh.a
+}
+
+# Override the method from gcc-cross so we don't try to install libgcc
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+}
+
diff --git a/gcc-snapshot/gcc-snapshot-cross_cvs.oe b/gcc-snapshot/gcc-snapshot-cross_cvs.oe
index e69de29bb2..1aa0daf790 100644
--- a/gcc-snapshot/gcc-snapshot-cross_cvs.oe
+++ b/gcc-snapshot/gcc-snapshot-cross_cvs.oe
@@ -0,0 +1,93 @@
+include gcc-snapshot_cvs.oe
+inherit cross
+FILESDIR = "${@os.path.dirname(oe.data.getVar('FILE',d,1))}/gcc-${PV}"
+
+DEPENDS = "virtual/${TARGET_PREFIX}binutils virtual/${TARGET_PREFIX}libc-for-gcc"
+PROVIDES = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
+
+# Files for these are defined in the main gcc.oe
+PACKAGES = "libgcc libstdc++ libg2c"
+INHIBIT_PACKAGE_STRIP = "1"
+
+EXTRA_OECONF_PATHS = "--with-local-prefix=${CROSS_DIR}/${TARGET_SYS} \
+		      --with-gxx-include-dir=${CROSS_DIR}/${TARGET_SYS}/include/c++"
+
+export CPPFLAGS = ""
+export CXXFLAGS = ""
+export CFLAGS = ""
+export LDFLAGS = ""
+
+do_configure () {
+	rm -f ${CROSS_DIR}/lib/gcc/${TARGET_SYS}/${PV}/libgcc_eh.a
+	(cd ${S} && gnu-configize) || die "failure running gnu-configize"
+	oe_runconf
+}
+
+do_compile_prepend () {
+	export CC="${BUILD_CC}"
+	export AR_FOR_TARGET="${TARGET_SYS}-ar"
+	export RANLIB_FOR_TARGET="${TARGET_SYS}-ranlib"
+	export LD_FOR_TARGET="${TARGET_SYS}-ld"
+	export NM_FOR_TARGET="${TARGET_SYS}-nm"
+	export CC_FOR_TARGET="${CCACHE} ${TARGET_SYS}-gcc"
+}
+
+do_stage_append () {
+	for d in info man share/doc share/locale ; do
+		rm -rf ${CROSS_DIR}/$d
+	done
+
+	# These aren't useful on the cross toolchain
+	rm -f ${CROSS_DIR}/bin/*gcov
+	rm -f ${CROSS_DIR}/bin/*gccbug
+
+	# Fix a few include links so cross builds are happier
+	if [ ! -e ${STAGING_INCDIR}/c++ ]; then
+		mkdir -p ${STAGING_INCDIR}
+		ln -sf ${CROSS_DIR}/${TARGET_SYS}/include/c++ \
+			${STAGING_INCDIR}/
+	fi
+
+	# We use libiberty from binutils
+	rm -f ${CROSS_DIR}/lib/libiberty.a
+
+	# We probably don't need these
+	rmdir ${CROSS_DIR}/include || :
+
+	# We don't really need to keep this around
+	rm -rf ${CROSS_DIR}/share
+}
+
+python do_package() {
+	if oe.data.getVar('DEBIAN_NAMES', d, 1):
+		oe.data.setVar('PKG_libgcc', 'libgcc1', d)
+	oe.build.exec_func('package_do_package', d)
+}
+
+do_install () {
+	oe_runmake 'DESTDIR=${D}' install
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/lib
+	if [ -f ${D}/lib/libgcc_s.so.? ]; then
+		# Already in the right location
+		:
+	elif [ -f ${D}/${prefix}/lib/libgcc_s.so.? ]; then
+		mv -f ${D}/${prefix}/lib/libgcc_s.so.* ${D}/lib
+	else
+		mv -f ${D}/${prefix}/*/lib/libgcc_s.so.* ${D}/lib
+	fi
+
+	# Move libstdc++ and libg2c into libdir (resetting our prefix to /usr
+	TGT_LIBDIR=`echo ${libdir} | sed -e 's,${CROSS_DIR},/usr,'`
+	mkdir -p ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libstdc++.so.* ${D}/${TGT_LIBDIR}
+	mv -f ${D}/${prefix}/*/lib/libg2c.so.* ${D}/${TGT_LIBDIR}
+
+	# Manually run the target stripper since we won't get it run by
+	# the packaging.
+	${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libstdc++.so.*
+	${TARGET_PREFIX}strip ${D}/${TGT_LIBDIR}/libg2c.so.*
+	${TARGET_PREFIX}strip ${D}/libgcc_s.so.*
+}
+
diff --git a/gcc-snapshot/gcc-snapshot_cvs.oe b/gcc-snapshot/gcc-snapshot_cvs.oe
index e69de29bb2..2a27e54927 100644
--- a/gcc-snapshot/gcc-snapshot_cvs.oe
+++ b/gcc-snapshot/gcc-snapshot_cvs.oe
@@ -0,0 +1,209 @@
+inherit autotools
+
+PV = "${CVSDATE}"
+DESCRIPTION = "The GNU cc and gcc C compilers."
+LICENSE = "GPL"
+MAINTAINER = "Gerald Britton <gbritton@doomcom.org>"
+
+# libgcc libstdc++ libg2c are listed in our FILES_*, but are actually
+# packaged in the respective cross packages.
+PACKAGES = "${PN} ${PN}-symlinks \
+            ${PN}-c++ ${PN}-c++-symlinks \
+            ${PN}-f77 ${PN}-f77-symlinks \
+            libstdc++-dev libg2c-dev \
+            ${PN}-doc"
+
+FILES_${PN} = "${bindir}/${TARGET_PREFIX}gcc \
+	       ${bindir}/${TARGET_PREFIX}cpp \
+	       ${bindir}/${TARGET_PREFIX}gcov \
+	       ${bindir}/${TARGET_PREFIX}gccbug \
+	       ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1 \
+	       ${libexecdir}/gcc/${TARGET_SYS}/${PV}/collect2 \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/*.o \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/specs \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/lib* \
+	       ${libdir}/gcc/${TARGET_SYS}/${PV}/include"
+
+FILES_${PN}-symlinks = "${bindir}/cc \
+			${bindir}/gcc \
+			${bindir}/cpp \
+			${bindir}/gcov \
+			${bindir}/gccbug"
+
+FILES_${PN}-f77 = "${bindir}/${TARGET_PREFIX}g77 \
+		   ${libexecdir}/gcc/${TARGET_SYS}/${PV}/f771"
+
+FILES_${PN}-f77-symlinks = "${bindir}/g77 \
+			    ${bindir}/f77"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libg2c = "${libdir}/libg2c.so.*"
+FILES_libg2c = "/usr/lib/libg2c.so.*"
+
+FILES_libg2c-dev = "${libdir}/libg2c.so \
+			  ${libdir}/libg2c.a \
+			  ${libdir}/libfrtbegin.a"
+
+FILES_${PN}-c++ = "${bindir}/${TARGET_PREFIX}g++ \
+		   ${libexecdir}/gcc/${TARGET_SYS}/${PV}/cc1plus"
+
+FILES_${PN}-c++-symlinks = "${bindir}/c++ \
+			    ${bindir}/g++"
+
+FILES_libgcc = "/lib/libgcc_s.so.*"
+
+# Called from within gcc-cross, so libdir is set wrong
+#FILES_libstdc++ = "${libdir}/libstdc++.so.*"
+FILES_libstdc++ = "/usr/lib/libstdc++.so.*"
+
+FILES_libstdc++-dev = "${includedir}/c++/${PV} \
+		       ${libdir}/libstdc++.so \
+		       ${libdir}/libstdc++.la \
+		       ${libdir}/libstdc++.a \
+		       ${libdir}/libsupc++.la \
+		       ${libdir}/libsupc++.a"
+
+FILES_${PN}-doc = "${infodir} \
+		   ${mandir} \
+		   ${libdir}/gcc/${TARGET_SYS}/${PV}/include/README"
+
+SRC_URI = "cvs://anoncvs:@savannah.gnu.org/cvsroot/gcc;module=gcc;method=ext;rsh=ssh"
+
+gccbuild_uclibc_do_patch () {
+	#
+	# Hack things to use the correct shared lib loader
+	#
+	#LIST=`grep -lr -- "-dynamic-linker.*\.so[\.0-9]*" .`
+	#if [ -n "$LIST" ] ; then
+	#	perl -i -p -e "s,-dynamic-linker.*\.so[\.0-9]*},-dynamic-linker /lib/ld-uClibc.so.0},;" $LIST
+	#fi
+
+	#
+	# Prevent system glibc start files from leaking in uninvited...
+	#
+	perl -i -p -e "s,standard_startfile_prefix_1 = \".*,standard_startfile_prefix_1 = \"${CROSS_DIR}/${TARGET_SYS}/lib/\";,;" gcc/gcc.c
+	perl -i -p -e "s,standard_startfile_prefix_2 = \".*,standard_startfile_prefix_2 = \"${CROSS_DIR}/${TARGET_SYS}/usr/lib/\";,;" gcc/gcc.c
+
+	#
+	# Prevent system glibc include files from leaking in uninvited...
+	#
+	perl -i -p -e "s,^NATIVE_SYSTEM_HEADER_DIR.*,NATIVE_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
+	perl -i -p -e "s,^CROSS_SYSTEM_HEADER_DIR.*,CROSS_SYSTEM_HEADER_DIR=${CROSS_DIR}/${TARGET_SYS}/include,;" gcc/Makefile.in
+	perl -i -p -e "s,^#define.*STANDARD_INCLUDE_DIR.*,#define STANDARD_INCLUDE_DIR \"${CROSS_DIR}/${TARGET_SYS}/include\",;" gcc/cppdefault.h
+
+	#
+	# Prevent system glibc libraries from being found by collect2 
+	# when it calls locatelib() and rummages about the system looking 
+	# for libraries with the correct name...
+	#
+	perl -i -p -e "s,\"/lib,\"${CROSS_DIR}/${TARGET_SYS}/lib,g;" \
+		gcc/collect2.c
+	perl -i -p -e "s,\"/usr/,\"${CROSS_DIR}/${TARGET_SYS}/usr/,g;" \
+		gcc/collect2.c
+
+	#
+	# Prevent gcc from using the unwind-dw2-fde-glibc code
+	#
+	perl -i -p -e "s,^#ifndef inhibit_libc,#define inhibit_libc\n#ifndef inhibit_libc,g;" gcc/unwind-dw2-fde-glibc.c
+}
+
+python do_patch () {
+    import oe, re
+    oe.build.exec_func('base_do_patch', d)
+    if (re.match('.*uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None):
+        oe.build.exec_func('gccbuild_uclibc_do_patch', d)
+}
+
+S = "${WORKDIR}/gcc"
+B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
+
+EXTRA_OECONF = "--disable-nls \
+                --with-gnu-ld \
+                --enable-shared \
+                --enable-multilib \
+                --enable-target-optspace \
+                --enable-languages=c,c++,f77 \
+                --enable-threads=posix \
+                --enable-c99 \
+                --enable-long-long \
+                --enable-symvers=gnu \
+                --program-prefix=${TARGET_PREFIX} \
+                ${EXTRA_OECONF_PATHS} \
+                ${EXTRA_OECONF_DEP}"
+
+EXTRA_OECONF_PATHS = "--with-local-prefix=${prefix}/local \
+                      --with-gxx-include-dir=${includedir}/c++/${PV}"
+
+EXTRA_OECONF_DEP = ""
+EXTRA_OECONF_uclibc = "--disable-__cxa_atexit"
+EXTRA_OECONF_glibc = "--enable-__cxa_atexit"
+
+python __anonymous () {
+    import oe, re
+    if (re.match('linux-uclibc$', oe.data.getVar('TARGET_OS', d, 1)) != None):
+        oe.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_uclibc}', d)
+    elif (re.match('linux$', oe.data.getVar('TARGET_OS', d, 1)) != None):
+        oe.data.setVar('EXTRA_OECONF_DEP', '${EXTRA_OECONF_glibc}', d)
+}
+
+do_configure () {
+	# Setup these vars for cross building only
+	if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
+		export CC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+		export GCC_FOR_TARGET="${CCACHE} ${HOST_PREFIX}gcc"
+		export CXX_FOR_TARGET="${CCACHE} ${HOST_PREFIX}g++"
+		export AS_FOR_TARGET="${HOST_PREFIX}as"
+		export LD_FOR_TARGET="${HOST_PREFIX}ld"
+		export NM_FOR_TARGET="${HOST_PREFIX}nm"
+		export AR_FOR_TARGET="${HOST_PREFIX}ar"
+		export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
+	fi
+	(cd ${S} && gnu-configize) || die "failure running gnu-configize"
+	oe_runconf
+}
+
+do_install () {
+	autotools_do_install
+
+	# Cleanup some of the /usr/lib{,exec}/gcc stuff ...
+	rm -r ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+	rm -r ${D}/${libexecdir}/gcc/${TARGET_SYS}/${PV}/install-tools
+
+	# Move libgcc_s into /lib
+	mkdir -p ${D}/lib
+	mv ${D}/${libdir}/libgcc_s.so.* ${D}/lib
+	rm ${D}/${libdir}/libgcc_s.so
+	ln -sf `echo ${libdir}/gcc/${TARGET_SYS}/${PV} \
+		| tr -s / \
+		| sed -e 's,^/,,' -e 's,[^/]*,..,g'`/lib/libgcc_s.so.? \
+		      ${D}/${libdir}/gcc/${TARGET_SYS}/${PV}/libgcc_s.so
+
+	# We don't need libtool libraries
+	rm ${D}/${libdir}/libg2c.la
+
+	# Cleanup manpages..
+	rm -r ${D}/${mandir}/man7
+
+	# We use libiberty from binutils
+	rm ${D}/${libdir}/libiberty.a
+
+	cd ${D}/${bindir}
+
+	# We care about g++ not c++
+	rm *c++
+
+	# We don't care about the gcc-<version> ones for this
+	rm *gcc-?.?*
+
+	# These sometimes show up, they are strange, we remove them
+	rm -f ${TARGET_ARCH}-*${TARGET_ARCH}-*
+
+	# Symlinks so we can use these trivially on the target
+	ln -sf ${TARGET_SYS}-g77 g77
+	ln -sf ${TARGET_SYS}-g++ g++
+	ln -sf ${TARGET_SYS}-gcc gcc
+	ln -sf g77 f77
+	ln -sf g++ c++
+	ln -sf gcc cc
+}
+